วิธีการเติมภูมิภาค / วรรคระบุคำนำหน้าย่อหน้า?

สมมุติว่าฉันมีบัฟเฟอร์ต่อไปนี้

1. lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum

การกดปุ่มM-qที่นี่ในขณะที่text-modeนำไปสู่การต่อไปนี้

1. lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem
ipsum lorem ipsum lorem ipsum lorem ipsum

ในทางตรงกันข้ามถ้าฉันเปิดใช้งานmarkdown-modeฉันได้รับดังต่อไปนี้ (Markdown เป็นเพียงตัวอย่างคุณจะเห็นพฤติกรรมที่คล้ายกันในโหมดต่างๆ)

1. lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem ipsum lorem
   ipsum lorem ipsum lorem ipsum lorem ipsum

ฉันจะกำหนดค่าโหมดข้อความให้ทำอย่างไร

ผมคิดนี้สามารถทำได้โดยการ writting พิเศษfill-paragraph-functionแต่ตัวแปรนี้จะถูกตั้งค่าเพียงเพื่อnilในmarkdown-modeจึงมีอาจจะเป็นวิธีที่ง่าย

ฉันเป็นผู้ใช้ที่มีความสุขของโหมด filladapt มาเป็นเวลานานซึ่งจัดการสิ่งเหล่านี้ได้เป็นอย่างดี สำหรับข้อมูลดู

http://emacswiki.org/emacs/FillAdapt

จากหน้านั้น:

Filladapt โดย KyleJones ปรับปรุงฟังก์ชั่นเติมของ Emacs โดยคาดเดาคำนำหน้าการเติมเช่นลำดับความคิดเห็นในรหัสโปรแกรมและการจัดการสัญลักษณ์หัวข้อย่อยเช่น "1" หรือ "*".

ตัวอย่างเช่นมันสามารถเปลี่ยนสิ่งนี้ได้

* Pretend I'm a really super long line.
* And the window's narrow.

เข้าไป

* Pretend I'm a really super
  long line.
* And the window's narrow.

(fill-paragraph &optional JUSTIFY REGION)

[...]

If `fill-paragraph-function' is non-nil, we call it (passing our
argument to it), and if it returns non-nil, we simply return its value.

If `fill-paragraph-function' is nil, return the `fill-prefix' used for filling.

[...]

markdown-modeสันนิษฐานว่าตั้งfill-paragraph-functionไว้nilเพื่อให้ฟังก์ชั่นใช้fill-prefixทำการเติม

(let ((fill-prefix (make-string (length "1. ") ? ))
  (fill-paragraph))

ตัวอย่างเต็มรูปแบบ:

(let* ((num 15)
       (numstr (format "%d. " num))
       (fill-prefix (make-string (length numstr) ? )))
  (with-temp-buffer
    (loop for i from 1 to 15 do
          (insert (format "lorem ipsum (%d) doler sit amet " i)))
    (beginning-of-line)
    (insert numstr)
    (fill-paragraph)
    (buffer-string)))

;; =>

"\
15. lorem ipsum (1) doler sit amet lorem ipsum (2) doler sit amet
    lorem ipsum (3) doler sit amet lorem ipsum (4) doler sit amet
    lorem ipsum (5) doler sit amet lorem ipsum (6) doler sit amet
    lorem ipsum (7) doler sit amet lorem ipsum (8) doler sit amet
    lorem ipsum (9) doler sit amet lorem ipsum (10) doler sit amet
    lorem ipsum (11) doler sit amet lorem ipsum (12) doler sit amet
    lorem ipsum (13) doler sit amet lorem ipsum (14) doler sit amet
    lorem ipsum (15) doler sit amet "

ส่วนสำคัญของฌอนชี้ให้ฉันไปในทิศทางที่ถูกต้องและนี่คือตัวอย่างที่แก้ไขได้

(defun my-adaptive-fill-function ()
  "Return prefix for filling paragraph or nil if not determined."
  (cond
   ;; List item inside blockquote
   ((looking-at "^[ \t]*>[ \t]*\\([0-9]+\\.\\|[*+-]\\)[ \t]+")
    (replace-regexp-in-string
     "[0-9\\.*+-]" " " (match-string-no-properties 0)))
   ;; Blockquote
   ((looking-at "^[ \t]*>[ \t]*")
    (match-string-no-properties 0))
   ;; List items
   ((looking-at "^\\([ \t]*\\)\\([0-9]+\\.\\|[\\*\\+-]\\)\\([ \t]+\\)")
    (match-string-no-properties 0))
   ;; No match
   (t nil)))

;; Paragraph filling in text-mode.
(add-hook 'text-mode-hook
  (lambda ()
    (set (make-local-variable 'paragraph-start)
         "\f\\|[ \t]*$\\|[ \t]*[*+-] \\|[ \t]*[0-9]+\\.[ \t]\\|[ \t]*: ")
    (set (make-local-variable 'paragraph-separate)
         "\\(?:[ \t\f]*\\|.*  \\)$")
    (set (make-local-variable 'adaptive-fill-first-line-regexp)
         "\\`[ \t]*>[ \t]*?\\'")
    (set (make-local-variable 'adaptive-fill-function)
         'my-adaptive-fill-function)))