ได้รับขั้นตอนการจัดเก็บ (ง่าย) เช่นนี้:
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
ENDหากSaleตารางมีขนาดใหญ่SELECTอาจใช้เวลาดำเนินการนานเนื่องจากเครื่องมือเพิ่มประสิทธิภาพไม่สามารถปรับให้เหมาะสมเนื่องจากตัวแปรท้องถิ่น เราทดสอบการใช้ชิ้นSELECTส่วนด้วยตัวแปรจากนั้นจึงกำหนดวันที่ฮาร์ดโค้ดและเวลาดำเนินการเริ่มจาก ~ 9 นาทีถึง ~ 1 วินาที
เรามีขั้นตอนการจัดเก็บจำนวนมากที่ค้นหาตามช่วงวันที่ "คงที่" (สัปดาห์, เดือน, 8 สัปดาห์เป็นต้น) ดังนั้นพารามิเตอร์อินพุตเป็นเพียง @endDate และ @startDate จะถูกคำนวณภายในขั้นตอน
คำถามคือวิธีปฏิบัติที่ดีที่สุดในการหลีกเลี่ยงตัวแปรในส่วนคำสั่ง WHERE เพื่อที่จะไม่ประนีประนอมกับเครื่องมือเพิ่มประสิทธิภาพคืออะไร?
ความเป็นไปได้ที่เราเกิดขึ้นมีดังต่อไปนี้ มีวิธีปฏิบัติที่ดีที่สุดเหล่านี้หรือมีวิธีอื่นหรือไม่
ใช้โพรซีเดอร์ wrapper เพื่อเปลี่ยนตัวแปรเป็นพารามิเตอร์
พารามิเตอร์ไม่ส่งผลกระทบต่อเครื่องมือเพิ่มประสิทธิภาพเช่นเดียวกับตัวแปรท้องถิ่นทำ
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
EXECUTE DateRangeProc @startDate, @endDate
END
CREATE PROCEDURE DateRangeProc(@startDate DATE, @endDate DATE)
AS
BEGIN
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
ENDใช้ SQL แบบไดนามิกที่กำหนดพารามิเตอร์
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
DECLARE @sql NVARCHAR(4000) = N'
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
'
DECLARE @param NVARCHAR(4000) = N'@startDate DATE, @endDate DATE'
EXECUTE sp_executesql @sql, @param, @startDate = @startDate, @endDate = @endDate
ENDใช้ SQL แบบไดนามิก "กำหนดตายยาก"
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
DECLARE @startDate DATE = DATEADD(DAY, -6, @endDate)
DECLARE @sql NVARCHAR(4000) = N'
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
'
SET @sql = REPLACE(@sql, '@startDate', CONVERT(NCHAR(10), @startDate, 126))
SET @sql = REPLACE(@sql, '@endDate', CONVERT(NCHAR(10), @endDate, 126))
EXECUTE sp_executesql @sql
ENDใช้ DATEADD()ฟังก์ชั่นโดยตรง
ฉันไม่กระตือรือร้นในเรื่องนี้เพราะฟังก์ชั่นการโทรใน WHERE นั้นมีผลต่อประสิทธิภาพการทำงานด้วยเช่นกัน
CREATE PROCEDURE WeeklyProc(@endDate DATE)
AS
BEGIN
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN DATEADD(DAY, -6, @endDate) AND @endDate
ENDใช้พารามิเตอร์ทางเลือก
ฉันไม่แน่ใจว่าการกำหนดพารามิเตอร์จะมีปัญหาเช่นเดียวกับการกำหนดตัวแปรดังนั้นนี่อาจไม่ใช่ตัวเลือก ฉันไม่ชอบโซลูชันนี้ แต่รวมไว้เพื่อความสมบูรณ์
CREATE PROCEDURE WeeklyProc(@endDate DATE, @startDate DATE = NULL)
AS
BEGIN
SET @startDate = DATEADD(DAY, -6, @endDate)
SELECT
-- Stuff
FROM Sale
WHERE SaleDate BETWEEN @startDate AND @endDate
END- อัปเดต -
ขอบคุณสำหรับคำแนะนำและความคิดเห็น หลังจากอ่านพวกเขาฉันวิ่งทดสอบเวลาด้วยวิธีการต่างๆ ฉันกำลังเพิ่มผลลัพธ์ที่นี่เป็นข้อมูลอ้างอิง
Run 1 ไม่มีแผน Run 2 ทันทีหลังจาก Run 1 ด้วยพารามิเตอร์เดียวกันทั้งหมดดังนั้นจะใช้แผนจากการรัน 1
เวลา NoProc สำหรับการเรียกใช้แบบสอบถามแบบเลือกด้วยตนเองใน SSMS นอกกระบวนงานที่เก็บไว้
TestProc1-7 เป็นแบบสอบถามจากคำถามเดิม
TestProcA-B อิงตามคำแนะนำของMikael ErikssonEriksson คอลัมน์ในฐานข้อมูลคือ DATE ดังนั้นฉันจึงพยายามผ่านพารามิเตอร์เป็น DATETIME และรันด้วยการคัดเลือกโดยนัย (testProcA) และการคัดเลือกนักแสดงที่ชัดเจน (testProcB)
TestProcC-D ขึ้นอยู่กับข้อเสนอแนะของKenneth Fisherฟิชเชอร์ เราใช้ตารางการค้นหาวันที่สำหรับสิ่งอื่น ๆ อยู่แล้ว แต่เราไม่มีตารางที่มีคอลัมน์เฉพาะสำหรับแต่ละช่วงเวลา รูปแบบที่ฉันพยายามยังคงใช้ระหว่าง แต่ทำในตารางการค้นหาที่มีขนาดเล็กและรวมกับตารางขนาดใหญ่ ฉันจะตรวจสอบเพิ่มเติมว่าเราสามารถใช้ตารางการค้นหาเฉพาะได้หรือไม่แม้ว่าช่วงเวลาของเราจะได้รับการแก้ไขแล้ว
แถวทั้งหมดในตารางลดราคา: 136,424,366
Run 1 (ms) Run 2 (ms)
CPU Elapsed ข้อคิดเห็นที่ผ่านไปของ CPU
NoProc ค่าคงที่ 6567 62199 2870 719 แบบสอบถามด้วยตนเองด้วยค่าคงที่
ตัวแปร NoProc 9314 62424 3993 998 แบบสอบถามแบบแมนนวลพร้อมตัวแปร
testProc1 6801 62919 2871 736 ช่วงฮาร์ดโค้ด
testProc2 8955 63190 3915 979 พารามิเตอร์และช่วงตัวแปร
testProc3 8985 63152 3932 987 ขั้นตอน Wrapper พร้อมช่วงพารามิเตอร์
testProc4 9142 63939 3931 977 พารามิเตอร์ไดนามิก SQL
testProc5 7269 62933 2933 728 SQL แบบไดนามิกที่กำหนดรหัสฮาร์ด
testProc6 9266 63421 3915 984 ใช้ DATEADD เมื่อ DATE
testProc7 2044 13950 1092 1087 พารามิเตอร์ดัมมี
testProcA 12120 61493 5491 1875 ใช้ DATEADD ใน DATETIME โดยไม่ใช้ CAST
testProcB 8612 61949 3932 978 ใช้ DATEADD ใน DATETIME ด้วย CAST
testProcC 8861 61651 3917 993 ใช้ตารางการค้นหาขายก่อน
testProcD 8625 61740 3994 1031 ใช้ตารางการค้นหาขายครั้งสุดท้าย
นี่คือรหัสทดสอบ
------ SETUP ------
IF OBJECT_ID(N'testDimDate', N'U') IS NOT NULL DROP TABLE testDimDate
IF OBJECT_ID(N'testProc1', N'P') IS NOT NULL DROP PROCEDURE testProc1
IF OBJECT_ID(N'testProc2', N'P') IS NOT NULL DROP PROCEDURE testProc2
IF OBJECT_ID(N'testProc3', N'P') IS NOT NULL DROP PROCEDURE testProc3
IF OBJECT_ID(N'testProc3a', N'P') IS NOT NULL DROP PROCEDURE testProc3a
IF OBJECT_ID(N'testProc4', N'P') IS NOT NULL DROP PROCEDURE testProc4
IF OBJECT_ID(N'testProc5', N'P') IS NOT NULL DROP PROCEDURE testProc5
IF OBJECT_ID(N'testProc6', N'P') IS NOT NULL DROP PROCEDURE testProc6
IF OBJECT_ID(N'testProc7', N'P') IS NOT NULL DROP PROCEDURE testProc7
IF OBJECT_ID(N'testProcA', N'P') IS NOT NULL DROP PROCEDURE testProcA
IF OBJECT_ID(N'testProcB', N'P') IS NOT NULL DROP PROCEDURE testProcB
IF OBJECT_ID(N'testProcC', N'P') IS NOT NULL DROP PROCEDURE testProcC
IF OBJECT_ID(N'testProcD', N'P') IS NOT NULL DROP PROCEDURE testProcD
GO
CREATE TABLE testDimDate
(
DateKey DATE NOT NULL,
CONSTRAINT PK_DimDate_DateKey UNIQUE NONCLUSTERED (DateKey ASC)
)
GO
DECLARE @dateTimeStart DATETIME = '2000-01-01'
DECLARE @dateTimeEnd DATETIME = '2100-01-01'
;WITH CTE AS
(
--Anchor member defined
SELECT @dateTimeStart FullDate
UNION ALL
--Recursive member defined referencing CTE
SELECT FullDate + 1 FROM CTE WHERE FullDate + 1 <= @dateTimeEnd
)
SELECT
CAST(FullDate AS DATE) AS DateKey
INTO #DimDate
FROM CTE
OPTION (MAXRECURSION 0)
INSERT INTO testDimDate (DateKey)
SELECT DateKey FROM #DimDate ORDER BY DateKey ASC
DROP TABLE #DimDate
GO
-- Hard coded date range.
CREATE PROCEDURE testProc1 AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN '2012-12-09' AND '2012-12-10'
END
GO
-- Parameter and variable date range.
CREATE PROCEDURE testProc2(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
END
GO
-- Parameter date range.
CREATE PROCEDURE testProc3a(@startDate DATE, @endDate DATE) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
END
GO
-- Wrapper procedure.
CREATE PROCEDURE testProc3(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
EXEC testProc3a @startDate, @endDate
END
GO
-- Parameterized dynamic SQL.
CREATE PROCEDURE testProc4(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
DECLARE @sql NVARCHAR(4000) = N'SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate'
DECLARE @param NVARCHAR(4000) = N'@startDate DATE, @endDate DATE'
EXEC sp_executesql @sql, @param, @startDate = @startDate, @endDate = @endDate
END
GO
-- Hard coded dynamic SQL.
CREATE PROCEDURE testProc5(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
DECLARE @sql NVARCHAR(4000) = N'SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN ''@startDate'' AND ''@endDate'''
SET @sql = REPLACE(@sql, '@startDate', CONVERT(NCHAR(10), @startDate, 126))
SET @sql = REPLACE(@sql, '@endDate', CONVERT(NCHAR(10), @endDate, 126))
EXEC sp_executesql @sql
END
GO
-- Explicitly use DATEADD on a DATE.
CREATE PROCEDURE testProc6(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN DATEADD(DAY, -1, @endDate) AND @endDate
END
GO
-- Dummy parameter.
CREATE PROCEDURE testProc7(@endDate DATE, @startDate DATE = NULL) AS
BEGIN
SET NOCOUNT ON
SET @startDate = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
END
GO
-- Explicitly use DATEADD on a DATETIME with implicit CAST for comparison with SaleDate.
-- Based on the answer from Mikael Eriksson.
CREATE PROCEDURE testProcA(@endDateTime DATETIME) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN DATEADD(DAY, -1, @endDateTime) AND @endDateTime
END
GO
-- Explicitly use DATEADD on a DATETIME but CAST to DATE for comparison with SaleDate.
-- Based on the answer from Mikael Eriksson.
CREATE PROCEDURE testProcB(@endDateTime DATETIME) AS
BEGIN
SET NOCOUNT ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN CAST(DATEADD(DAY, -1, @endDateTime) AS DATE) AND CAST(@endDateTime AS DATE)
END
GO
-- Use a date lookup table, Sale first.
-- Based on the answer from Kenneth Fisher.
CREATE PROCEDURE testProcC(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM Sale J INNER JOIN testDimDate D ON D.DateKey = J.SaleDate WHERE D.DateKey BETWEEN @startDate AND @endDate
END
GO
-- Use a date lookup table, Sale last.
-- Based on the answer from Kenneth Fisher.
CREATE PROCEDURE testProcD(@endDate DATE) AS
BEGIN
SET NOCOUNT ON
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
SELECT SUM(Value) FROM testDimDate D INNER JOIN Sale J ON J.SaleDate = D.DateKey WHERE D.DateKey BETWEEN @startDate AND @endDate
END
GO
------ TEST ------
SET STATISTICS TIME OFF
DECLARE @endDate DATE = '2012-12-10'
DECLARE @startDate DATE = DATEADD(DAY, -1, @endDate)
DBCC FREEPROCCACHE WITH NO_INFOMSGS
DBCC DROPCLEANBUFFERS WITH NO_INFOMSGS
RAISERROR('Run 1: NoProc with constants', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN '2012-12-09' AND '2012-12-10'
SET STATISTICS TIME OFF
RAISERROR('Run 2: NoProc with constants', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN '2012-12-09' AND '2012-12-10'
SET STATISTICS TIME OFF
DBCC FREEPROCCACHE WITH NO_INFOMSGS
DBCC DROPCLEANBUFFERS WITH NO_INFOMSGS
RAISERROR('Run 1: NoProc with variables', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
SET STATISTICS TIME OFF
RAISERROR('Run 2: NoProc with variables', 0, 0) WITH NOWAIT
SET STATISTICS TIME ON
SELECT SUM(Value) FROM Sale WHERE SaleDate BETWEEN @startDate AND @endDate
SET STATISTICS TIME OFF
DECLARE @sql NVARCHAR(4000)
DECLARE _cursor CURSOR LOCAL FAST_FORWARD FOR
SELECT
procedures.name,
procedures.object_id
FROM sys.procedures
WHERE procedures.name LIKE 'testProc_'
ORDER BY procedures.name ASC
OPEN _cursor
DECLARE @name SYSNAME
DECLARE @object_id INT
FETCH NEXT FROM _cursor INTO @name, @object_id
WHILE @@FETCH_STATUS = 0
BEGIN
SET @sql = CASE (SELECT COUNT(*) FROM sys.parameters WHERE object_id = @object_id)
WHEN 0 THEN @name
WHEN 1 THEN @name + ' ''@endDate'''
WHEN 2 THEN @name + ' ''@startDate'', ''@endDate'''
END
SET @sql = REPLACE(@sql, '@name', @name)
SET @sql = REPLACE(@sql, '@startDate', CONVERT(NVARCHAR(10), @startDate, 126))
SET @sql = REPLACE(@sql, '@endDate', CONVERT(NVARCHAR(10), @endDate, 126))
DBCC FREEPROCCACHE WITH NO_INFOMSGS
DBCC DROPCLEANBUFFERS WITH NO_INFOMSGS
RAISERROR('Run 1: %s', 0, 0, @sql) WITH NOWAIT
SET STATISTICS TIME ON
EXEC sp_executesql @sql
SET STATISTICS TIME OFF
RAISERROR('Run 2: %s', 0, 0, @sql) WITH NOWAIT
SET STATISTICS TIME ON
EXEC sp_executesql @sql
SET STATISTICS TIME OFF
FETCH NEXT FROM _cursor INTO @name, @object_id
END
CLOSE _cursor
DEALLOCATE _cursor