การกระจายตัวของสารตกค้างที่คาดหวังในตัวแบบเชิงเส้นทั่วไปคืออะไร

ฉันกำลังแสดงโมเดลเชิงเส้นทั่วไปที่ฉันต้องระบุครอบครัวที่แตกต่างจากครอบครัวปกติ

• การกระจายของสารตกค้างที่คาดหวังคืออะไร?
• ตัวอย่างเช่นส่วนที่เหลือควรกระจายตามปกติ?

What is the expected distribution of residuals?

มันแตกต่างกันไปตามรุ่นในรูปแบบที่ทำให้เป็นไปไม่ได้ที่จะตอบโดยทั่วไป

For example, should the residuals be distributed normally?

ไม่ปกติไม่

มีอุตสาหกรรมกระท่อมทั้งหมดซึ่งมีศูนย์กลางอยู่ที่การออกแบบส่วนที่เหลือสำหรับ GLMs ซึ่งมีความสมมาตรมากกว่าหรือแม้แต่ประมาณ "ปกติ" (เช่น Gaussian), เช่นเพียร์สัน, เช่นเพียร์สัน, Anscombe ที่เหลือ, (ปรับปรุง) . Hardin และ Joseph M. Hilbe (2007) "รุ่นที่สองและส่วนขยายเชิงเส้นทั่วไป" รุ่นที่สอง College Station, TX: Stata Press หากตัวแปรตามนั้นไม่ต่อเนื่อง (ตัวแปรตัวบ่งชี้หรือจำนวน) มันก็เป็นเรื่องยากมากที่จะทำให้การกระจายตัวที่เหลือของเกาส์เสียนอย่างแน่นอน

สิ่งหนึ่งที่คุณสามารถทำได้คือจำลองข้อมูลใหม่ซ้ำ ๆ ภายใต้สมมติฐานที่ว่าโมเดลของคุณเป็นจริงประเมินโมเดลของคุณโดยใช้ข้อมูลจำลองและคำนวณค่าส่วนที่เหลือแล้วเปรียบเทียบส่วนที่เหลือจริงกับค่าจำลองที่เหลืออยู่ ใน Stata ฉันจะทำเช่นนี้:

sysuse nlsw88, clear
glm wage i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)

// collect which observations were used in estimation and the predicted mean
gen byte touse = e(sample)
predict double mu if touse

// predict residuals
predict resid if touse, anscombe

// prepare variables for plotting a cumulative distribution function
cumul resid, gen(c)

// collect the graph command in the local macro `graph'
local graph "twoway"

// create 19 simulations:
gen ysim = .
forvalues i = 1/19 {
    replace ysim = rpoisson(mu) if touse
    glm ysim i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)
    predict resid`i' if touse, anscombe
    cumul resid`i', gen(c`i')
    local graph "`graph' line c`i' resid`i', sort lpattern(solid) lcolor(gs8) ||"
}
local graph "`graph' line c resid, sort lpattern(solid) lcolor(black) "

// display the graph
`graph' legend(order(20 "actual residuals" 1 "simulations"))