จัดย่อหน้าคำหลักได้อย่างไร

อาจได้รับอิทธิพลจาก Clojure ฉันมักจะใช้รายการคุณสมบัติเป็นโครงสร้างข้อมูล ส่วนใหญ่ emacs เยื้องพวกเขาเช่นนี้

`(:token ,token
         :token-quality ,quality)  , 

ในขณะนี้คือสิ่งที่ฉันต้องการ

`(:token ,token
  :token-quality ,quality) . 

ดังนั้นฉันสงสัยว่าถ้าใครบางคนจัดการเรื่องนี้ไปแล้ว?

ที่สามารถทำได้โดยการเปลี่ยนโหมดlisp-indent-functionสำหรับ emacs-lisp:

(add-hook 'emacs-lisp-mode-hook
          (lambda () (setq-local lisp-indent-function #'common-lisp-indent-function)))

จากlisp-mode.elแหล่ง emacs

 (defcustom lisp-indent-function 'lisp-indent-function
  "A function to be called by `calculate-lisp-indent'.
It indents the arguments of a Lisp function call.  This function
should accept two arguments: the indent-point, and the
`parse-partial-sexp' state at that position.  One option for this
function is `common-lisp-indent-function'."
  :type 'function
  :group 'lisp)

ทางเลือก

ตามที่@wasamasaพูดถึงในความคิดเห็นต่อคำถาม@ Fuco1 (บน github.com) ได้แก้ไขค่าเริ่มต้นlisp-indent-functionเพื่อแก้ไขการเยื้องของคำหลัก (เริ่มต้นด้วย:)

Emacs ได้จัดเตรียมตัวแปรlisp-indent-functionสำหรับผู้ใช้ในการเลือกฟังก์ชันที่จะใช้สำหรับการเยื้องในโหมดเสียงกระเพื่อม

แทนที่จะแทนที่คำนิยามฟังก์ชั่นดั้งเดิมเราสามารถสร้างฟังก์ชั่นของเราเองและกำหนดตัวแปรข้างต้นให้กับชื่อฟังก์ชั่นนั้น

ในตัวอย่างนี้

• บันทึกฟังก์ชั่นที่ปรับเปลี่ยนของ Fuco1เป็นสิ่งที่คล้ายกับFuco1/lisp-indent-functionในการตั้งค่า emacs ของคุณ
• ใช้ประโยชน์จากฟังก์ชันนั้นเพื่อเยื้องในemacs-lisp-mode:

(add-hook 'emacs-lisp-mode-hook
          (lambda () (setq-local lisp-indent-function #'Fuco1/lisp-indent-function)))

การอ้างอิง

ฟังก์ชั่น modded จะถูกวางไว้ด้านล่างในกรณีที่แหล่งที่อ้างถึง GitHub หายไป

;; https://github.com/Fuco1/.emacs.d/blob/af82072196564fa57726bdbabf97f1d35c43b7f7/site-lisp/redef.el#L20-L94
(defun Fuco1/lisp-indent-function (indent-point state)
  "This function is the normal value of the variable `lisp-indent-function'.
The function `calculate-lisp-indent' calls this to determine
if the arguments of a Lisp function call should be indented specially.

INDENT-POINT is the position at which the line being indented begins.
Point is located at the point to indent under (for default indentation);
STATE is the `parse-partial-sexp' state for that position.

If the current line is in a call to a Lisp function that has a non-nil
property `lisp-indent-function' (or the deprecated `lisp-indent-hook'),
it specifies how to indent.  The property value can be:

* `defun', meaning indent `defun'-style
  \(this is also the case if there is no property and the function
  has a name that begins with \"def\", and three or more arguments);

* an integer N, meaning indent the first N arguments specially
  (like ordinary function arguments), and then indent any further
  arguments like a body;

* a function to call that returns the indentation (or nil).
  `lisp-indent-function' calls this function with the same two arguments
  that it itself received.

This function returns either the indentation to use, or nil if the
Lisp function does not specify a special indentation."
  (let ((normal-indent (current-column))
        (orig-point (point)))
    (goto-char (1+ (elt state 1)))
    (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
    (cond
     ;; car of form doesn't seem to be a symbol, or is a keyword
     ((and (elt state 2)
           (or (not (looking-at "\\sw\\|\\s_"))
               (looking-at ":")))
      (if (not (> (save-excursion (forward-line 1) (point))
                  calculate-lisp-indent-last-sexp))
          (progn (goto-char calculate-lisp-indent-last-sexp)
                 (beginning-of-line)
                 (parse-partial-sexp (point)
                                     calculate-lisp-indent-last-sexp 0 t)))
      ;; Indent under the list or under the first sexp on the same
      ;; line as calculate-lisp-indent-last-sexp.  Note that first
      ;; thing on that line has to be complete sexp since we are
      ;; inside the innermost containing sexp.
      (backward-prefix-chars)
      (current-column))
     ((and (save-excursion
             (goto-char indent-point)
             (skip-syntax-forward " ")
             (not (looking-at ":")))
           (save-excursion
             (goto-char orig-point)
             (looking-at ":")))
      (save-excursion
        (goto-char (+ 2 (elt state 1)))
        (current-column)))
     (t
      (let ((function (buffer-substring (point)
                                        (progn (forward-sexp 1) (point))))
            method)
        (setq method (or (function-get (intern-soft function)
                                       'lisp-indent-function)
                         (get (intern-soft function) 'lisp-indent-hook)))
        (cond ((or (eq method 'defun)
                   (and (null method)
                        (> (length function) 3)
                        (string-match "\\`def" function)))
               (lisp-indent-defform state indent-point))
              ((integerp method)
               (lisp-indent-specform method state
                                     indent-point normal-indent))
              (method
               (funcall method indent-point state))))))))

แนะนำการคำนวณ - เสียงกระเพื่อม

calculate-lisp-indentทางออกที่ดีคือการแทนที่ฟังก์ชั่น กล่าวโดยย่อcalculate-lisp-indentคือฟังก์ชั่นที่คืนค่าคอลัมน์ที่ควรระบุบรรทัดที่จุด ฟังก์ชั่นนี้เป็นสิ่งที่แจ้งให้ทราบlisp-indent-functionว่าแต่ละบรรทัดควรเยื้องเท่าใด (ดูโพสต์ของฉันใน Redditสำหรับข้อมูลเพิ่มเติม)

เปรียบเทียบกับคำตอบอื่น ๆ

ข้อได้เปรียบที่คำตอบนี้มีมากกว่าการใช้ฟังก์ชั่นที่ปรับเปลี่ยนของ Fuco1 คือ (1) แก้ไขปัญหาของรากซึ่งอยู่ในcalculate-lisp-indentแทนที่จะทำความสะอาดหลังจากการเยื้องที่ไม่ถูกต้องที่ส่งคืนโดยcalculate-lisp-indent(2) เป็นการสรุปรายการที่ยกมาและ backquote ทำงานไม่ว่าพวกเขาจะอ้าง / backquote อย่างชัดเจนหรือด้วย'และ `) มันยังทำงานร่วมกับคำพูดซ้อนและ backquotes โดยพลการ

ข้อดีคำตอบนี้มีมากกว่าการแทนที่lisp-indent-functionด้วยcommon-lisp-indent-functionฟังก์ชั่นคือมันไม่ได้มีผลข้างเคียงของการเยื้อง elisp อื่น ๆ Elisp และ lisp ทั่วไปมีการย่อหน้าที่แตกต่างกัน

มันทำงานอย่างไร

เงื่อนไข (ในcalculate-lisp-indent) นี้เป็นสิ่งที่ตัดสินใจว่า sexp ถูกเยื้องเช่นฟังก์ชั่นหรือไม่ สิ่งที่ตกอยู่ในข้ออื่นคือเยื้องเช่นฟังก์ชั่น สิ่งที่อยู่ในนั้นคือถ้าส่วนคำสั่งเยื้องตามปกติ (ภายใต้องค์ประกอบปัจจุบัน) เพื่อให้รายการที่ยกมาเยื้องเป็นข้อมูลแทนที่จะเป็นฟังก์ชั่นเราจำเป็นต้องเพิ่มการตรวจสอบเพิ่มเติมสำหรับกรณีที่รายการจะถูกยกมาในภาคแสดงเงื่อนไข

(if (= (point) calculate-lisp-indent-last-sexp)
    ;; Containing sexp has nothing before this line
    ;; except the first element.  Indent under that element.
    nil
  ;; Skip the first element, find start of second (the first
  ;; argument of the function call) and indent under.
  (progn (forward-sexp 1)
         (parse-partial-sexp (point)
                             calculate-lisp-indent-last-sexp
                             0 t)))

รหัสนี้จะตรวจสอบวงเล็บเปิดของ sexp ที่ถูกเยื้อง ถ้ามันเป็น sexp ด้วยหลาย sexp มันจะตรวจสอบพวกเขาทั้งหมด มันจะส่งกลับ t หากพบ sexps ใด ๆ ที่ยกมาหรือ backquote

(let* ((positions (elt state 9))
       (last (car (last positions)))
       (rest (nreverse (butlast positions)))
       (any-quoted-p nil)
       (point nil))
  (or
   (when-let (char last)
     (or (char-equal char ?')
         (char-equal char ?`)))
   (while (and rest (not any-quoted-p))
     (setq point (pop rest))
     (setq any-quoted-p
           (or
            (when-let (char point)
              (or (char-equal char ?')
                  (char-equal char ?`)))
            (save-excursion
              (goto-char (1+ point))
              (looking-at-p "\\(?:back\\)?quote[\t\n\f\s]+(")))))))

