วิธีที่ดีที่สุดในการเรียกคืนค่าในรายการ assoc-ซ้อนกัน?

สมมติว่าฉันได้รับรายการรองแบบนี้:

(setq x '((foo . ((bar . "llama")
                  (baz . "monkey")))))

barและฉันต้องการให้ค่าที่ ฉันสามารถทำสิ่งนี้:

(assoc-default 'bar (assoc-default 'foo x))

แต่สิ่งที่ฉันชอบจริงๆคือสิ่งที่ยอมรับได้หลายปุ่มเช่น

(assoc-multi-key 'foo 'bar x)

สิ่งนั้นมีอยู่จริงหรือเปล่า ฉันแน่ใจว่าฉันสามารถเขียนได้ แต่ฉันรู้สึกว่า Google-fu ของฉันเพิ่งจะล้มเหลวและฉันไม่พบมัน

นี่คือตัวเลือกที่ใช้ไวยากรณ์ที่แน่นอนที่คุณขอ แต่ในลักษณะทั่วไปและค่อนข้างง่ายที่จะเข้าใจ ความแตกต่างเพียงอย่างเดียวก็คือALISTพารามิเตอร์จะต้องมาก่อน (คุณสามารถปรับให้เข้ากับสภาพได้หากจำเป็นสำหรับคุณ)

(defun assoc-recursive (alist &rest keys)
  "Recursively find KEYs in ALIST."
  (while keys
    (setq alist (cdr (assoc (pop keys) alist))))
  alist)

จากนั้นคุณสามารถโทรหาด้วย:

(assoc-recursive x 'foo 'bar)

นี่คือทางออกทั่วไปเพิ่มเติม:

(defun assoc-multi-key (path nested-alist)
   "Find element in nested alist by path."
   (if (equal nested-alist nil)
       (error "cannot lookup in empty list"))
   (let ((key (car path))
         (remainder (cdr path)))
     (if (equal remainder nil)
         (assoc key nested-alist)
       (assoc-multi-key remainder (assoc key nested-alist)))))

มันสามารถใช้ "เส้นทาง" ของคีย์ใด ๆ สิ่งนี้จะกลับมา(bar . "llama")

(assoc-multi-key '(foo bar)
    '((foo (bar . "llama") (baz . "monkey"))))

ในขณะที่สิ่งนี้จะกลับมา(baz . "monkey"):

(assoc-multi-key '(foo bar baz)
    '((foo (bar (bozo . "llama") (baz . "monkey")))))

นี่เป็นฟังก์ชั่นพื้นฐานที่ทำงานกับ alist ซ้อนกันภายใน alist อื่น:

(defun assoc2 (outer inner alist)
  "`assoc', but for an assoc list inside an assoc list."
  (assoc inner (assoc outer alist)))

(setq alist2 '((puppies (tail . "waggly") (ears . "floppy"))
               (kitties (paws . "fuzzy")  (coat . "sleek"))))

(assoc2 'kitties 'coat alist2)       ;; => (coat . "sleek")
(cdr (assoc2 'kitties 'coat alist2)) ;; => "sleek"