ฉันจะวัดประสิทธิภาพของรหัส elisp ได้อย่างไร

ฉันจะวัดประสิทธิภาพของรหัส elisp ของฉันได้อย่างไร มีเครื่องมือ / แพ็คเกจภายนอกใดบ้างที่ฉันสามารถวัดเวลาได้

นอกจากเวลาทั้งหมดแล้วฉันสามารถดูโปรไฟล์ที่แสดงเวลาที่ใช้ต่อฟังก์ชั่นได้หรือไม่ ฉันจะโปรไฟล์การใช้หน่วยความจำด้วยหรือไม่

เกณฑ์มาตรฐาน

ตัวเลือกที่ตรงไปตรงมาที่สุดคือbenchmarkแพ็คเกจในตัว การใช้งานง่ายอย่างน่าทึ่ง:

(benchmark 100 (form (to be evaluated)))

มันโหลดอัตโนมัติดังนั้นคุณไม่จำเป็นต้องใช้มัน

โปรไฟล์

เกณฑ์มาตรฐานนั้นดีในการทดสอบโดยรวม แต่ถ้าคุณประสบปัญหาด้านประสิทธิภาพก็ไม่ได้บอกคุณว่าฟังก์ชั่นใดเป็นสาเหตุของปัญหา เพื่อที่คุณจะมี (ยัง built-in) Profiler

1. M-x profiler-startเริ่มต้นด้วย
2. ดำเนินการบางครั้งต้องใช้เวลามาก
3. M-x profiler-reportได้รับรายงานด้วย

คุณควรถูกนำไปที่บัฟเฟอร์ด้วยแผนผังการนำทางของการเรียกฟังก์ชัน

นอกเหนือจากคำตอบของ @ Malabara แล้วฉันมักจะใช้with-timerมาโครที่กำหนดเองเพื่อใช้กับส่วนต่างๆของรหัสของฉันอย่างถาวร (เช่นinit.elไฟล์ของฉัน)

ความแตกต่างคือในขณะที่benchmarkช่วยให้การศึกษาประสิทธิภาพของบิตของรหัสเฉพาะที่คุณใช้เครื่องมือwith-timerให้เวลาที่คุณใช้ในแต่ละส่วนของรหัส (ไม่มีค่าใช้จ่ายมากสำหรับชิ้นส่วนที่มีขนาดใหญ่เพียงพอ) ซึ่งช่วยให้คุณรับรู้ ส่วนใดที่ควรตรวจสอบเพิ่มเติม

(defmacro with-timer (title &rest forms)
  "Run the given FORMS, counting the elapsed time.
A message including the given TITLE and the corresponding elapsed
time is displayed."
  (declare (indent 1))
  (let ((nowvar (make-symbol "now"))
        (body   `(progn ,@forms)))
    `(let ((,nowvar (current-time)))
       (message "%s..." ,title)
       (prog1 ,body
         (let ((elapsed
                (float-time (time-subtract (current-time) ,nowvar))))
           (message "%s... done (%.3fs)" ,title elapsed))))))

ตัวอย่างการใช้:

(with-timer "Doing things"
  (form (to (be evaluated))))

ให้ผลลัพธ์ต่อไปนี้ใน*Messages*บัฟเฟอร์:

Doing things... done (0.047s)

ฉันควรพูดถึงว่านี่เป็นแรงบันดาลใจอย่างมากจากuse-package-with-elapsed-timerมาโครของ Jon Wiegley ในการuse-packageต่อยอดเยี่ยมของเขา

นอกจากคำตอบของ @ Malabarba โปรดทราบว่าคุณสามารถวัดเวลาดำเนินการที่คอมไพล์ด้วยรหัสของคุณbenchmark-run-compiledได้ ตัวชี้วัดนั้นมักจะเกี่ยวข้องมากกว่าเวลาดำเนินการตีความที่M-x benchmarkให้คุณ:

ELISP> (benchmark-run (cl-loop for i below (* 1000 1000) sum i))
(0.79330082 6 0.2081620540000002)

ELISP> (benchmark-run-compiled (cl-loop for i below (* 1000 1000) sum i))
(0.047896284 0 0.0)

ตัวเลขสามตัวคือเวลาที่ผ่านไปทั้งหมดจำนวนการรัน GC และเวลาที่ใช้ใน GC

การเปรียบเทียบไม่เพียง แต่เกี่ยวกับการรับตัวเลขเท่านั้น แต่ยังเกี่ยวกับการตัดสินใจโดยอาศัยการวิเคราะห์ผลลัพธ์

มีแพ็คเกจbenchstat.elใน MELPA ซึ่งคุณสามารถใช้เพื่อรับคุณสมบัติที่โปรแกรมbenchstatจัดหาให้

จะดำเนินการเปรียบเทียบตามการเปรียบเทียบที่คุณตรวจสอบคุณสมบัติประสิทธิภาพการทำงานกับXY

ฟังก์ชั่น Benchstat สามารถดูได้เป็นbenchmark-run-compiledwrapper ที่ไม่เพียง แต่รวบรวมข้อมูล แต่ให้กลับมาอ่านง่ายในรูปแบบตีความ มันรวมถึง:

• เวลาที่ผ่านไประหว่างXและY
• เวลาเฉลี่ยโดยเฉลี่ย
• จำนวนการจัดสรร

ตัวอย่างการใช้งานที่ง่ายมาก:

(require 'benchstat)

;; Decide how much repetitions is needed.
;; This is the same as `benchmark-run-compiled` REPETITIONS argument.
(defconst repetitions 1000000)

;; Collect old code profile.
(benchstat-run :old repetitions (list 1 2))
;; Collect new code profile.
(benchstat-run :new repetitions (cons 1 2))

;; Display the results.
;; Can be run interactively by `M-x benchstat-compare'.
(benchstat-compare)

benchstat-compareจะแสดงผลลัพธ์ในบัฟเฟอร์ชั่วคราว:

name   old time/op    new time/op    delta
Emacs    44.2ms ± 6%    25.0ms ±15%  -43.38%  (p=0.000 n=10+10)

name   old allocs/op  new allocs/op  delta
Emacs      23.0 ± 0%      11.4 ± 5%  -50.43%  (p=0.000 n=10+10)

คุณจะต้องใช้benchstatโปรแกรมไบนารี หากคุณใช้ภาษาโปรแกรม Go เป็นไปได้ว่าคุณมีภาษาหนึ่งในระบบ มิฉะนั้นจะมีตัวเลือกในการรวบรวมจากแหล่งที่มา

ไบนารี precompiled สำหรับลินุกซ์ / amd64 สามารถพบได้ที่หน้าปล่อย GitHub