โบนัส

หากคุณต้องการให้รายการใด ๆ ที่ขึ้นต้นด้วยคำสำคัญถูกเยื้องเป็นข้อมูลแม้ว่าจะไม่ได้เพิ่มให้เพิ่มนี่เป็นการตรวจสอบอีกครั้งในเพรดิเคตตามเงื่อนไข ซึ่งอาจเป็นประโยชน์สำหรับแมโครที่ plists ไม่ได้ยกมาเพื่อความสะดวกสบายเช่นในdefhydra

(when-let (char-after (char-after (1+ containing-sexp)))
  (char-equal char-after ?:))

ตัวอย่าง

ข้อมูลโค้ดแบบเต็มที่ฉันโพสต์ไว้ด้านล่างใช้งานได้กับกรณีที่คุณพูดถึงและอีกมากมาย โปรดลอง!

;; Your example
`(:token ,token
  :token-quality ,quality)

;; Other cool examples
(quote (hi im gosu
        the best vayne player))

'(i am the phantom of
  the opera)

'((angel of music
   hide no longer))

(backquote (past the point
            no return
            ... the final chapter))

`(fee fi fo
  fum)

;; should indent it like a function.
(iamafunction arg1
              arg2
              arg3)

สำหรับคำอธิบายเพิ่มเติมในเชิงลึกของวิธีการทำงานนี้ดูโพสต์ของฉันใน Reddit

