วิธีที่ง่ายที่สุดในการตรวจสอบว่าบรรทัดปัจจุบันเป็น“ ว่างเปล่า” (ละเว้นช่องว่าง) หรือไม่

ฉันแค่ต้องการตรวจสอบว่าบรรทัดปัจจุบันว่างหรือไม่ (ถ้ามันมีเพียงช่องว่างเท่านั้นแล้วฉันยังคงพิจารณาว่าว่างเปล่า)

นี่คือเวอร์ชั่นเริ่มต้นของฉัน:

(defun strip-text-properties(txt)
  (set-text-properties 0 (length txt) nil txt)
  txt)

(defun is-current-line-empty ()
  (interactive)
  (setq c-line (thing-at-point 'line))
  (string-match "^\s*$" (strip-text-properties c-line)))

วิธีที่ง่ายที่สุดในการตรวจสอบว่าบรรทัดปัจจุบันว่างเปล่าคืออะไร?

สิ่งนี้จะเป็น "ง่ายขึ้น" หรือไม่?

(defun current-line-empty-p ()
  (save-excursion
    (beginning-of-line)
    (looking-at "[[:space:]]*$")))

วิธีง่ายๆใกล้กับสิ่งที่คุณมี:

(defun current-line-empty-p ()
  (string-match-p "\\`\\s-*$" (thing-at-point 'line)))

(defun blank-line-p (&optional pos)
  "Returns `t' if line (optionally, line at POS) is empty or
composed only of whitespace."
  (save-excursion
    (goto-char (or pos (point)))
    (beginning-of-line)
    (= (point-at-eol)
       (progn (skip-syntax-forward " ") (point)))))

ฉันแนะนำ:

(defun blank-line-p ()
  (and (progn (skip-chars-backward " ") (bolp))
       (progn (skip-chars-forward " ") (eolp))))

(โปรดทราบว่าprognในความเป็นจริงแล้วไม่จำเป็นเพราะฟังก์ชั่นการข้ามจะไม่ส่งคืนศูนย์) ดานทำตามคำตอบของเขาskip-syntax-*ก็สามารถใช้แทนได้เช่นกัน

นี่เป็นอีกวิธีที่ง่ายสำหรับมันนำมาจากcomment-dwim-2แพคเกจ

(defun is-empty-line-p ()
  (string-match "^[[:blank:]]*$"
        (buffer-substring (line-beginning-position)
                          (line-end-position))))

นี่คือการดัดแปลงสิ่งที่ PythonNut ตอบซึ่งไม่ได้ผลสำหรับฉัน (เพราะเหตุใด):

(defun current-line-blank ()
  (= 0 (string-match-p "^\\s-*$" (thing-at-point 'line))))

string-match-pส่งคืนดัชนีของบรรทัดถัดไปเมื่อใดก็ตามที่บรรทัดปัจจุบันไม่ว่างเปล่า ดังนั้นฉันจึงตรวจสอบว่าค่าส่งคืนเป็น 0

current-indentation ให้คอลัมน์ตามช่องว่างนำหน้าซึ่งสามารถเปรียบเทียบกับคอลัมน์ที่ท้ายบรรทัดได้

(defun blank-line-p ()
  (= (current-indentation)
     (- (line-end-position) (line-beginning-position))))