ใครเป็นผู้สร้างขั้นตอน (SQL Server 2008 R2)

มีวิธีในรายการที่สร้างการจัดหาใน SQL Server 2008 หรือไม่?

ในลิงค์ SO นี้มีคำตอบบางส่วน แต่เมื่อ 6 ปีที่แล้ว

ฉันรู้ว่าเป็นวิธีที่ดีที่สุดในการเขียนชื่อและวันที่ของคุณจากนั้นเริ่มสร้างขั้นตอน แต่ฉันไม่เห็นสิ่งนี้ที่ฉันทำงาน

หากไม่มีวิธีในการทำเช่นนี้งานนี้จะถูกกระตุ้นด้วยทริกเกอร์หรือไม่?

และคำถามโบนัส เป็นงานของ dba หรือไม่ รู้ว่าใครเป็นผู้สร้าง

ขอบคุณมาก.

ใช่มีวิธี

ตารางเพื่อเก็บผลลัพธ์ของทริกเกอร์

USE [SOME_DATABASE]
GO

CREATE TABLE [dbo].[ddl_objects_log](
    [date] [datetime] NULL DEFAULT (getdate()),
    [login_name] [nvarchar](128) NULL,
    [nt_user_name] [nvarchar](128) NULL,
    [program_name] [nvarchar](128) NULL,
    [host_name] [nvarchar](128) NULL,
    [text] [xml] NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]

GO

ทริกเกอร์

USE [SOME_DATABASE]
GO

/****** Object:  DdlTrigger [ddl_db_trigger]    Script Date: 22/01/2015 13:41:38 ******/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

CREATE TRIGGER [ddl_db_trigger]
ON DATABASE
FOR CREATE_FUNCTION,
    CREATE_PROCEDURE,
    CREATE_TABLE,
    CREATE_TRIGGER,
    CREATE_VIEW,
    ALTER_FUNCTION,
    ALTER_PROCEDURE,
    ALTER_TABLE,
    ALTER_TRIGGER,
    ALTER_VIEW,
    DROP_FUNCTION,
    DROP_PROCEDURE,
    DROP_TABLE,
    DROP_TRIGGER,
    DROP_VIEW,
    CREATE_INDEX,
    ALTER_INDEX,
    DROP_INDEX
AS 
BEGIN
set nocount ON
    insert into ddl_objects_log(login_name, nt_user_name, program_name, host_name, text)
    select login_name, nt_user_name, program_name, host_name, EVENTDATA() from sys.dm_exec_sessions WITH(NOLOCK) where session_id=@@SPID
set nocount OFF
END

GO

ENABLE TRIGGER [ddl_db_trigger] ON DATABASE
GO

Query to Audit ผลลัพธ์ของทริกเกอร์

USE [SOME_DATABASE]
GO


SELECT top 10
REPLACE(CONVERT(VARCHAR(250), text.query('data(/EVENT_INSTANCE/PostTime)')),'T', ' ') as modify_datetime,
CONVERT(VARCHAR(215), text.query('data(/EVENT_INSTANCE/EventType)')) as event_type,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ServerName)')) as server_name,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/DatabaseName)')) as database_name,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectType)')) as object_type,
CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectName)')) as object_name,
CONVERT(VARCHAR(215), text.query('data(/EVENT_INSTANCE/UserName)')) as user_name,
Login_name,
CONVERT(VARCHAR(MAX), text.query('data(/EVENT_INSTANCE/TSQLCommand/CommandText)')) as command_text
FROM [SOME_DATABASE].[dbo].[ddl_objects_log]
where CONVERT(VARCHAR(225), text.query('data(/EVENT_INSTANCE/ObjectName)')) like '%SOME_STORED_PROCEDURE%'
order by date desc
GO

DBA อื่นอาจมีความเห็นที่แตกต่างกัน แต่ฉันคิดว่าการเตรียมข้อมูลนี้ให้พร้อมเป็นสิ่งสำคัญสำหรับ DBA

หากคุณมีการเปิดใช้งานการติดตามเริ่มต้นและยังไม่ได้ผ่านไปคุณสามารถใช้มันเพื่อค้นหาผู้ที่สร้าง SP

/*
    Object Altered
    Object Created
    Object Deleted 
*/

