ทำให้ `delete-Duplicate Lines 'ละเว้นบรรทัดว่างเปล่าและคำบางคำ

ฉันกำลังแก้ไขข้อความในโหมดองค์กรมีการทำซ้ำหลายบรรทัดเนื่องจากเป็นส่วนหนึ่งของไฟล์ที่แตกต่างจากหัวข้อเดียวกัน

ฉันต้องการใช้delete-duplicate-linesเพื่อลบบรรทัดที่ซ้ำกันอย่างไรก็ตามคำสั่งจะลบบรรทัดว่างด้วยซึ่งเป็นสิ่งที่ฉันไม่ต้องการ (ไม่เช่นนั้นจะไม่มีย่อหน้า!) ฉันต้องการละเว้นคำบางคำที่มีอยู่ตามลำพังในบรรทัดเช่น"ดำเนินการต่อ"มันซ้ำหลายครั้งในข้อความ แต่ฉันต้องการเก็บไว้เพราะจำเป็น

ละเว้นบรรทัดว่าง

คุณสามารถบอกdelete-duplicate-linesให้ละเว้นบรรทัดว่างได้โดยโทรผ่าน

C-u C-u C-u M-x delete-duplicate-lines RET

หากคุณไม่ต้องการที่จะกดปุ่มC-uหลายครั้งเมื่อคุณโทรdelete-duplicate-linesคุณสามารถปิดมันในคำสั่งที่กำหนดเองและผูกคำสั่งนั้นกับลำดับที่สำคัญที่คุณเลือก:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

ละเว้นบรรทัดที่ตรงกับ regexp

delete-duplicate-linesในฐานะที่เป็นส่วนที่สองของคำถามของคุณผมไม่คิดว่าคุณจะประสบความสำเร็จในสิ่งที่คุณต้องการใช้ในตัวรุ่นของ อย่างไรก็ตามคุณสามารถใช้คำสั่งเวอร์ชันที่แก้ไข (ซึ่งจะเก็บบรรทัดว่างไว้ตามค่าเริ่มต้น):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

เวอร์ชันนี้delete-duplicate-linesจะแจ้งให้คุณทราบสำหรับ regexp และเก็บทุกบรรทัดที่ตรงกับ regexp ตัวอย่างเช่นเพื่อให้ทุกบรรทัดประกอบด้วยคำที่Resumeคุณจะทำ:

M-x delete-duplicate-lines RET ^Resume$ RET