วิธีแทนที่สตริงที่สามในไฟล์โดยใช้sedคำสั่ง

ตัวอย่าง:

เปลี่ยนเฉพาะเหตุการณ์ที่สามของisเป็นusในไฟล์

ไฟล์อินพุตของฉันประกอบด้วย:

hai this is linux.
hai this is unix.
hai this is mac.
hai this is unchanged.

ฉันคาดหวังผลลัพธ์คือ:

hai this is linux.
hai thus is unix.
hai this is mac.
hai this is unchanged.

ทำได้ง่ายขึ้นมากด้วย perlมันมากทำง่ายขึ้นด้วย

ในการเปลี่ยน 3 ^ถเกิดขึ้น:

perl -pe 's{is}{++$n == 3 ? "us" : $&}ge'

ในการเปลี่ยนทุก 3 ^ถเกิดขึ้น:

perl -pe 's{is}{++$n % 3 ? $& : "us"}ge'

เมื่อสตริงการแทนที่เกิดขึ้นเพียงครั้งเดียวต่อบรรทัดคุณสามารถรวมโปรแกรมอรรถประโยชน์ที่แตกต่างกัน
เมื่ออินพุตอยู่ในไฟล์ "อินพุต" และคุณกำลังแทนที่ "คือ" โดย "เรา" คุณสามารถใช้

LINENR=$(cat input | grep -n " is " | head -3 | tail -1 | cut -d: -f1)
cat input | sed ${LINENR}' s/ is / us /'

สคริปต์ด้านล่าง (ใช้ไวยากรณ์GNU sed ) ใช้งานได้สำหรับการแก้ไขในที่ไม่ใช่สำหรับการส่งออกเพราะมันจะหยุดสายการพิมพ์หลังจากการทดแทนที่ต้องการ:

sed -i '/is/{: 1 ; /\(.*is\)\{3\}/!{N;b1} ; s/is/us/3 ; q}' text.file

หากการตัดสินใจของคุณเช่นchorobaคุณสามารถแก้ไขด้านบนเป็น

sed '/is/{:1 ; /\(.*is\)\{3\}/!{N;b1} ; s/is/us/3 ; :2 ; n ; $!b2}' text.file

ซึ่งเอาต์พุตทุกบรรทัด

หรือคุณต้องใส่ทุกบรรทัดในพื้นที่รูปแบบ (ในหน่วยความจำดังนั้นระวังข้อ จำกัด ขนาด) และทำการทดแทน

sed ': 1 ; N ; $!b1 ; s/is/us/3 ' text.file

คุณสามารถใช้sedสำหรับการที่หากบรรทัดใหม่ก่อนหน้านี้จะถูกแทนที่เป็นอักขระอื่น ๆ เช่น:

tr '\n' '\000' | sed 's/is/us/3' | tr '\000' '\n'

และเหมือนกันกับ pure (GNU) sed:

sed ':a;N;$!ba;s/\n/\x0/g;s/is/us/3;s/\x0/\n/g'

