ไฟล์แบตช์ของ Windows มีโครงสร้าง *% หรือไม่

ในแบตช์ไฟล์ฉันต้องทำ (เช่น) สิ่งต่อไปนี้หรือไม่?

@echo off
call other.bat %1 %2 %3 %4 %5 %6 %7 %8 %9

ไฟล์แบตช์ Windows (ตั้งแต่ Windows XP แต่อาจเป็นไปได้ก่อนหน้านี้) รองรับการ%*สร้างซึ่งประเมินพารามิเตอร์ทั้งหมดจาก% 1 เป็นต้นไป

น่าเสียดายที่นี่ไม่เคารพSHIFTคำสั่งดังนั้นสิ่งต่อไปนี้จะไม่ทำงาน:

@echo off
set EATEN=%1
shift

call other.bat %*

มันจะยังคงผ่านพารามิเตอร์แรกไปยังไฟล์ชุดที่สอง

คุณสามารถรวบรวม args ทั้งหมดเข้าด้วยกันโดยใช้สิ่งที่ชอบ:

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

วิธีนี้ใช้งานได้โดยไม่คำนึงว่ามีอาร์กิวเมนต์เท่าใด

หากคุณต้องการข้ามพารามิเตอร์ 3 ตัวแรกตัวอย่างเช่นและผ่านส่วนที่เหลือ:

@echo off
for /f "tokens=1-3*" %%a in ("%*") do (
   set par1=%%a
   set par2=%%b
   set par3=%%c
   set therest=%%d
   )

call other.bat %therest%

อาจมีปัญหากับคำพูดในพารามิเตอร์

รุ่งโรจน์ถึง Patrick Cuff, /programming/382587/how-to-get-batch-file-parameters-from-nth-position-on

ใช่.

คุณสามารถเขียนตัวอย่างของคุณดังนี้:

@echo off
call other.bat %*

นอกจากนี้: การเปลี่ยนแปลงการสนับสนุนบน Windows ... ดูนี้
แต่แท้จริงแล้วลิงค์สุดท้ายยืนยันว่าการเปลี่ยนแปลงไม่ทำงานร่วมกับ% *:

•การใช้% * พร้อมshift
  shiftไม่มีผลกับพารามิเตอร์ชุด%%

@echo off
cls
setlocal enabledelayedexpansion

:: Disable the display of information by changing [set "_ENABLE_INFO="] to [set "_ENABLE_INFO=::"].
set "_ENABLE_INFO="
set _DBQ="

set "_PARMS.ORIGINAL=%*" && if defined _PARMS.ORIGINAL (
   if not defined _PARMS.IDX (
      echo Parameter Index^(es^) to extract eg.:
      echo 1 2 5 9 11 39 400
      set /p "_PARMS.IDX=>"
   )
   set "_PARMS.IDX=¡!_PARMS.IDX: =¡ ¡!¡"
   set "_PARMS.IDX=!_PARMS.IDX:¡¡=!"
   set "_PARMS.IDX=!_PARMS.IDX: =!"
   call :_FN_PROC.STRING %*
%_ENABLE_INFO% goto :FINISH
   goto :eof
) else (
   echo No input parameters.
)
goto :eof


:_FN_PROC.STRING
set "_PARMS.PROCESS.STRING=%*"
:_FN_PROC.STRING.LOOP
set "_PARMS.PROCESS.STRING=!_PARMS.PROCESS.STRING:%_DBQ%=¡!"
set /a _PARMS.COUNT+=1
for /f "tokens=1* delims= " %%a in ("!_PARMS.PROCESS.STRING!") do (
   set _PARMS.TMP.CHECK=%%a
   set _PARMS.PROCESS.STRING=%%b
   if "!_PARMS.TMP.CHECK!" NEQ "!_PARMS.TMP.CHECK:¡=!" (
      for /f "tokens=1* delims=¡" %%c in ("%%a !_PARMS.PROCESS.STRING!") do (
         set _PARMS.TMP.CHECK="%%c"
         set _PARMS.PROCESS.STRING=%%d
      )
   )
)

if "!_PARMS.IDX:¡%_PARMS.COUNT%¡=!" EQU "!_PARMS.IDX!" (
   set _PARMS.REMAINING=!_PARMS.REMAINING! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX!{%_PARMS.COUNT%}
) else (
   set _PARMS.EXTRACTED=!_PARMS.EXTRACTED! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX:¡%_PARMS.COUNT%¡=!
   set _PARMS.IDX=!_PARMS.IDX![%_PARMS.COUNT%]
)

if "!_PARMS.PROCESS.STRING: =!"=="" (set _PARMS.PROCESS.STRING=)
if defined _PARMS.PROCESS.STRING (goto :_FN_PROC.STRING.LOOP)

set _DBQ=
set _PARMS.TMP.CHECK=
if defined _PARMS.REMAINING (set _PARMS.REMAINING=!_PARMS.REMAINING:~1!)
if defined _PARMS.EXTRACTED (set _PARMS.EXTRACTED=!_PARMS.EXTRACTED:~1!)
goto :eof


:FINISH
echo.
echo _PARMS.IDX ^:
echo    ¡^=¡ no Parameter Index was specified for extraction.
echo    ¡n¡ nth Parameter was not processed (Index larger than Parameters Count).
echo    [n] nth Parameter was Extracted.
echo    {n} nth Parameter was Ignored (Remaining).
echo.
set _
goto :eof