เป็นไปได้หรือไม่ที่จะสะกดคำว่า "บนอวกาศ" โดยอัตโนมัติ?

ฉันกำลังจะโพสต์คำถาม แต่จากนั้นฉันเห็นมันใน Stack Overflowขณะที่ค้นหาความเป็นไปได้ที่ถูกต้องโดยอัตโนมัติ คำถามที่เชื่อมโยงไม่มีคำตอบดังนั้นฉันคิดว่ามันจะมีโชคมากขึ้นในเว็บไซต์นี้ นี่คือข้อความ:

ฉันหวังว่าจะมีวิธีหนึ่งดังนั้นเมื่อฉันพิมพ์คำผิด flyspell สามารถแก้ไขโดยอัตโนมัติเพื่อแก้ไข "น่าจะ" เมื่อฉันพิมพ์คำผิดแล้วกด OPTION-TAB เพื่อแก้ไขคำนั้น flyspell ALMOST ALM ALS จะเลือกการแก้ไขที่ถูกต้องตามค่าเริ่มต้นเป็นคำแนะนำหลัก

อย่างไรก็ตามฉันต้องการให้ flyspell ทำสิ่งนี้กับทุกคำที่ฉันพิมพ์ผิดโดยไม่ต้องกด OPTION-TAB เพียงแค่กดปุ่ม SPACE bar และเลื่อนไปยังคำถัดไป

เป็นไปได้ไหม

ดังนั้นโดยทั่วไปบางสิ่งบางอย่างเช่นการแก้ไขอัตโนมัติบนโทรศัพท์มือถือ คุณสมบัติดังกล่าวจะมีประโยชน์สำหรับโหมดเช่นjabberและcaptureในorg-mode

แก้ไข :

ฉันอยากให้คุณสมบัตินี้เป็นโหมดรองแยกต่างหากแทนที่จะเขียนทับฟังก์ชั่นการสะกดคำที่เป็นค่าเริ่มต้น มันสามารถเปิดใช้งานนอกเหนือจากหรือแทนการสะกดทันทีเมื่อจำเป็น

ผมขอนำคุณไปยังโพสต์ของฉันเกี่ยวกับเรื่องนี้

ฉันพบว่าตัวย่อเป็นวิธีที่ดีที่สุดในการแก้ไขSPCคุณจำเป็นต้องกำหนดการแก้ไขที่คุณต้องการเท่านั้น เพื่อที่ฉันจะใช้วิธีการดังต่อไปนี้:

1. เพิ่มรหัสด้านล่างลงในไฟล์ init ของคุณ
2. เมื่อใดก็ตามที่คุณพิมพ์ผิดพลาดให้กดC-x C-iและเลือกหนึ่งในการแก้ไขที่เสนอ
3. แค่นั้นแหละ! การแก้ไขจะถูกแทนที่โดยอัตโนมัติและจะดำเนินการโดยอัตโนมัติทุกครั้งที่คุณทำผิดพลาดนับจากนี้เป็นต้นไป

นี่คือรหัส

(define-key ctl-x-map "\C-i" 'endless/ispell-word-then-abbrev)

(defun endless/ispell-word-then-abbrev (p)
  "Call `ispell-word'. Then create an abbrev for the correction made.
With prefix P, create local abbrev. Otherwise it will be global."
  (interactive "P")
  (let ((bef (downcase (or (thing-at-point 'word) ""))) aft)
    (call-interactively 'ispell-word)
    (setq aft (downcase (or (thing-at-point 'word) "")))
    (unless (string= aft bef)
      (message "\"%s\" now expands to \"%s\" %sally"
               bef aft (if p "loc" "glob"))
      (define-abbrev
        (if p local-abbrev-table global-abbrev-table)
        bef aft))))

(setq save-abbrevs t)
(setq-default abbrev-mode t)

การเพิ่มการแก้ไขด้วยตนเองอาจฟังดูยุ่งยาก แต่จริงๆแล้วไม่ใช่ คุณเพิ่งกดปุ่มไม่กี่ปุ่มและคุณจะสังเกตว่าการแก้ไขบางอย่างจะทำให้คุณต้องใช้เวลาอีกนาน

นอกจากนี้ทางเลือก (ให้ ispell เลือกการแก้ไขสำหรับคุณ ทุกครั้งที่ไม่มีคำศัพท์) จะทำให้คุณแก้ไขผิดบ่อยกว่าไม่ได้ ดังนั้นจึงเป็นการดีที่สุดที่จะกำหนดของคุณเองต่อไป มันยังช่วยแก้ปัญหาเมื่อคุณต้องการพิมพ์คำที่ไม่ใช่

นี่คือความพยายามอย่างง่าย:

(defun my-flyspell-correct-on-space ()
  (interactive)
  (when flyspell-mode
    (flyspell-auto-correct-word))
  (self-insert-command 1))
(local-set-key " " 'my-flyspell-correct-on-space)

มันทำงานแปลก ๆ เมื่อคุณแทรกมากกว่าหนึ่งช่องว่างในแถวและบางครั้งก็แยกออกเป็นส่วนหนึ่งของคำที่ถูกแก้ไข ดังนั้นโพสต์นี้คือวิกิชุมชน อย่าลังเลที่จะปรับปรุง

คำตอบช่วงปลายแรงบันดาลใจจากคำถามเกี่ยวกับการแก้ไขอัตโนมัติอีกและ คำตอบ @ legoscia ของ flyspellนี่เป็นโหมดย่อยอย่างรวดเร็วที่จะแก้ไขอัตโนมัติในทันทีที่ใช้ มันคือผล "ทั่วโลก" ในการที่จะให้คำแนะนำself-insert-commandแต่เพียงไฟไหม้ในบัฟเฟอร์ที่ได้flyspell-modeเปิด

(defun flyspell-ac-word (&optional arg)
  "Autocorrect a word when entering a non-word character."
  (when flyspell-mode
    (unless (eq ?w (char-syntax (string-to-char (this-command-keys))))
      (when (or (bobp)
                (eq ?w (char-syntax (char-before))))
        (flyspell-auto-correct-word)))))

(define-minor-mode flyspell-autocorrect-mode
  "Toggle `flyspell-autocorrect-mode'.  Fires flyspell on a
just-completed word.  Only operates when `flyspell-mode' is on."
  :init-value nil
  :lighter (" AC")
  (if flyspell-autocorrect-mode
      (progn 
        (require 'flyspell)
        (advice-add #'self-insert-command :before #'flyspell-ac-word))
    (advice-remove #'self-insert-command #'flyspell-ac-word)))