_{(การขึ้นsedบรรทัดใหม่ถูกขโมยอย่างไร้ยางอายจากhttps://stackoverflow.com/a/1252191/4488514 )}

p='[:punct:]' s='[:space:]'
sed -Ee'1!{/\n/!b' -e\}            \
     -e's/(\n*)(.*)/ \2 \1/'       \
     -e"s/is[$p]?[$s]/\n&/g"       \
     -e"s/([^$s])\n/\1/g;1G"       \
-e:c -e"s/\ni(.* )\n{3}/u\1/"      \
     -e"/\n$/!s/\n//g;/\ni/G"      \
     -e's//i/;//tc'                \
     -e's/^ (.*) /\1/;P;$d;N;D'

บิตเหล่าsedนั้นมีจำนวนisครั้งเกิดขึ้นจากหนึ่งบรรทัดไปยังอีกบรรทัดหนึ่ง มันควรจะจัดการได้อย่างน่าเชื่อถือisต่อ es มากที่สุดเท่าที่คุณโยนมันและมันไม่จำเป็นต้องบัฟเฟอร์บรรทัดเก่าในขณะที่มันทำ - มันเพียงแค่รักษาอักขระบรรทัดใหม่เดียวสำหรับทุกisที่พบซึ่งไม่ได้เป็นส่วนหนึ่งของคำอื่น

ผลที่สุดคือมันจะแก้ไขเพียงครั้งที่สามที่เกิดขึ้นในไฟล์ - และมันจะดำเนินการนับต่อบรรทัด ดังนั้นหากไฟล์มีลักษณะดังนี้:

1. is is isis
2. is does

... มันจะพิมพ์ ...

1. is is isis
2. us does

มันจัดการกับกรณีขอบโดยการใส่ช่องว่างที่หัวและส่วนท้ายของทุกบรรทัด ทำให้ขอบเขตของคำง่ายขึ้นเล็กน้อยในการตรวจสอบให้แน่ใจ

ถัดไปจะค้นหาises ที่ถูกต้องโดยการแทรก\newline ก่อนที่เหตุการณ์ทั้งหมดนั้นจะเกิดขึ้นisทันทีนำหน้าศูนย์หรืออักขระเครื่องหมายวรรคตอนหนึ่งอันตามด้วยช่องว่างในทันที มันจะส่งผ่านอีกครั้งและลบ\newlines ทั้งหมดที่นำหน้าด้วยอักขระที่ไม่ใช่ช่องว่างทันที เครื่องหมายนี้ทิ้งไว้ข้างหลังจะตรงis.และisแต่ไม่thisหรือ?isหรือ

รวบรวมต่อไปแต่ละเครื่องหมายถึงหางของสตริง - สำหรับทุก\niการแข่งขันบนเส้นมันผนวก\newline ถึงหางของสตริงและแทนที่มันด้วยกับทั้งหรือi uหากมี 3 \newlines ในแถวที่รวมกันที่ส่วนท้ายของสตริงจะใช้ u - else i ครั้งแรกที่ใช้ au เป็นครั้งสุดท้าย - การแทนที่จะกำหนดลูปที่ไม่มีที่สิ้นสุดซึ่งจะลดลงget line, print line, get line, print line,เรื่อย ๆ

ในตอนท้ายของแต่ละรอบลองลูปมันจะล้างช่องว่างที่แทรกไว้พิมพ์เฉพาะบรรทัดใหม่ที่เกิดขึ้นครั้งแรกในพื้นที่รูปแบบและไปอีกครั้ง

ฉันจะเพิ่มlคำสั่ง ook ที่ส่วนหัวของห่วงเช่น:

l; s/\ni(.* )\n{9}/u\1/...

... และดูว่ามันทำงานอย่างไรกับข้อมูลนี้:

hai this is linux.
hai this is unix.


hai this is mac.
hai this is unchanged is.

... ดังนั้นนี่คือสิ่งที่ทำ:

 hai this \nis linux. \n$        #behind the scenes
hai this is linux.               #actually printed
 hai this \nis unix. \n\n$       #it builds the marker string
hai this is unix.
  \n\n\n$                        #only for lines matching the

  \n\n\n$                        #pattern - and not otherwise.

 hai this \nis mac. \n\n\n$      #here's the match - 3 ises so far in file.
hai this us mac.                 #printed
hai this is unchanged is.        #no look here - this line is never evaled

มันสมเหตุสมผลมากกว่าบางทีอาจมีises ต่อบรรทัดมากขึ้น:

nthword()(  p='[:punct:]' s='[:space:]'         
    sed -e '1!{/\n/!b' -e\}             \
        -e 's/\(\n*\)\(.*\)/ \2 \1/'    \
        -e "s/$1[$p]\{0,1\}[$s]/\n&/g"  \
        -e "s/\([^$s]\)\n/\1/g;1G;:c"   \
        -e "${dbg+l;}s/\n$1\(.* \)\n\{$3\}/$2\1/" \
        -e '/\n$/!s/\n//g;/\n'"$1/G"    \
        -e "s//$1/;//tc" -e 's/^ \(.*\) /\1/'     \
        -e 'P;$d;N;D'
)        