SELECT  TE.name ,

        v.subclass_name ,

        DB_NAME(t.DatabaseId) AS DBName ,

        T.NTDomainName ,

        t.NTUserName ,

        t.HostName ,

        t.ApplicationName ,

        t.LoginName ,

        t.Duration ,

        t.StartTime ,

        t.ObjectName ,

        CASE t.ObjectType

          WHEN 8259 THEN 'Check Constraint'

          WHEN 8260 THEN 'Default (constraint or standalone)'

          WHEN 8262 THEN 'Foreign-key Constraint'

          WHEN 8272 THEN 'Stored Procedure'

          WHEN 8274 THEN 'Rule'

          WHEN 8275 THEN 'System Table'

          WHEN 8276 THEN 'Trigger on Server'

          WHEN 8277 THEN '(User-defined) Table'

          WHEN 8278 THEN 'View'

          WHEN 8280 THEN 'Extended Stored Procedure'

          WHEN 16724 THEN 'CLR Trigger'

          WHEN 16964 THEN 'Database'

          WHEN 16975 THEN 'Object'

          WHEN 17222 THEN 'FullText Catalog'

          WHEN 17232 THEN 'CLR Stored Procedure'

          WHEN 17235 THEN 'Schema'

          WHEN 17475 THEN 'Credential'

          WHEN 17491 THEN 'DDL Event'

          WHEN 17741 THEN 'Management Event'

          WHEN 17747 THEN 'Security Event'

          WHEN 17749 THEN 'User Event'

          WHEN 17985 THEN 'CLR Aggregate Function'

          WHEN 17993 THEN 'Inline Table-valued SQL Function'

          WHEN 18000 THEN 'Partition Function'

          WHEN 18002 THEN 'Replication Filter Procedure'

          WHEN 18004 THEN 'Table-valued SQL Function'

          WHEN 18259 THEN 'Server Role'

          WHEN 18263 THEN 'Microsoft Windows Group'

          WHEN 19265 THEN 'Asymmetric Key'

          WHEN 19277 THEN 'Master Key'

          WHEN 19280 THEN 'Primary Key'

          WHEN 19283 THEN 'ObfusKey'

          WHEN 19521 THEN 'Asymmetric Key Login'

          WHEN 19523 THEN 'Certificate Login'

          WHEN 19538 THEN 'Role'

          WHEN 19539 THEN 'SQL Login'

          WHEN 19543 THEN 'Windows Login'

          WHEN 20034 THEN 'Remote Service Binding'

          WHEN 20036 THEN 'Event Notification on Database'

          WHEN 20037 THEN 'Event Notification'

          WHEN 20038 THEN 'Scalar SQL Function'

          WHEN 20047 THEN 'Event Notification on Object'

          WHEN 20051 THEN 'Synonym'

          WHEN 20549 THEN 'End Point'

          WHEN 20801 THEN 'Adhoc Queries which may be cached'

          WHEN 20816 THEN 'Prepared Queries which may be cached'

          WHEN 20819 THEN 'Service Broker Service Queue'

          WHEN 20821 THEN 'Unique Constraint'

          WHEN 21057 THEN 'Application Role'

          WHEN 21059 THEN 'Certificate'

          WHEN 21075 THEN 'Server'

          WHEN 21076 THEN 'Transact-SQL Trigger'

          WHEN 21313 THEN 'Assembly'

          WHEN 21318 THEN 'CLR Scalar Function'

          WHEN 21321 THEN 'Inline scalar SQL Function'

          WHEN 21328 THEN 'Partition Scheme'

          WHEN 21333 THEN 'User'

          WHEN 21571 THEN 'Service Broker Service Contract'

          WHEN 21572 THEN 'Trigger on Database'

          WHEN 21574 THEN 'CLR Table-valued Function'

          WHEN 21577

          THEN 'Internal Table (For example, XML Node Table, Queue Table.)'

          WHEN 21581 THEN 'Service Broker Message Type'

          WHEN 21586 THEN 'Service Broker Route'

          WHEN 21587 THEN 'Statistics'

          WHEN 21825 THEN 'User'

          WHEN 21827 THEN 'User'

          WHEN 21831 THEN 'User'

          WHEN 21843 THEN 'User'

          WHEN 21847 THEN 'User'

          WHEN 22099 THEN 'Service Broker Service'

          WHEN 22601 THEN 'Index'

          WHEN 22604 THEN 'Certificate Login'

          WHEN 22611 THEN 'XMLSchema'

          WHEN 22868 THEN 'Type'

          ELSE 'Hmmm???'

        END AS ObjectType

FROM    [fn_trace_gettable](CONVERT(VARCHAR(150), ( SELECT TOP 1

                                                            value

                                                    FROM    [fn_trace_getinfo](NULL)

                                                    WHERE   [property] = 2

                                                  )), DEFAULT) T

        JOIN sys.trace_events TE ON T.EventClass = TE.trace_event_id

        JOIN sys.trace_subclass_values v ON v.trace_event_id = TE.trace_event_id

                                            AND v.subclass_value = t.EventSubClass

