โล่ TFT LCD 2.4 "ไม่ทำงานบน Arduino Mega

แม้ในเว็บไซต์ของ ebay มีการกล่าวถึงว่าฉันไม่สามารถใช้จอแสดงผล TFT LCD Shield 2.4 "ที่แนบมากับ Arduino Mega ปัญหาคือฉันซื้อเกราะนี้โดยไม่ได้ตั้งใจฉันต้องการใส่โล่นี้ลงบน Arduino Mega 2560 มี วิธีในการรวมจอแสดงผล Mega และ 2.4 "

หมายเหตุ: ฉันลองใช้ Arduino Uno ของเพื่อนฉัน โล่ทำงานได้ดีมาก

หมายเหตุ: รูปภาพด้านล่างกำลังระบุคำถามของฉัน จอแสดงผลไม่ทำงานรหัส Arduino ของฉัน มันรันเฉพาะ LED

    // UTFT_Demo_320x240 (C)2012 Henning Karlsen
// web: http://www.henningkarlsen.com/electronics
//
// This program is a demo of how to use most of the functions
// of the library with a supported display modules.
//
// This demo was made for modules with a screen resolution 
// of 320x240 pixels.
//
// This program requires the UTFT library.
//

#include <UTFT.h>
#define ILI9320_16 18
// Declare which fonts we will be using
extern uint8_t SmallFont[];

// Uncomment the next line for Arduino 2009/Uno
//UTFT myGLCD(UNO_24,A2,A1,A3,A4);   // Remember to change the model parameter to suit your display module!

// Uncomment the next line for Arduino Mega
UTFT myGLCD(ILI9320_16,38,39,40,41);   // Remember to change the model parameter to suit your display module!

void setup()
{
  randomSeed(analogRead(0));

// Setup the LCD
  pinMode(A0,OUTPUT);       // for the UNO_SHIELD_1IN1
  digitalWrite(A0,HIGH);    // the RD pin must be set high
  myGLCD.InitLCD();
  myGLCD.setFont(SmallFont);
}

