สลับการวางแนวการแบ่งหน้าต่างวิธีที่เร็วที่สุด

สมมติว่าคุณเปิดบัฟเฟอร์สองอันเช่นนี้:

------------------------------------
            |                      |
  buffer 1  |        buffer 2      |       
            |                      |
------------------------------------

เป็นวิธีที่เร็วที่สุดในการสลับบัฟเฟอร์เพื่อให้คุณได้รับสิ่งนี้:

------------------------------------
           buffer 1                |
                                   |
------------------------------------
            buffer 2               |
                                   |
------------------------------------

นี่คือ defun ที่จะทำสิ่งที่คุณกำลังมองหา:

(defun toggle-window-split ()
  (interactive)
  (if (= (count-windows) 2)
      (let* ((this-win-buffer (window-buffer))
             (next-win-buffer (window-buffer (next-window)))
             (this-win-edges (window-edges (selected-window)))
             (next-win-edges (window-edges (next-window)))
             (this-win-2nd (not (and (<= (car this-win-edges)
                                         (car next-win-edges))
                                     (<= (cadr this-win-edges)
                                         (cadr next-win-edges)))))
             (splitter
              (if (= (car this-win-edges)
                     (car (window-edges (next-window))))
                  'split-window-horizontally
                'split-window-vertically)))
        (delete-other-windows)
        (let ((first-win (selected-window)))
          (funcall splitter)
          (if this-win-2nd (other-window 1))
          (set-window-buffer (selected-window) this-win-buffer)
          (set-window-buffer (next-window) next-win-buffer)
          (select-window first-win)
          (if this-win-2nd (other-window 1))))))

(คัดลอกมาจากMagnars .emacs.d )

บวกถ้าคุณเรียกมันอีกครั้งมันจะแบ่งหน้าต่างของคุณในแนวตั้งเดิม