นั่นคือสิ่งเดียวกัน แต่เขียน w / POSIX BRE และการจัดการอาร์กิวเมนต์เบื้องต้น

 printf 'is is. is? this is%.0s\n' {1..4}  | nthword is us 12

... ได้รับ ...

is is. is? this is
is is. is? this is
is is. is? this us
is is. is? this is

... และถ้าฉันเปิดใช้งาน${dbg}:

printf 'is is. is? this is%.0s\n' {1..4}  | 
dbg=1 nthword is us 12

... เราสามารถดูมันซ้ำ ...

 \nis \nis. \nis? this \nis \n$
 is \nis. \nis? this \nis \n\n$
 is is. \nis? this \nis \n\n\n$
 is is. is? this \nis \n\n\n\n$
is is. is? this is
 \nis \nis. \nis? this \nis \n\n\n\n\n$
 is \nis. \nis? this \nis \n\n\n\n\n\n$
 is is. \nis? this \nis \n\n\n\n\n\n\n$
 is is. is? this \nis \n\n\n\n\n\n\n\n$
is is. is? this is
 \nis \nis. \nis? this \nis \n\n\n\n\n\n\n\n\n$
 is \nis. \nis? this \nis \n\n\n\n\n\n\n\n\n\n$
 is is. \nis? this \nis \n\n\n\n\n\n\n\n\n\n\n$
 is is. is? this \nis \n\n\n\n\n\n\n\n\n\n\n\n$
is is. is? this us
is is. is? this is

นี่คือโซลูชันเชิงตรรกะที่ใช้sedและtrแต่ต้องเขียนในสคริปต์เพื่อให้ทำงานได้ โค้ดด้านล่างแทนที่ทุกเกิดขึ้นที่ 3ของคำที่ระบุไว้ในsedคำสั่ง แทนที่i=3ด้วยเพื่อให้งานนี้สำหรับการใด ๆi=nn

รหัส:

# replace new lines with '^' character to get everything onto a single line
tr '\n' '^' < input.txt > output.txt

# count number of occurrences of the word to be replaced
num=`grep -o "apple" "output.txt" | wc -l`

# in successive iterations, replace the i + (n-1)th occurrence
n=3
i=3
while [ $i -le $num ]
do
    sed -i '' "s/apple/lemon/${i}" 'output.txt'
    i=$(( i + (n-1) ))
done

# replace the '^' back to new line character
tr '^' '\n' < output.txt > tmp && mv tmp output.txt

ทำไมจึงใช้งานได้:

a b b b b a c a d a b b b a b e b z b s b a bสมมติว่าแฟ้มข้อความเป็น

• เมื่อ n = 2: bเราต้องการที่จะเปลี่ยนทุกการเกิดที่สองของ

  • a b b b b a c a d a b b b a b e b z b s b a b
. . ^ . ^ . . . . . . ^ . . ^ . . . ^ . ^ . ^
  • ก่อนอื่นเราแทนที่เหตุการณ์ที่สองจากนั้นก็เกิดเหตุการณ์ที่ 3 จากนั้นก็เปลี่ยนที่ 4, 5 และอื่น ๆ นับตามลำดับที่แสดงด้านบนเพื่อดูตัวคุณเอง

• เมื่อ n = 3: bเราต้องการที่จะเปลี่ยนทุกที่เกิดขึ้นในสามของ

  • a b b b b a c a d a b b b a b e b z b s b a b
. . . ^ . . . . . . . ^ . . . . ^ . . . . . ^
  • ก่อนอื่นเราแทนที่เหตุการณ์ที่ 3 จากนั้นเป็นวันที่ 5 จากนั้นก็วันที่ 7, 9, 11 และอื่น ๆ

• เมื่อ n = 4: bเราต้องการที่จะเปลี่ยนทุกที่เกิดขึ้นในสามของ

  • ก่อนอื่นเราแทนที่เหตุการณ์ที่ 4 จากนั้น 7 จากนั้น 10 และ 13 และต่อไปเรื่อย ๆ