วิธีคำนวณบรรทัดเริ่มต้นและสิ้นสุดโดยอัตโนมัติเมื่อรวมไฟล์ต้นฉบับในโหมดองค์กร

ฉันมีด้านล่างในเอกสารของฉัน:

#+INCLUDE: "code/basic.sv" :src systemverilog :lines "14-117"

นี่คือสาย 14 เป็นที่ที่ผมมีclass basic extends ..และสาย 116 endclassเป็นที่ที่ฉันมี

มีวิธีการอัตโนมัติแทรกหมายเลข 14 และ 117 (= 116 + 1) เพื่อที่ฉันจะได้ไม่ต้องด้วยตนเองปรับปรุงพวกเขาทุกครั้งที่ผมปรับเปลี่ยนcode/basic.sv?

นี่คือตัวเลือกอื่น อันนี้คือให้คุณปรับแต่งการแสดงออกปกติบนพื้นฐานรวมต่อ ควรเหมาะสมกับเวิร์กโฟลว์บางส่วนเนื่องจากคุณไม่ได้จำกัดความหมายที่อิงตามส่วนขยาย

ใช้

ทำสิ่งต่อไปนี้ในไฟล์องค์กรของคุณ ( :linesคำหลักเป็นตัวเลือก)

#+INCLUDE: "code/my-class.sv" :src systemverilog :range-begin "^class" :range-end "^endclass" :lines "14-80"

ฟังก์ชั่นจะไปที่ "my-class.sv" และค้นหา regexps ทั้งสองนั้นจากนั้นจะอัปเดต:linesคำหลักตามผลลัพธ์การจับคู่

หาก:range-beginหายไปช่วงจะเป็น "-80"
หาก:range-endหายไปช่วงจะเป็น "14-"

รหัส

(add-hook 'before-save-hook #'endless/update-includes)

(defun endless/update-includes (&rest ignore)
  "Update the line numbers of #+INCLUDE:s in current buffer.
Only looks at INCLUDEs that have either :range-begin or :range-end.
This function does nothing if not in org-mode, so you can safely
add it to `before-save-hook'."
  (interactive)
  (when (derived-mode-p 'org-mode)
    (save-excursion
      (goto-char (point-min))
      (while (search-forward-regexp
              "^\\s-*#\\+INCLUDE: *\"\\([^\"]+\\)\".*:range-\\(begin\\|end\\)"
              nil 'noerror)
        (let* ((file (expand-file-name (match-string-no-properties 1)))
               lines begin end)
          (forward-line 0)
          (when (looking-at "^.*:range-begin *\"\\([^\"]+\\)\"")
            (setq begin (match-string-no-properties 1)))
          (when (looking-at "^.*:range-end *\"\\([^\"]+\\)\"")
            (setq end (match-string-no-properties 1)))
          (setq lines (endless/decide-line-range file begin end))
          (when lines
            (if (looking-at ".*:lines *\"\\([-0-9]+\\)\"")
                (replace-match lines :fixedcase :literal nil 1)
              (goto-char (line-end-position))
              (insert " :lines \"" lines "\""))))))))

(defun endless/decide-line-range (file begin end)
  "Visit FILE and decide which lines to include.
BEGIN and END are regexps which define the line range to use."
  (let (l r)
    (save-match-data
      (with-temp-buffer
        (insert-file file)
        (goto-char (point-min))
        (if (null begin)
            (setq l "")
          (search-forward-regexp begin)
          (setq l (line-number-at-pos (match-beginning 0))))
        (if (null end)
            (setq r "")
          (search-forward-regexp end)
          (setq r (1+ (line-number-at-pos (match-end 0)))))
        (format "%s-%s" l r)))))

วิธีที่ดีที่สุดที่ฉันสามารถคิดได้คือการอัปเดตตัวเลขเหล่านี้ทันทีก่อนส่งออกหรือก่อนประเมินผล

Updater

นี่คือฟังก์ชันที่ต้องผ่านบัฟเฟอร์ คุณสามารถผูกมันไว้กับกุญแจหรือเพิ่มลงในตะขอ โค้ดต่อไปนี้จะอัพเดตบรรทัด เมื่อใดก็ตามที่คุณบันทึกไฟล์แต่ถ้ากรณีการใช้งานของคุณแตกต่างกันเพียงแค่ค้นหาว่าคุณต้องการ hook อะไร! (โหมดองค์กรเต็มไปด้วย hooks)

(add-hook 'before-save-hook #'endless/update-includes)

(defun endless/update-includes (&rest ignore)
  "Update the line numbers of all #+INCLUDE:s in current buffer.
Only looks at INCLUDEs that already have a line number listed!
This function does nothing if not in org-mode, so you can safely
add it to `before-save-hook'."
  (interactive)
  (when (derived-mode-p 'org-mode)
    (save-excursion
      (goto-char (point-min))
      (while (search-forward-regexp
              "^\\s-*#\\+INCLUDE: *\"\\([^\"]+\\)\".*:lines *\"\\([-0-9]+\\)\""
              nil 'noerror)
        (let* ((file (expand-file-name (match-string-no-properties 1)))
               (lines (endless/decide-line-range file)))
          (when lines
            (replace-match lines :fixedcase :literal nil 2)))))))

Regexps

นี่คือที่ที่คุณกำหนด regexps ซึ่งจะใช้เป็นบรรทัดแรกและบรรทัดสุดท้ายที่จะรวม คุณสามารถให้รายการ regexps สำหรับแต่ละนามสกุลไฟล์

(defcustom endless/extension-regexp-map 
  '(("sv" ("^class\\b" . "^endclass\\b") ("^enum\\b" . "^endenum\\b")))
  "Alist of regexps to use for each file extension.
Each item should be
    (EXTENSION (REGEXP-BEGIN . REGEXP-END) (REGEXP-BEGIN . REGEXP-END))
See `endless/decide-line-range' for more information."
  :type '(repeat (cons string (repeat (cons regexp regexp)))))

ผู้ทำงานเบื้องหลัง

นี่คือคนที่ทำงานส่วนใหญ่

(defun endless/decide-line-range (file)
  "Visit FILE and decide which lines to include.
The FILE's extension is used to get a list of cons cells from
`endless/extension-regexp-map'. Each cons cell is a pair of
regexps, which determine the beginning and end of region to be
included. The first one which matches is used."
  (let ((regexps (cdr-safe (assoc (file-name-extension file)
                                  endless/extension-regexp-map)))
        it l r)
    (when regexps
      (save-match-data
        (with-temp-buffer
          (insert-file file)
          (while regexps
            (goto-char (point-min))
            (setq it (pop regexps))
            (when (search-forward-regexp (car it) nil 'noerror)
              (setq l (line-number-at-pos (match-beginning 0)))
              (when (search-forward-regexp (cdr it) nil 'noerror)
                (setq regexps nil
                      r (line-number-at-pos (match-end 0))))))
          (when r (format "%s-%s" l (+ r 1))))))))