วิธีโอนย้ายอาร์กิวเมนต์สองข้อของฟังก์ชันใน Python อย่างไร

ฉันจะสลับสองอาร์กิวเมนต์ในการเรียกไปยังฟังก์ชัน Python ได้อย่างไร

ถ้าฉันใส่pointช่องว่างระหว่างสองอาร์กิวเมนต์นี้:

self.assertEqual(json.loads(some.data), json_data)

จากนั้นM-t( transpose-words) ฉันจะได้รับ:

self.assertEqual(json.loads(some.json), data_data)

ในทางกลับกันด้วย CMt ( transpose-sexps) ฉันจะได้รับ:

self.assertEqual(json.loadsjson_data, (some.data))

สิ่งที่ฉันต้องการคือ:

self.assertEqual(json_data, json.loads(some.data))

มีคำสั่งที่จะทำเช่นนั้นหรือไม่?

นี่คือสิ่งที่ฉันต้องการได้เป็นเวลานานและที่นี่ฉันพบว่ามีแรงจูงใจในการทำงาน มันอาจจะไม่แข็งแกร่งมาก แต่ในตอนแรกลองดูเหมือนว่าจะครอบคลุมกรณีที่ฉันพยายาม:

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

ฉันจะใช้รูปแบบของtranspose-sexpsรูปลักษณ์ที่ว่าสำหรับกรณีที่คุณอธิบายและ transposes transpose-sexpsสิ่งที่แยกออกจากกันโดยเครื่องหมายจุลภาคหรือเพียงแค่ไม่ปกติ มันทำให้เคอร์เซอร์อยู่ที่เดิมแทนที่จะลากไปข้างหน้าซึ่งแตกต่างกันเล็กน้อย แต่โดยส่วนตัวแล้วฉันชอบ

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

ในโหมดที่ใช้ SMIE transpose-sexpควรทำงานอย่างถูกต้องสำหรับกรณีนั้น พวกเขาจะยังคงล้มเหลวเมื่อสัญลักษณ์ infix (aka "ตัวคั่น") ไม่ใช่,(หรือ;) แต่เป็นคำ (เช่นand)

ดังนั้นความเห็นของฉันคือคำสั่งสำหรับสิ่งนั้นtranspose-sexpและเมื่อสิ่งนี้ทำงานไม่ถูกต้องฉันถือว่ามันเป็นข้อผิดพลาด (แต่ข้อผิดพลาดที่อาจยากและ / หรือใช้เวลาในการแก้ไขและมีลำดับความสำคัญต่ำดังนั้นอย่า ' อย่ากลั้นลมหายใจของคุณ) วิธีการแก้ไขคือการตั้งค่าforward-sexp-functionฟังก์ชั่นที่จะรู้ว่า "หลังจากที่ฉันเห็นเครื่องหมายจุลภาคฉันเพิ่งกระโดดไปรอบ ๆ อาร์กิวเมนต์ทั้งหมด"