คุณจะเตะผู้ใช้ออกจากฐานข้อมูล SQL Server 2008 ได้อย่างไร

เราจำเป็นต้องทำการกู้คืนและไม่สามารถทำได้เนื่องจากผู้ใช้รายอื่นเชื่อมต่ออยู่ เราคิดว่าเราตัดการเชื่อมต่อทุกขั้นตอน แต่ดูเหมือนจะไม่

จาก Studio Management เราจะเริ่มต้นกับคนอื่นได้อย่างไรเพื่อให้เราสามารถสำรองข้อมูลนี้ได้

การทำมีสองวิธี:

1. คลิกขวาที่ฐานข้อมูลใน Object Explorer ไปที่ Tasks> Detach เลือกช่องทำเครื่องหมายปล่อยการเชื่อมต่อ

2. ตั้งค่าฐานข้อมูลเป็นโหมดผู้ใช้คนเดียวดังที่แสดงไว้ที่นี่ :

   -- hit Ctrl+Shift+M in SSMS to fill in the template parameter
   USE master;
   GO
   
   ALTER DATABASE N'<Database Name, sysname,>'
   SET SINGLE_USER
   WITH ROLLBACK IMMEDIATE;
   GO
   
   ALTER DATABASE N'<Database Name, sysname,>'
   SET READ_ONLY;
   GO
   
   ALTER DATABASE N'<Database Name, sysname,>'
   SET MULTI_USER;
   GO

ฉันมักจะใช้สิ่งต่อไปนี้:

USE master; -- get out of dbname myself
GO
-- kick all other users out:
ALTER DATABASE [dbname] SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
GO
-- prevent sessions from re-establishing connection:
ALTER DATABASE [dbname] SET OFFLINE;

บางครั้งอาจใช้เวลาสักครู่และบางครั้งมันก็ถูกบล็อกเพราะคุณเป็นคนที่ทำงานและคุณมีการเชื่อมต่อใช้งานกับฐานข้อมูล ตรวจสอบหน้าต่างคิวรีอื่นที่อาจมีบริบทฐานข้อมูลเดียวกันซึ่งอาจรวมถึงไดอะล็อกเปิด, Object Explorer, IntelliSense, งานที่รันนาน ฯลฯ

เมื่อฉันทำการเปลี่ยนแปลงการตั้งค่าฐานข้อมูลของฉันเสร็จแล้วฉันก็:

ALTER DATABASE [dbname] SET ONLINE;
ALTER DATABASE [dbname] SET MULTI_USER;

แม้ว่าบางครั้งสิ่งที่ฉันต้องทำกับฐานข้อมูลนั้นต้องมีฐานข้อมูลออนไลน์ดังนั้นบางครั้งฉันต้องปล่อยไว้ในโหมดผู้ใช้คนเดียวและทำสิ่งนี้:

ALTER DATABASE [dbname] SET ONLINE;
GO
USE [dbname];

ตอนนี้ฉันสามารถทำการเปลี่ยนแปลงของฉันแล้วเมื่อฉันพร้อมให้ผู้ใช้รายอื่นเชื่อมต่อได้อย่างง่ายดาย:

ALTER DATABASE [dbname] SET MULTI_USER;

ปกติฉันจะตั้งค่าฐานข้อมูลใน single_user แล้วรอการหน่วงเวลาจากนั้นตั้งค่าฐานข้อมูลกลับเป็นผู้ใช้หลายคนดังต่อไปนี้:

-- to kill all connections for particular db ... otherwise the restore will fail as exclusive lock cannot be obtained for the db being restored.

    alter database db_name
    set single_user with rollback immediate
    waitfor delay '00:00:05'  -- wait for 5 secs
    alter database db_name
    set multi_user
    restore database db_name from disk = 'D:\restore\db_name.bak'
    with replace, stats = 10, recovery -- if you want to recover your database online
    -- optional if you dont have the same directory/file structure
    move 'datafile logical name' to 'E:\data\physical_name.mdf',
    move 'logfile logical name' to 'F:\log\physical_name_log.ldf'

ไม่มีตัวเลือกใด ๆ ที่ได้ผลสำหรับฉันเพราะเซิร์ฟเวอร์ใช้การเชื่อมต่อระยะไกลหลายครั้ง

เมื่อฉันปิดพอร์ตฐานข้อมูลเฉพาะบนไฟร์วอลล์ windows Alter ปกติ .. การตั้งค่า Multi_User ทำงานได้ในครั้งแรก

ต่อไปนี้จะฆ่าทุกการเชื่อมต่อ ค่อนข้างมีประโยชน์ในกรณีที่การตั้งค่าโหมดผู้ใช้คนเดียวล้มเหลว

declare @execSql varchar(1000), @databaseName varchar(100)
-- Set the database name for which to kill the connections
set @databaseName = 'databasename'
set @execSql = '' 
select  @execSql = @execSql + 'kill ' + convert(char(10), spid) + ' '
from    master.dbo.sysprocesses
where   db_name(dbid) = @databaseName
     and
     DBID <> 0
     and
     spid <> @@spid
exec(@execSql)

คุณสามารถใช้สคริปต์ด้านล่างเพื่อทำนุกทุกคนหรือแก้ไขสำหรับฐานข้อมูลเฉพาะ

อะไรก็ตามที่สามารถฆ่าได้จะเป็น! SPID ของบริการ SQL อย่างไรก็ตามจะไม่ได้รับผลกระทบ

Drop table #who

go 

Create table #who(  [spid] int,
                    [ECID] int,
                    [Status] varchar(100),
                    [Loginname] varchar(200),
                    [Hostname] varchar(200),
                    [blk] bit,
                    dbname varchar(200),
                    cmd varchar(1000),
                    requestID int
                  )

go

Insert into #who (Spid, ECID, Status, Loginname, hostname,blk, dbname, cmd, requestid)
exec sp_who

Declare cursKillUsers Cursor for Select 'Kill ' + cast(spid as varchar(100)) + ';' [SQL] from #who where dbname like '%'
Declare @sql varchar(200)
Open cursKillUsers
Fetch next from cursKillUsers into @sql
While @@fetch_status = 0 
begin

    print @sql
    Exec (@sql)
    Fetch next from cursKillUsers into @sql

end

close cursKillUsers
deallocate cursKillUsers

ฉันใช้รหัสนี้:

ALTER DATABASE [Dbname] set offline with rollback immediate
GO
ALTER DATABASE [Dbname] set online
GO

แต่ฉันเห็นตัวอย่างผู้ใช้คนเดียวพิมพ์น้อยกว่า