ฆ่าหรือคัดลอกบรรทัดปัจจุบันด้วยการกดแป้นน้อยที่สุด

ฉันC-a C-k C-kจะฆ่าจุดเส้นทั้งหมดที่อยู่บน

หากฉันต้องการคัดลอกบรรทัดแทนที่จะฆ่ามันฉันสามารถกดได้C-/ C-/ หลังจากพิมพ์ลำดับด้านบน

C-a C-SPC C-n M-wหรือฉันสามารถทำได้

มีวิธีที่เร็วกว่าในการฆ่าหรือคัดลอกจุดเส้นทั้งหมดที่เปิดอยู่?

คุณสามารถใช้kill-whole-lineเพื่อฆ่าจุดเส้นทั้งหมดที่อยู่บน ตำแหน่งของจุดไม่สำคัญ คำสั่งนี้ถูกผูกไว้C-S-DELโดยค่าเริ่มต้น

นอกจากนี้คุณยังสามารถสั่งkill-line(ผูกไว้กับC-k) เพื่อฆ่าทั้งบรรทัดโดยการตั้งค่าตัวแปร kill-whole-lineเป็นnilค่าที่ไม่ใช่:

(setq kill-whole-line t)

โปรดทราบว่าจุดนั้นจะต้องอยู่ที่จุดเริ่มต้นของบรรทัดเพื่อให้สามารถใช้งานได้

จากนั้นก็มีอัญมณีสองชนิดนี้ (ผ่านemacs-fu ):

(defadvice kill-region (before slick-cut activate compile)
  "When called interactively with no active region, kill a single line instead."
  (interactive
   (if mark-active
       (list (region-beginning) (region-end))
     (list (line-beginning-position) (line-beginning-position 2)))))

(defadvice kill-ring-save (before slick-copy activate compile)
  "When called interactively with no active region, copy a single line instead."
  (interactive
   (if mark-active
       (list (region-beginning) (region-end))
     (message "Copied line")
     (list (line-beginning-position) (line-beginning-position 2)))))

ด้วยสิ่งเหล่านี้ในสถานที่ที่คุณสามารถฆ่าหรือคัดลอกจุดบรรทัดอยู่ด้วยการกดแป้นเดียว :

• C-w ฆ่าบรรทัดปัจจุบัน
• M-w คัดลอกบรรทัดปัจจุบัน

โปรดทราบว่าหากมีพื้นที่ที่ใช้งานอยู่kill-regionและkill-ring-saveจะทำสิ่งที่พวกเขาทำตามปกติ: ฆ่าหรือคัดลอก

พอร์ตslick-cutและslick-copyระบบคำแนะนำใหม่

Emacs 24.4 เปิดตัวระบบใหม่คำแนะนำ ในขณะที่defadvice ยังใช้งานได้มีความเป็นไปได้ที่จะเลิกใช้งานระบบใหม่ในเวอร์ชันของ Emacs ในอนาคต ในการเตรียมพร้อมสำหรับสิ่งนั้นคุณอาจต้องการใช้เวอร์ชันที่อัปเดตแล้วslick-cutและslick-copy:

(defun slick-cut (beg end)
  (interactive
   (if mark-active
       (list (region-beginning) (region-end))
     (list (line-beginning-position) (line-beginning-position 2)))))

(advice-add 'kill-region :before #'slick-cut)

(defun slick-copy (beg end)
  (interactive
   (if mark-active
       (list (region-beginning) (region-end))
     (message "Copied line")
     (list (line-beginning-position) (line-beginning-position 2)))))

(advice-add 'kill-ring-save :before #'slick-copy)

วิธีแก้ปัญหาที่ฉันพบสำหรับตัวเองคือใช้อาร์กิวเมนต์คำนำหน้า

สำหรับฉันการฆ่าครึ่งบรรทัดเป็นคุณสมบัติที่มีประโยชน์ แต่ฉันต้องการวิธีที่ง่ายกว่าในการฆ่าทั้งบรรทัดด้วย ดังนั้นฉันจึงสร้างมันขึ้นมาเพื่อที่ kill-lineจะได้สังหารทุกสิ่งทุกอย่างเมื่อได้รับอาร์กิวเมนต์นำหน้า

