ดังนั้น…ฉันได้ทำงานกับ VBScript เล็กน้อยที่สามารถ:
- ถ่ายรูป VSS อย่างต่อเนื่อง
- ต่อเชื่อมเข้ากับโฟลเดอร์ (ซึ่งคุณสามารถสำรองไฟล์ได้)
- unmount VSS snapshots
ต้องอาศัยvshadow.exe( เอกสารประกอบ ) ซึ่งเป็นส่วนหนึ่งของVolume Shadow Copy Service SDK 7.2ตามที่มีอยู่จาก Microsoft ฉันทำงานกับเวอร์ชันนี้: " VSHADOW.EXE 2.2 - ไคลเอ็นต์ตัวอย่าง Volume Shadow Copy, ลิขสิทธิ์ (C) 2005 Microsoft Corporation "
โดยทั่วไปมันเป็น wrapper เล็กน้อยเรียบร้อยรอบคำสั่ง vshadow สี่เหล่านี้:
vshadow.exe -q - แสดงรายการ Shadow Copy ทั้งหมดในระบบ
vshadow.exe -p {รายการไดรฟ์ข้อมูล} - จัดการสำเนาเงาถาวร
vshadow.exe -el = {SnapID}, dir - แสดง shadow copy เป็นจุดเชื่อมต่อ
vshadow.exe -ds = {SnapID} - ลบสำเนาเงานี้
นี่คือหน้าจอความช่วยเหลือ:
เครื่องมือสร้าง / ติดตั้ง VSS Snapshot
การใช้งาน:
cscript / nologo VssSnapshot.vbs / target: path {/ volume: X | / unmount} [/ debug]
/ volume - อักษรชื่อไดรฟ์ของไดรฟ์ข้อมูลเพื่อ snapshot
/ target - พา ธ (สัมบูรณ์หรือญาติ) เพื่อเมานต์สแนปชอต
/ debug - swich บนเอาต์พุตการดีบัก
ตัวอย่าง:
cscript / nologo VssSnapshot.vbs / target: C: \ Backup \ DriveD / ไดรฟ์ข้อมูล: D
cscript / nologo VssSnapshot.vbs / target: C: \ Backup \ DriveD / unmount
คำแนะนำ: ไม่จำเป็นต้องยกเลิกการต่อเชื่อมก่อนถ่ายภาพใหม่
ตัวอย่างผลลัพธ์ที่นี่:
C: \ VssSnapshot> cscript / nologo VssSnapshot.vbs / เป้าหมาย: MountPoints \ E / ปริมาณ: E
05/03/2010 17:13:04 เตรียมจุดเมานต์ VSS ...
05/03/2010 17:13:04 น. เตรียมจุดเมานต์ที่: C: \ VssSnapshot \ MountPoints \ E
05/03/2010 17:13:04 น. สร้างสแน็ปช็อต VSS สำหรับปริมาณ: E
05/03/2010 17:13:08 สร้างสแนปชอตด้วย ID: {4ed3a907-c66f-4b20-bda0-9dcda3b667ec}
05/03/2010 17:13:08 ภาพรวม VSS ติดตั้งสำเร็จแล้ว
05/03/2010 17:13:08 นเสร็จสิ้น
C: \ VssSnapshot> cscript / nologo VssSnapshot.vbs / target: MountPoints \ E / unmount
05/03/2010 17:13:35 เตรียมจุดเมานต์ VSS ...
05/03/2010 17:13:36 ไม่มีอะไรให้ทำอีกแล้ว
05/03/2010 17:13:36 เสร็จแล้ว
และนี่คือสคริปต์ของตัวเอง ข้อจำกัดความรับผิดชอบตามปกติ: ซอฟต์แวร์นี้มีให้ตามที่เป็นฉันจะไม่รับประกันใช้ความเสี่ยงของคุณเองหากมีบางสิ่งผิดพลาดเพียงอย่างเดียวที่จะโทษตัวเอง ฉันทดสอบมันค่อนข้างละเอียดแม้ว่ามันจะใช้ได้ดีสำหรับฉัน อย่าลังเลที่จะแจ้งให้ฉันทราบข้อบกพร่องใด ๆ ผ่านความคิดเห็นด้านล่าง
''# VssSnapshot.vbs
''# http://serverfault.com/questions/119120/how-to-use-a-volume-shadow-copy-to-make-backups/119592#119592
Option Explicit
Dim fso: Set fso = CreateObject("Scripting.FileSystemObject")
''# -- MAIN SCRIPT -------------------------------------------
Dim args, snapshotId, targetPath, success
Set args = WScript.Arguments.Named
CheckEnvironment
Log "preparing VSS mount point..."
targetPath = PrepareVssMountPoint(args("target"))
If args.Exists("unmount") Then
Log "nothing else to do"
ElseIf targetPath <> vbEmpty Then
Log "mount point prepared at: " & targetPath
Log "creating VSS snapshot for volume: " & args("volume")
snapshotId = CreateVssSnapshot(args("volume"))
If snapshotId <> vbEmpty Then
Log "snapshot created with ID: " & snapshotId
success = MountVssSnapshot(snapshotId, targetPath)
If success Then
Log "VSS snapshot mounted sucessfully"
Else
Die "failed to mount snapshot"
End If
Else
Die "failed to create snapshot"
End If
Else
Die "failed to prepare mount point"
End If
Log "finished"
''# -- FUNCTIONS ---------------------------------------------
Function PrepareVssMountPoint(target) ''# As String
Dim cmd, result, outArray
Dim path, snapshot, snapshotId
Dim re, matches, match
PrepareVssMountPoint = VbEmpty
target = fso.GetAbsolutePathName(target)
If Not fso.FolderExists(fso.GetParentFolderName(target)) Then
Die "Invalid mount point: " & target
End If
''# create or unmount (=delete existing snapshot) mountpoint
If Not fso.FolderExists(target) Then
If Not args.Exists("unmount") Then fso.CreateFolder target
Else
Set re = New RegExp
re.MultiLine = False
re.Pattern = "- Exposed locally as: ([^\r\n]*)"
cmd = "vshadow -q"
result = RunCommand(cmd, false)
outarray = Split(result, "*")
For Each snapshot In outArray
snapshotId = ParseSnapshotId(snapshot)
If snapshotId <> vbEmpty Then
Set matches = re.Execute(snapshot)
If matches.Count = 1 Then
path = Trim(matches(0).SubMatches(0))
If fso.GetAbsolutePathName(path) = target Then
cmd = "vshadow -ds=" & snapshotId
RunCommand cmd, true
Exit For
End If
End If
End If
Next
If args.Exists("unmount") Then fso.DeleteFolder target
End If
PrepareVssMountPoint = target
End Function
Function CreateVssSnapshot(volume) ''# As String
Dim cmd, result
If Not fso.DriveExists(volume) Then
Die "Drive " & volume & " does not exist."
End If
cmd = "vshadow -p " & Replace(UCase(volume), ":", "") & ":"
result = RunCommand(cmd, false)
CreateVssSnapshot = ParseSnapshotId(result)
End Function
Function MountVssSnapshot(snapshotId, target) ''# As Boolean
Dim cmd, result
If fso.FolderExists(targetPath) Then
cmd = "vshadow -el=" & snapshotId & "," & targetPath
result = RunCommand(cmd, true)
Else
Die "Mountpoint does not exist: " & target
End If
MountVssSnapshot = (result = "0")
End Function
Function ParseSnapshotId(output) ''# As String
Dim re, matches, match
Set re = New RegExp
re.Pattern = "SNAPSHOT ID = (\{[^}]{36}\})"
Set matches = re.Execute(output)
If matches.Count = 1 Then
ParseSnapshotId = matches(0).SubMatches(0)
Else
ParseSnapshotId = vbEmpty
End If
End Function
Function RunCommand(cmd, exitCodeOnly) ''# As String
Dim shell, process, output
Dbg "Running: " & cmd
Set shell = CreateObject("WScript.Shell")
On Error Resume Next
Set process = Shell.Exec(cmd)
If Err.Number <> 0 Then
Die Hex(Err.Number) & " - " & Err.Description
End If
On Error GoTo 0
Do While process.Status = 0
WScript.Sleep 100
Loop
output = Process.StdOut.ReadAll
If process.ExitCode = 0 Then
Dbg "OK"
Dbg output
Else
Dbg "Failed with ERRORLEVEL " & process.ExitCode
Dbg output
If Not process.StdErr.AtEndOfStream Then
Dbg process.StdErr.ReadAll
End If
End If
If exitCodeOnly Then
Runcommand = process.ExitCode
Else
RunCommand = output
End If
End Function
Sub CheckEnvironment
Dim argsOk
If LCase(fso.GetFileName(WScript.FullName)) <> "cscript.exe" Then
Say "Please execute me on the command line via cscript.exe!"
Die ""
End If
argsOk = args.Exists("target")
argsOk = argsOk And (args.Exists("volume") Or args.Exists("unmount"))
If Not argsOk Then
Say "VSS Snapshot Create/Mount Tool" & vbNewLine & _
vbNewLine & _
"Usage: " & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:path { /volume:X | /unmount } [/debug]" & _
vbNewLine & vbNewLine & _
"/volume - drive letter of the volume to snapshot" & _
vbNewLine & _
"/target - the path (absolute or relative) to mount the snapshot to" & _
vbNewLine & _
"/debug - swich on debug output" & _
vbNewLine & vbNewLine & _
"Examples: " & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:C:\Backup\DriveD /volume:D" & vbNewLine & _
"cscript /nologo " & fso.GetFileName(WScript.ScriptFullName) & _
" /target:C:\Backup\DriveD /unmount" & _
vbNewLine & vbNewLine & _
"Hint: No need to unmount before taking a new snapshot." & vbNewLine
Die ""
End If
End Sub
Sub Say(message)
If message <> "" Then WScript.Echo message
End Sub
Sub Log(message)
Say FormatDateTime(Now()) & " " & message
End Sub
Sub Dbg(message)
If args.Exists("debug") Then
Say String(75, "-")
Say "DEBUG: " & message
End If
End Sub
Sub Die(message)
If message <> "" Then Say "FATAL ERROR: " & message
WScript.Quit 1
End Sub
ฉันหวังว่านี่จะช่วยใครซักคน รู้สึกอิสระที่จะใช้ในการตามซีซีโดย-SA ทั้งหมดที่ฉันถามก็คือคุณจะต้องทิ้งลิงค์ไว้เหมือนเดิม