“ ป๊อป” หน้าต่างเข้าไปในกรอบ

บ่อยครั้งที่ฉันหน้าต่างของฉันถูกแบ่งโดยอัตโนมัติจนกว่าฉันจะตัดสินใจเองว่าเฟรมปัจจุบันไม่มีอสังหาริมทรัพย์เพียงพอสำหรับพวกเขาทั้งหมด เมื่อสิ่งนี้เกิดขึ้นฉันจะลบหน้าต่างด้วยตนเองสร้างเฟรมและสลับไปที่หน้าต่างที่ถูกลบนั้น ฉันจะเขียนฟังก์ชัน elisp ที่ทำสิ่งนี้ได้อย่างไร

ฉันเหนื่อย:

(defun pop-window-into-frame ()
  (interactive)
  (delete-window)
  (make-frame-command)
  (switch-to-prev-buffer))

แต่ด้วยเหตุผลบางอย่างนี้ไม่ได้ทำในสิ่งที่ฉันคิดว่ามันควร

ลองใช้สิ่งนี้แทน:

(defun my-turn-current-window-into-frame ()
  (interactive)
  (let ((buffer (current-buffer)))
    (unless (one-window-p)
      (delete-window))
    (display-buffer-pop-up-frame buffer nil)))

;; Inspired from `mouse-tear-off-window'.
(defun tear-off-window ()
  "Create a new frame displaying buffer of selected window.
    If window is not the only one in frame, then delete it.
    Otherwise, this command effectively clones the frame and window."
  (interactive)
  (let ((owin  (selected-window))
        (buf   (window-buffer))
        (fr    (make-frame)))
    (select-frame fr)
    (switch-to-buffer buf)
    (save-window-excursion 
      (select-window owin)
      (unless (one-window-p) (delete-window owin)))))

frame-cmds.elคำสั่งนี้เช่นเดียวกับการต่อไปซึ่งไม่ทำอะไรเลยถ้าหน้าต่างที่เลือกเป็นคนเดียวในกรอบของตนที่มีอยู่ในห้องสมุด

(defun tear-off-window-if-not-alone ()
  "Move selected window to a new frame, unless it is alone in its frame.
If it is alone, do nothing.  Otherwise, delete it and create a new
frame showing the same buffer."
  (interactive)
  (if (one-window-p 'NOMINI)
      (message "Sole window in frame")
    (tear-off-window)))