(defmacro bol-with-prefix (function)
  "Define a new function which calls FUNCTION.
Except it moves to beginning of line before calling FUNCTION when
called with a prefix argument. The FUNCTION still receives the
prefix argument."
  (let ((name (intern (format "endless/%s-BOL" function))))
    `(progn
       (defun ,name (p)
         ,(format 
           "Call `%s', but move to BOL when called with a prefix argument."
           function)
         (interactive "P")
         (when p
           (forward-line 0))
         (call-interactively ',function))
       ',name)))

(global-set-key [remap paredit-kill] (bol-with-prefix paredit-kill))
(global-set-key [remap org-kill-line] (bol-with-prefix org-kill-line))
(global-set-key [remap kill-line] (bol-with-prefix kill-line))
(global-set-key "\C-k" (bol-with-prefix kill-line))

ด้วยมาโครตัวเล็กนี้C-kยังคงสังหารจากจุด แต่ C-3 C-kกลืนทั้งสามบรรทัด เป็นโบนัส, เราได้รับ พฤติกรรมโดยการทำkill-whole-lineC-1 C-k

มีแพคเกจที่เรียกว่าwhole-line-or-regionซึ่งให้คำแนะนำในตัวคำสั่งต่าง ๆ เพื่อให้พวกเขาทำหน้าที่ในบรรทัดปัจจุบันหากไม่มีการใช้งานภูมิภาคดังนั้นM-wจะคัดลอกบรรทัดปัจจุบันและC-wจะฆ่ามันตัวอย่างเช่น ฉันใช้แพ็คเกจมาหลายปีแล้วและพบว่ามันขาดไม่ได้

นอกจากนี้แพคเกจนี้สร้างขึ้นเพื่อให้คำนำหน้าตัวเลขจะระบุจำนวนบรรทัดที่จะดำเนินการดังนั้นM-2 M-wจะคัดลอกสองบรรทัด คำตอบอื่น ๆ ที่นี่ไม่ได้มีฟังก์ชั่นที่สะดวก

ฉันเข้ารับการบำรุงรักษาแพคเกจที่บัญชี GitHub ของฉันเมื่อผู้เขียนหยุดการบำรุงรักษาและไม่ตอบสนอง

whole-line-or-region ยังให้บริการสิ่งอำนวยความสะดวกสำหรับการเพิ่มพฤติกรรมนี้ให้กับคำสั่งเพิ่มเติมหากคุณต้องการ

นี่ไม่ใช่คำตอบสำหรับ emacs ดั้งเดิม อย่างไรก็ตามหากคุณยินดีดูหมิ่นevilการแก้ไขคำกริยาคุณสามารถ:

• dd สำหรับสายฆ่า
• cc สำหรับสายการคัดลอก

ทั้งสองสามารถนำหน้าด้วยจำนวนบรรทัดที่จะฆ่า / คัดลอก (เช่น4ccจะคัดลอก 4 บรรทัดถัดไป)

นอกจาก @itsjeyd คำตอบฉันขอแนะนำฟังก์ชันทั้งสองนี้ได้ไหม?

(defun xah-copy-line-or-region ()
  "Copy current line, or text selection.
When `universal-argument' is called first, copy whole buffer (but respect `narrow-to-region')."
  (interactive)
  (let (p1 p2)
    (if (null current-prefix-arg)
        (progn (if (use-region-p)
                   (progn (setq p1 (region-beginning))
                          (setq p2 (region-end)))
                 (progn (setq p1 (line-beginning-position))
                        (setq p2 (line-end-position)))))
      (progn (setq p1 (point-min))
             (setq p2 (point-max))))
    (kill-ring-save p1 p2)))

(defun xah-cut-line-or-region ()
  "Cut current line, or text selection.
When `universal-argument' is called first, cut whole buffer (but respect `narrow-to-region')."
  (interactive)
  (let (p1 p2)
    (if (null current-prefix-arg)
        (progn (if (use-region-p)
                   (progn (setq p1 (region-beginning))
                          (setq p2 (region-end)))
                 (progn (setq p1 (line-beginning-position))
                        (setq p2 (line-beginning-position 2)))))
      (progn (setq p1 (point-min))
             (setq p2 (point-max))))
    (kill-region p1 p2)))

จากนั้นคำจำกัดความสำคัญ (คุณอาจต้องการปรับเปลี่ยน):

(global-set-key (kbd "<f2>") 'xah-cut-line-or-region) ; cut

(global-set-key (kbd "<f3>") 'xah-copy-line-or-region) ; copy

(global-set-key (kbd "<f4>") 'yank) ; paste

ความอนุเคราะห์จากErgoEmacs

ในฐานะที่เป็นส่วนขยายของคำตอบของ @ itsjeyd ด้านบนฉันมีดังต่อไปนี้ (ลอจิกอาจจะทำความสะอาดได้เล็กน้อยและฉันจะเมื่อฉันพอร์ตไปยังระบบคำแนะนำใหม่ฉันจะยังขยายมันเพื่อขยายไปยังsexp/ paragraphถ้าทำซ้ำอีกครั้ง)

เริ่มต้นC-w/ M-wจะคว้าเฉพาะคำที่จุดในขณะที่เรียกมันเป็นครั้งที่สองจะคว้าทั้งบรรทัด

;; *** Copy word/line without selecting
(defadvice kill-ring-save (before slick-copy-line activate compile)
  "When called interactively with no region, copy the word or line

Calling it once without a region will copy the current word.
Calling it a second time will copy the current line."
    (interactive
     (if mark-active (list (region-beginning) (region-end))
       (if (eq last-command 'kill-ring-save)
           (progn
             ;; Uncomment to only keep the line in the kill ring
             ;; (kill-new "" t)
             (message "Copied line")
             (list (line-beginning-position)
                   (line-beginning-position 2)))
         (save-excursion
           (forward-char)
           (backward-word)
           (mark-word)
           (message "Copied word")
           (list (mark) (point)))))))

;; *** Kill word/line without selecting
(defadvice kill-region (before slick-cut-line first activate compile)
  "When called interactively kill the current word or line.

Calling it once without a region will kill the current word.
Calling it a second time will kill the current line."
  (interactive
   (if mark-active (list (region-beginning) (region-end))
    (if (eq last-command 'kill-region)
        (progn
          ;; Return the previous kill to rebuild the line
          (yank)
          ;; Add a blank kill, otherwise the word gets appended.
          ;; Change to (kill-new "" t) to remove the word and only
          ;; keep the whole line.
          (kill-new "")
          (message "Killed Line")
          (list (line-beginning-position)
                (line-beginning-position 2)))
      (save-excursion
        (forward-char)
        (backward-word)
        (mark-word)
        (message "Killed Word")
        (list (mark) (point)))))))

เนื่องจากคุณต้องการใช้ปุ่มกดน้อยที่สุดคุณสามารถใช้แพ็คเกจคีย์คอร์ดที่ยอดเยี่ยมของ David Andersson "คอร์ดปุ่ม" คือกดสองปุ่มพร้อมกันหรือกดปุ่มเดียวสองครั้ง

คุณสามารถผูกคอร์ดกุญแจใด ๆ กับฟังก์ชั่นเหล่านั้นได้

(require 'key-chord)
(key-chord-mode 1)
(key-chord-define-global "dd"  'kill-whole-line)
(key-chord-define-global "cc"  'yank-whole-line)

วิธีการเฉพาะกิจน้อยลงคือการกำหนดmark-whole-lineซึ่ง Emacs ควรมีคำสั่งเริ่มต้นสำหรับ

(defun mark-whole-line ()               
    "Combinition of C-a, mark, C-e"
    (interactive)
    (move-beginning-of-line nil)
    (set-mark-command nil)
    (move-end-of-line nil)
)
(global-set-key (kbd "C-2") 'mark-whole-line) ; 2 is near w

จากนั้นC-2 C-wจะทำงาน

นอกจากนี้ยังทำให้สิ่งต่าง ๆ ง่ายขึ้นเช่นการแสดงความคิดเห็นทั้งบรรทัดปัจจุบัน

นี่คือการแก้ไขคำตอบโดย itsjeyd - ปัจจุบันเป็นคำตอบที่ได้รับการโหวตสูงสุดและเป็นคำตอบที่ฉันใช้มานานหลายปี อย่างไรก็ตามมีปัญหา: รุ่นที่แนะนำของkill-ring-saveบางครั้งจะล้มเหลวเนื่องจากไม่ได้ตั้งค่าเครื่องหมาย (โดยทั่วไปจะอยู่ในบัฟเฟอร์ใหม่) และแม้ว่าจะทำงานแล้วเคอร์เซอร์ก็เต้นแปลก ๆ หลังจากใช้ฟังก์ชั่นเพื่อคัดลอกบรรทัดเดียว . หลังจากการขุดบางครั้งก็เกิดขึ้นกับฉันว่าสิ่งนี้เกิดขึ้นเพราะการkill-ring-saveโทรindicate-copied-regionหลังจากทำงานเสร็จแล้ว แต่เนื่องจากจุดและเครื่องหมายไม่ตรงกับภูมิภาคที่คัดลอกindicate-copied-regionทำเครื่องหมายว่าภูมิภาคไม่ถูกต้อง

พูดพอแล้ว. นี่คือทางออกที่แก้ไขสิ่งนี้:

(define-advice kill-ring-save
    (:before-while (beg end &optional region) slick)
  (or mark-active
      (not (called-interactively-p 'interactive))
      (prog1 nil
    (copy-region-as-kill
     (line-beginning-position) (line-beginning-position 2))
    (message "Copied current line"))))

มีอะไรผิดปกติกับคำแนะนำ itsjeyd kill-regionบนคือ นี่คือตัวแปรของมัน แต่อย่างใด stylistically สอดคล้องกับข้างต้น:

(define-advice kill-region
    (:around (kill-region beg end &optional region) slick)
  (if (or mark-active (not region))
      (funcall kill-region beg end region)
    (funcall kill-region
             (line-beginning-position) (line-beginning-position 2))
    (message "Killed current line")))

โปรดทราบว่าหากtransient-mark-modeไม่ได้เปิดใช้งานคำแนะนำเหล่านี้จะไม่ทำอะไรเลย

ผมใช้แพคเกจที่เรียกว่าcomposable.el สิ่งที่เรียบร้อยเกี่ยวกับแพ็กเกจคือการปรับเปลี่ยน Mw และ Cw (คัดลอกและฆ่าคำสั่ง) ให้เหมือน Vim มากขึ้นด้วยการหมุนที่ยอมรับคำสั่ง emacs แบบดั้งเดิมแทน ดังนั้นC-w lฆ่าทั้งเส้น แต่คุณสามารถทำสิ่งต่าง ๆ เช่นC-w M->การกำจัดจุดสิ้นสุดไฟล์ คำสั่งทั้งสองทำหน้าที่เหมือนปกติเมื่อทำเครื่องหมายภูมิภาค