WHERE   TE.name IN ( 'Object:Created', 'Object:Deleted', 'Object:Altered' )

                -- filter statistics created by SQL server                                         

        AND t.ObjectType NOT IN ( 21587 )

                -- filter tempdb objects

        AND DatabaseID <> 2

                -- get only events in the past 24 hours

        AND StartTime > DATEADD(HH, -24, GETDATE())

ORDER BY t.StartTime DESC ;

คลิกที่นี่เพื่อดูภาพขยาย

เป็นงานของ dba หรือไม่ เพื่อทราบว่าใครเป็นผู้สร้างสิ่งที่อยู่ภายใน sql

ขึ้นอยู่กับสาเหตุที่คุณต้องการทราบว่าวัตถุถูกสร้าง / แก้ไขหรือหลุด คุณสามารถใช้การแจ้งเตือนเหตุการณ์เพื่อเข้าสู่ระบบและแจ้งให้คุณทราบหากคุณรู้สึกว่าวัตถุนั้นถูกสร้าง / วางหรือเปลี่ยนแปลงโดยผู้ใช้ที่ไม่ได้รับอนุญาต ตรวจสอบให้แน่ใจว่าคุณมีตัวกรองที่เหมาะสม

เพื่อความสมบูรณ์ของคำตอบนี้ฉันต้องการพูดถึง - ข้อมูลเหตุการณ์ใดที่ฉันจะได้รับจากค่าเริ่มต้นจาก SQL Server จากแอรอนเบอร์ทรานด์

ฉันมาสาย แต่ฉัน "ทำ" ความปลอดภัยและสิ่งต่าง ๆ ในการดูแล *

เป็นงานของ dba หรือไม่ เพื่อทราบว่าใครเป็นผู้สร้างสิ่งที่อยู่ภายใน sql

ใช่ มันเป็นสิ่งสำคัญที่จะมีหรือสร้างบันทึกเหล่านี้ทุกที่ที่เป็นไปได้ อย่างไรก็ตามเป็นความรับผิดชอบของคุณในมุมมองของฉันที่จะไม่ "เปิดกล่องนี้" จนกว่ามันจะกลายเป็นสิ่งสำคัญ พูดอีกอย่างคือในมุมมองของฉัน - เป็นหน้าที่ของคุณที่จะให้ข้อมูลซื้อคืนตรวจสอบให้แน่ใจว่าได้รับความปลอดภัยตรวจสอบให้แน่ใจว่าได้ปรับ ... แล้วพักให้ห่างจากข้อมูลภายในเว้นแต่คุณจะถูกเรียกให้มาโดยเฉพาะ ดูมันหรือถ้ามันไม่จำเป็นต้องใช้เพื่อให้บรรลุเป้าหมายของคุณ

ความเห็นของฉันและมุมมองของฉัน แต่ฉันได้จัดการกับข้อมูลที่ละเอียดอ่อนและเป็นความลับเป็นเวลาหลายปีและทำให้มันแทบจะไม่เคย [1] "เปิดกล่อง" เพราะสิ่งนี้ทำให้ความไว้วางใจของผู้ใช้ลดลง

ตอนนี้ให้ฉันใช้เส้นทางที่แตกต่าง : ถ้าไม่มีใครสามารถคิดได้อย่างรวดเร็วว่าขั้นตอนการตอบสนองต่อกรณีขอบ? สิ่งที่อาจใช้เวลาคุณหรือฉันชั่วโมงเพื่อไขปริศนาอาจใช้เวลาสักครู่ผู้เขียน: "อ่าใช่สิ่งนี้ล้มเหลวเมื่อ ... "

1. มีข้อยกเว้นเพียงข้อเดียวเท่านั้น ในปี 2007 หรือมากกว่านั้นฉันสังเกตเห็นกิจกรรมเครือข่ายมากมายในส่วนนี้ ฉันปล่อยให้มันไปหนึ่งวันแล้วตรวจสอบเพราะมันมาจากเครื่องจักรของคนที่ดูเหมือนจะออกจากสำนักงานมากกว่าในวันที่เธอถามเธอไปครึ่งวันดังนั้นมือของฉันถูกบังคับ . ปรากฎว่าเธอกำลังดาวน์โหลดซีดีจาก Limewire และ Bearshare สำหรับงานแต่งงานที่กำลังจะมาถึง ฉันส่งต่อให้เจ้านายของเธอเพื่อพูดคุย เขาตัดสินใจที่จะไม่ทำอะไรเลย แต่ฉันคิดว่าอย่างน้อยเขาก็ควรรู้เพราะมันทำให้องค์กรเสี่ยงต่อการถูกดำเนินคดี