ข้อมูลโค้ดแบบเต็ม

นี่คือข้อมูลโค้ดแบบเต็ม

(advice-add #'calculate-lisp-indent :override #'void~calculate-lisp-indent)

(defun void~calculate-lisp-indent (&optional parse-start)
  "Add better indentation for quoted and backquoted lists."
  ;; This line because `calculate-lisp-indent-last-sexp` was defined with `defvar` 
  ;; with it's value ommited, marking it special and only defining it locally. So  
  ;; if you don't have this, you'll get a void variable error.
  (defvar calculate-lisp-indent-last-sexp)
  (save-excursion
    (beginning-of-line)
    (let ((indent-point (point))
          state
          ;; setting this to a number inhibits calling hook
          (desired-indent nil)
          (retry t)
          calculate-lisp-indent-last-sexp containing-sexp)
      (cond ((or (markerp parse-start) (integerp parse-start))
             (goto-char parse-start))
            ((null parse-start) (beginning-of-defun))
            (t (setq state parse-start)))
      (unless state
        ;; Find outermost containing sexp
        (while (< (point) indent-point)
          (setq state (parse-partial-sexp (point) indent-point 0))))
      ;; Find innermost containing sexp
      (while (and retry
                  state
                  (> (elt state 0) 0))
        (setq retry nil)
        (setq calculate-lisp-indent-last-sexp (elt state 2))
        (setq containing-sexp (elt state 1))
        ;; Position following last unclosed open.
        (goto-char (1+ containing-sexp))
        ;; Is there a complete sexp since then?
        (if (and calculate-lisp-indent-last-sexp
                 (> calculate-lisp-indent-last-sexp (point)))
            ;; Yes, but is there a containing sexp after that?
            (let ((peek (parse-partial-sexp calculate-lisp-indent-last-sexp
                                            indent-point 0)))
              (if (setq retry (car (cdr peek))) (setq state peek)))))
      (if retry
          nil
        ;; Innermost containing sexp found
        (goto-char (1+ containing-sexp))
        (if (not calculate-lisp-indent-last-sexp)
            ;; indent-point immediately follows open paren.
            ;; Don't call hook.
            (setq desired-indent (current-column))
          ;; Find the start of first element of containing sexp.
          (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
          (cond ((looking-at "\\s(")
                 ;; First element of containing sexp is a list.
                 ;; Indent under that list.
                 )
                ((> (save-excursion (forward-line 1) (point))
                    calculate-lisp-indent-last-sexp)
                 ;; This is the first line to start within the containing sexp.
                 ;; It's almost certainly a function call.
                 (if (or
                      ;; Containing sexp has nothing before this line
                      ;; except the first element. Indent under that element.
                      (= (point) calculate-lisp-indent-last-sexp)

                      ;; First sexp after `containing-sexp' is a keyword. This
                      ;; condition is more debatable. It's so that I can have
                      ;; unquoted plists in macros. It assumes that you won't
                      ;; make a function whose name is a keyword.
                      ;; (when-let (char-after (char-after (1+ containing-sexp)))
                      ;;   (char-equal char-after ?:))

                      ;; Check for quotes or backquotes around.
                      (let* ((positions (elt state 9))
                             (last (car (last positions)))
                             (rest (reverse (butlast positions)))
                             (any-quoted-p nil)
                             (point nil))
                        (or
                         (when-let (char (char-before last))
                           (or (char-equal char ?')
                               (char-equal char ?`)))
                         (progn
                           (while (and rest (not any-quoted-p))
                             (setq point (pop rest))
                             (setq any-quoted-p
                                   (or
                                    (when-let (char (char-before point))
                                      (or (char-equal char ?')
                                          (char-equal char ?`)))
                                    (save-excursion
                                      (goto-char (1+ point))
                                      (looking-at-p
                                       "\\(?:back\\)?quote[\t\n\f\s]+(")))))
                           any-quoted-p))))
                     ;; Containing sexp has nothing before this line
                     ;; except the first element.  Indent under that element.
                     nil
                   ;; Skip the first element, find start of second (the first
                   ;; argument of the function call) and indent under.
                   (progn (forward-sexp 1)
                          (parse-partial-sexp (point)
                                              calculate-lisp-indent-last-sexp
                                              0 t)))
                 (backward-prefix-chars))
                (t
                 ;; Indent beneath first sexp on same line as
                 ;; `calculate-lisp-indent-last-sexp'.  Again, it's
                 ;; almost certainly a function call.
                 (goto-char calculate-lisp-indent-last-sexp)
                 (beginning-of-line)
                 (parse-partial-sexp (point) calculate-lisp-indent-last-sexp
                                     0 t)
                 (backward-prefix-chars)))))
      ;; Point is at the point to indent under unless we are inside a string.
      ;; Call indentation hook except when overridden by lisp-indent-offset
      ;; or if the desired indentation has already been computed.
      (let ((normal-indent (current-column)))
        (cond ((elt state 3)
               ;; Inside a string, don't change indentation.
               nil)
              ((and (integerp lisp-indent-offset) containing-sexp)
               ;; Indent by constant offset
               (goto-char containing-sexp)
               (+ (current-column) lisp-indent-offset))
              ;; in this case calculate-lisp-indent-last-sexp is not nil
              (calculate-lisp-indent-last-sexp
               (or
                ;; try to align the parameters of a known function
                (and lisp-indent-function
                     (not retry)
                     (funcall lisp-indent-function indent-point state))
                ;; If the function has no special alignment
                ;; or it does not apply to this argument,
                ;; try to align a constant-symbol under the last
                ;; preceding constant symbol, if there is such one of
                ;; the last 2 preceding symbols, in the previous
                ;; uncommented line.
                (and (save-excursion
                       (goto-char indent-point)
                       (skip-chars-forward " \t")
                       (looking-at ":"))
                     ;; The last sexp may not be at the indentation
                     ;; where it begins, so find that one, instead.
                     (save-excursion
                       (goto-char calculate-lisp-indent-last-sexp)
                       ;; Handle prefix characters and whitespace
                       ;; following an open paren.  (Bug#1012)
                       (backward-prefix-chars)
                       (while (not (or (looking-back "^[ \t]*\\|([ \t]+"
                                                     (line-beginning-position))
                                       (and containing-sexp
                                            (>= (1+ containing-sexp) (point)))))
                         (forward-sexp -1)
                         (backward-prefix-chars))
                       (setq calculate-lisp-indent-last-sexp (point)))
                     (> calculate-lisp-indent-last-sexp
                        (save-excursion
                          (goto-char (1+ containing-sexp))
                          (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
                          (point)))
                     (let ((parse-sexp-ignore-comments t)
                           indent)
                       (goto-char calculate-lisp-indent-last-sexp)
                       (or (and (looking-at ":")
                                (setq indent (current-column)))
                           (and (< (line-beginning-position)
                                   (prog2 (backward-sexp) (point)))
                                (looking-at ":")
                                (setq indent (current-column))))
                       indent))
                ;; another symbols or constants not preceded by a constant
                ;; as defined above.
                normal-indent))
              ;; in this case calculate-lisp-indent-last-sexp is nil
              (desired-indent)
              (t
               normal-indent))))))

หมายเหตุสุดท้าย

มันเป็นที่น่าสังเกตว่าคำถามนี้จะได้รับการทั่วไปดีขึ้นเป็นวิธีที่จะหยุด emacs จากการเยื้องยกและรายการ unquoted เป็นฟังก์ชั่น

สำหรับทางเลือกที่แฮ็กเกอร์มากสำหรับคำตอบของ kaushalmodi คุณสามารถเขียนทับสิ่งที่lisp-indent-functionคล้ายกับสิ่งที่ Mark H. Weaver ทำscheme-indent-functionเพื่อแก้ไขการจัดตำแหน่งคำหลักใน Guile Scheme

ฉันเพิ่งคัดลอกรหัสจากhttp://netris.org/~mhw/scheme-indent-function.el ; การเปลี่ยนแปลงเพียงอย่างเดียวคือการเพิ่มcondข้อใหม่ คุณอาจต้องการใช้รหัสปัจจุบันlisp-indent-functionแทนการใช้ฟังก์ชันนี้ตามที่เป็นอยู่

(น่าเสียดายที่ฟังก์ชั่นการเยื้องไม่ได้แสดง hooks มากขึ้นเพื่อลดความซับซ้อนของการเปลี่ยนแปลงเล็กน้อยเช่นนี้)

(defun scheme-indent-function (indent-point state)
  "Scheme mode function for the value of the variable `lisp-indent-function'.
This behaves like the function `lisp-indent-function', except that:

i) it checks for a non-nil value of the property `scheme-indent-function'
\(or the deprecated `scheme-indent-hook'), rather than `lisp-indent-function'.

ii) if that property specifies a function, it is called with three
arguments (not two), the third argument being the default (i.e., current)
indentation."
  (let ((normal-indent (current-column)))
    (goto-char (1+ (elt state 1)))
    (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
    (if (and (elt state 2)
             (not (looking-at "\\sw\\|\\s_")))
        ;; car of form doesn't seem to be a symbol
        (progn
          (if (not (> (save-excursion (forward-line 1) (point))
                      calculate-lisp-indent-last-sexp))
              (progn (goto-char calculate-lisp-indent-last-sexp)
                     (beginning-of-line)
                     (parse-partial-sexp (point)
                     calculate-lisp-indent-last-sexp 0 t)))
          ;; Indent under the list or under the first sexp on the same
          ;; line as calculate-lisp-indent-last-sexp.  Note that first
          ;; thing on that line has to be complete sexp since we are
          ;; inside the innermost containing sexp.
          (backward-prefix-chars)
          (current-column))
      (let ((function (buffer-substring (point)
                    (progn (forward-sexp 1) (point))))
        method)
    (setq method (or (get (intern-soft function) 'scheme-indent-function)
             (get (intern-soft function) 'scheme-indent-hook)))
    (cond ((or (eq method 'defun)
           (and (null method)
            (> (length function) 3)
            (string-match "\\`def" function)))
           (lisp-indent-defform state indent-point))
              ;; This next cond clause is the only change -mhw
          ((and (null method)
                    (> (length function) 1)
                    ; The '#' in '#:' seems to get lost, not sure why
                    (string-match "\\`:" function))
               (let ((lisp-body-indent 1))
                 (lisp-indent-defform state indent-point)))
          ((integerp method)
           (lisp-indent-specform method state
                     indent-point normal-indent))
          (method
        (funcall method state indent-point normal-indent)))))))

คุณสามารถแทนที่lisp-indent-functionในอนาคตที่พิสูจน์ได้โดยใช้แพทช์ el-patchของฉัน:

(el-patch-defun lisp-indent-function (indent-point state)
  "This function is the normal value of the variable `lisp-indent-function'.
The function `calculate-lisp-indent' calls this to determine
if the arguments of a Lisp function call should be indented specially.
INDENT-POINT is the position at which the line being indented begins.
Point is located at the point to indent under (for default indentation);
STATE is the `parse-partial-sexp' state for that position.
If the current line is in a call to a Lisp function that has a non-nil
property `lisp-indent-function' (or the deprecated `lisp-indent-hook'),
it specifies how to indent.  The property value can be:
* `defun', meaning indent `defun'-style
  (this is also the case if there is no property and the function
  has a name that begins with \"def\", and three or more arguments);
* an integer N, meaning indent the first N arguments specially
  (like ordinary function arguments), and then indent any further
  arguments like a body;
* a function to call that returns the indentation (or nil).
  `lisp-indent-function' calls this function with the same two arguments
  that it itself received.
This function returns either the indentation to use, or nil if the
Lisp function does not specify a special indentation."
  (el-patch-let (($cond (and (elt state 2)
                             (el-patch-wrap 1 1
                               (or (not (looking-at "\\sw\\|\\s_"))
                                   (looking-at ":")))))
                 ($then (progn
                          (if (not (> (save-excursion (forward-line 1) (point))
                                      calculate-lisp-indent-last-sexp))
                              (progn (goto-char calculate-lisp-indent-last-sexp)
                                     (beginning-of-line)
                                     (parse-partial-sexp (point)
                                                         calculate-lisp-indent-last-sexp 0 t)))
                          ;; Indent under the list or under the first sexp on the same
                          ;; line as calculate-lisp-indent-last-sexp.  Note that first
                          ;; thing on that line has to be complete sexp since we are
                          ;; inside the innermost containing sexp.
                          (backward-prefix-chars)
                          (current-column)))
                 ($else (let ((function (buffer-substring (point)
                                                          (progn (forward-sexp 1) (point))))
                              method)
                          (setq method (or (function-get (intern-soft function)
                                                         'lisp-indent-function)
                                           (get (intern-soft function) 'lisp-indent-hook)))
                          (cond ((or (eq method 'defun)
                                     (and (null method)
                                          (> (length function) 3)
                                          (string-match "\\`def" function)))
                                 (lisp-indent-defform state indent-point))
                                ((integerp method)
                                 (lisp-indent-specform method state
                                                       indent-point normal-indent))
                                (method
                                 (funcall method indent-point state))))))
    (let ((normal-indent (current-column))
          (el-patch-add
            (orig-point (point))))
      (goto-char (1+ (elt state 1)))
      (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
      (el-patch-swap
        (if $cond
            ;; car of form doesn't seem to be a symbol
            $then
          $else)
        (cond
         ;; car of form doesn't seem to be a symbol, or is a keyword
         ($cond $then)
         ((and (save-excursion
                 (goto-char indent-point)
                 (skip-syntax-forward " ")
                 (not (looking-at ":")))
               (save-excursion
                 (goto-char orig-point)
                 (looking-at ":")))
          (save-excursion
            (goto-char (+ 2 (elt state 1)))
            (current-column)))
         (t $else))))))

วิธีนี้ช่วยแก้ไขปัญหาให้ฉันได้ เห็นมันในบริบท