void loop()
{
  int buf[318];
  int x, x2;
  int y, y2;
  int r;

// Clear the screen and draw the frame
  myGLCD.clrScr();

  myGLCD.setColor(255, 0, 0);
  myGLCD.fillRect(0, 0, 319, 13);
  myGLCD.setColor(64, 64, 64);
  myGLCD.fillRect(0, 226, 319, 239);
  myGLCD.setColor(255, 255, 255);
  myGLCD.setBackColor(255, 0, 0);
  myGLCD.print("* Universal Color TFT Display Library *", CENTER, 1);
  myGLCD.setBackColor(64, 64, 64);
  myGLCD.setColor(255,255,0);
  myGLCD.print("<http://electronics.henningkarlsen.com>", CENTER, 227);

  myGLCD.setColor(0, 0, 255);
  myGLCD.drawRect(0, 14, 319, 225);

// Draw crosshairs
  myGLCD.setColor(0, 0, 255);
  myGLCD.setBackColor(0, 0, 0);
  myGLCD.drawLine(159, 15, 159, 224);
  myGLCD.drawLine(1, 119, 318, 119);
  for (int i=9; i<310; i+=10)
    myGLCD.drawLine(i, 117, i, 121);
  for (int i=19; i<220; i+=10)
    myGLCD.drawLine(157, i, 161, i);

// Draw sin-, cos- and tan-lines  
  myGLCD.setColor(0,255,255);
  myGLCD.print("Sin", 5, 15);
  for (int i=1; i<318; i++)
  {
    myGLCD.drawPixel(i,119+(sin(((i*1.13)*3.14)/180)*95));
  }

  myGLCD.setColor(255,0,0);
  myGLCD.print("Cos", 5, 27);
  for (int i=1; i<318; i++)
  {
    myGLCD.drawPixel(i,119+(cos(((i*1.13)*3.14)/180)*95));
  }

  myGLCD.setColor(255,255,0);
  myGLCD.print("Tan", 5, 39);
  for (int i=1; i<318; i++)
  {
    myGLCD.drawPixel(i,119+(tan(((i*1.13)*3.14)/180)));
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);
  myGLCD.setColor(0, 0, 255);
  myGLCD.setBackColor(0, 0, 0);
  myGLCD.drawLine(159, 15, 159, 224);
  myGLCD.drawLine(1, 119, 318, 119);

// Draw a moving sinewave
  x=1;
  for (int i=1; i<(318*20); i++) 
  {
    x++;
    if (x==319)
      x=1;
    if (i>319)
    {
      if ((x==159)||(buf[x-1]==119))
        myGLCD.setColor(0,0,255);
      else
        myGLCD.setColor(0,0,0);
      myGLCD.drawPixel(x,buf[x-1]);
    }
    myGLCD.setColor(0,255,255);
    y=119+(sin(((i*1.1)*3.14)/180)*(90-(i / 100)));
    myGLCD.drawPixel(x,y);
    buf[x-1]=y;
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some filled rectangles
  for (int i=1; i<6; i++)
  {
    switch (i)
    {
      case 1:
        myGLCD.setColor(255,0,255);
        break;
      case 2:
        myGLCD.setColor(255,0,0);
        break;
      case 3:
        myGLCD.setColor(0,255,0);
        break;
      case 4:
        myGLCD.setColor(0,0,255);
        break;
      case 5:
        myGLCD.setColor(255,255,0);
        break;
    }
    myGLCD.fillRect(70+(i*20), 30+(i*20), 130+(i*20), 90+(i*20));
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some filled, rounded rectangles
  for (int i=1; i<6; i++)
  {
    switch (i)
    {
      case 1:
        myGLCD.setColor(255,0,255);
        break;
      case 2:
        myGLCD.setColor(255,0,0);
        break;
      case 3:
        myGLCD.setColor(0,255,0);
        break;
      case 4:
        myGLCD.setColor(0,0,255);
        break;
      case 5:
        myGLCD.setColor(255,255,0);
        break;
    }
    myGLCD.fillRoundRect(190-(i*20), 30+(i*20), 250-(i*20), 90+(i*20));
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some filled circles
  for (int i=1; i<6; i++)
  {
    switch (i)
    {
      case 1:
        myGLCD.setColor(255,0,255);
        break;
      case 2:
        myGLCD.setColor(255,0,0);
        break;
      case 3:
        myGLCD.setColor(0,255,0);
        break;
      case 4:
        myGLCD.setColor(0,0,255);
        break;
      case 5:
        myGLCD.setColor(255,255,0);
        break;
    }
    myGLCD.fillCircle(100+(i*20),60+(i*20), 30);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some lines in a pattern
  myGLCD.setColor (255,0,0);
  for (int i=15; i<224; i+=5)
  {
    myGLCD.drawLine(1, i, (i*1.44)-10, 224);
  }
  myGLCD.setColor (255,0,0);
  for (int i=224; i>15; i-=5)
  {
    myGLCD.drawLine(318, i, (i*1.44)-11, 15);
  }
  myGLCD.setColor (0,255,255);
  for (int i=224; i>15; i-=5)
  {
    myGLCD.drawLine(1, i, 331-(i*1.44), 15);
  }
  myGLCD.setColor (0,255,255);
  for (int i=15; i<224; i+=5)
  {
    myGLCD.drawLine(318, i, 330-(i*1.44), 224);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some random circles
  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=32+random(256);
    y=45+random(146);
    r=random(30);
    myGLCD.drawCircle(x, y, r);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some random rectangles
  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=2+random(316);
    y=16+random(207);
    x2=2+random(316);
    y2=16+random(207);
    myGLCD.drawRect(x, y, x2, y2);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

// Draw some random rounded rectangles
  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=2+random(316);
    y=16+random(207);
    x2=2+random(316);
    y2=16+random(207);
    myGLCD.drawRoundRect(x, y, x2, y2);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

  for (int i=0; i<100; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    x=2+random(316);
    y=16+random(209);
    x2=2+random(316);
    y2=16+random(209);
    myGLCD.drawLine(x, y, x2, y2);
  }

  delay(2000);

  myGLCD.setColor(0,0,0);
  myGLCD.fillRect(1,15,318,224);

  for (int i=0; i<10000; i++)
  {
    myGLCD.setColor(random(255), random(255), random(255));
    myGLCD.drawPixel(2+random(316), 16+random(209));
  }

  delay(2000);

  myGLCD.fillScr(0, 0, 255);
  myGLCD.setColor(255, 0, 0);
  myGLCD.fillRoundRect(80, 70, 239, 169);

  myGLCD.setColor(255, 255, 255);
  myGLCD.setBackColor(255, 0, 0);
  myGLCD.print("That's it!", CENTER, 93);
  myGLCD.print("Restarting in a", CENTER, 119);
  myGLCD.print("few seconds...", CENTER, 132);

  myGLCD.setColor(0, 255, 0);
  myGLCD.setBackColor(0, 0, 255);
  myGLCD.print("Runtime: (msecs)", CENTER, 210);
  myGLCD.printNumI(millis(), CENTER, 225);

  delay (10000);
}

ฉันเพิ่งเกิดขึ้นที่จะซื้อจอแอลซีดีโล่เดียวกันไม่กี่วันที่ผ่านมามองหาห้องสมุดที่จะใช้มันกับคณะกรรมการ MEGA 2560 ผมพบว่าhttps://github.com/Smoke-And-Wires/TFT-Shield-Example-Codeซึ่ง รองรับทั้งบอร์ดUNOและMEGA

การใช้งานนั้นง่ายมากหากเราต้องการใช้งานกับMEGAเราควรเปลี่ยนส่วนหัว#include "uno_24_shield.h"ในSWTFT.cppเป็น#include "mega_24_shield.h"

คำอธิบาย (มีประโยชน์สำหรับการเพิ่ม suppport สำหรับเกราะในห้องสมุดอื่น ๆ ):

ความเข้ากันไม่ได้นั้นมาจากการจับคู่พอร์ตที่แตกต่างกันสำหรับ Arduino pin-out ระหว่าง Mega และ UNO

ในโล่ LCD ของUNOจะเชื่อมต่อผ่าน:

+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| LCD Data Bit  |  7  |  6  |  5  |  4  |  3  |  2  |  1  |  0  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| Digital pin # |  7  |  6  |  5  |  4  |  3  |  2  |  9  |  8  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| Uno port/pin  | PD7 | PD6 | PD5 | PD4 | PD3 | PD2 | PB1 | PB0 |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+

ในMEGAมันจะเชื่อมต่อผ่าน:

+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| LCD Data Bit  |  7  |  6  |  5  |  4  |  3  |  2  |  1  |  0  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| Digital pin # |  7  |  6  |  5  |  4  |  3  |  2  |  9  |  8  |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+
| MEGA port/pin | PH4 | PH3 | PE3 | PG5 | PE5 | PE4 | PH6 | PH5 |
+---------------+-----+-----+-----+-----+-----+-----+-----+-----+

วิธีดำเนินการต่อคือสร้างสเปรดชีตที่แสดงตำแหน่งพินที่ใช้โดยบอร์ดนี้และสัญญาณ Arduino Shield ที่พวกเขาเสียบเข้า ถัดจากสิ่งเหล่านี้คุณต้องมีคอลัมน์ที่แสดงสัญญาณจริงใน ATMega2560 (สำหรับ Mega2560) และ ATMega328 (สำหรับ Uno) ที่หมุดโล่เหล่านี้ติดอยู่ คุณสามารถรับข้อมูลนี้ได้จากแผนผังแบบ Uno และ Mega2560

ในลักษณะที่รวดเร็วดูเหมือนว่า Arduino Shield pin ชื่อสำหรับ Uno และ Mega เหมือนกัน: ตัวอย่างเช่น shield pin '0' (ศูนย์ดิจิตอล) อยู่ในตำแหน่งเดียวกันบนทั้งสองแผงและเหมือนกันสำหรับหมุดอื่น ๆ

อย่างไรก็ตามใน Uno digital-0 นั้นเชื่อมต่อกับ ATMega328 Port D bit 0 ในขณะที่ Mega2560 นั้นจะแนบกับ ATMega2560 Port E bit 0 และสิ่งต่างๆจะเพิ่มความน่าเบื่อด้วย Digital 2..7

ตอนนี้เมื่อ twiddling bits แยกกันโดยใช้ digitalWrite (pin, value) ไลบรารี Arduino ไม่ต้องสงสัยเลยที่จะดูแลการแปลไปยังพอร์ต / บิตที่เหมาะสมซึ่งจำเป็นต้องตั้งค่าสำหรับชิป ATMega และบอร์ด Arduino ที่ใช้งานอยู่ อย่างไรก็ตามไลบรารีที่ใช้ฟังก์ชั่นระดับล่าง (โดยเฉพาะอย่างยิ่งหากจำเป็นต้องเขียนทั้งไบต์ไปยังพอร์ตเนื่องจากไลบรารี LCD ที่รวดเร็วอาจต้องใช้ขั้นตอนของตนเองในการแปลนี้

ดังนั้น ... ขั้นตอนแรกคือการตรวจสอบว่ามีไลบรารี่ไดรเวอร์ LCD แยกต่างหากสำหรับ Mega2560 หรือไม่

จากนั้นตรวจสอบว่าห้องสมุดของคุณมีรหัสเริ่มต้นที่ควรกำหนดว่าบอร์ดใดที่ทำงานอยู่ (และบอร์ดของคุณรวมอยู่ด้วยหรือไม่) หรือกำหนดให้คุณตั้งค่าสถานะเพื่อแจ้งให้ทราบว่าบอร์ดนั้นใช้งานอยู่หรือไม่

ความล้มเหลวนั้นคุณสามารถสร้างจัมเปอร์จัมเปอร์หรือรูปแบบการเดินสายอื่น ๆ เพื่อจัมเปอร์สัญญาณของ ATMega2560 ของ Mega เพื่อให้มีสายเหมือน Uno ไม่ชัดเจนว่าเป็นไปได้เนื่องจาก Port D ของ ATMega2560 บางตัวไม่ได้ต่อสายเข้ากับส่วนหัว

หรือคุณสามารถดูซอร์สโค้ดของไลบรารีและดูว่ามันทำอะไรอยู่จริง ๆ และสิ่งที่ต้องทำในการใช้งาน ATMega 2560 หมุดที่โล่เชื่อมต่อนั้นแตกต่างกัน

คุณตรวจสอบหน้าแรกของห้องสมุดแล้วหรือยัง หน้าห้องสมุดของ Henning Karlsen

เขาได้สร้างคู่มือผู้ใช้สำหรับห้องสมุด นอกจากนี้ยังมีการอ้างอิงถึงสิ่งที่พินไปที่ที่อยู่ในเอกสารข้อกำหนด

คุณต้องเปรียบเทียบฟังก์ชั่นพินระหว่าง Mega และ Uno ของเพื่อน จากนั้นคุณต้องทำให้การเชื่อมต่อไฟฟ้าเกิดขึ้น ฉันพูดคุยเกี่ยวกับเรื่องนี้เล็ก ๆ น้อย ๆ ในส่วน "สถานที่ขา" ของคำตอบของฉันที่นี่

ต้องมี "การแฮ็ก" สิ่งที่ต้องทำเพื่อกำหนดเส้นทางการเชื่อมต่อทางกายภาพเหล่านั้นใหม่ โดยปกติฉันใช้ตัวป้องกันระดับกลางเพื่อแปลพินตามต้องการ มีเกราะที่สร้างขึ้นมาเพื่อจุดประสงค์นี้โดยเฉพาะ แต่ฉันหามันไม่เจอ บางทีอันนี้อาจใช้งานได้ ?