วิธีรับข้อมูลต่อท้ายของไฟล์เก็บถาวร gzip?

ฉันมีไฟล์เก็บถาวร gzip ที่มีข้อมูลต่อท้าย ถ้าฉันแกะมันโดยใช้gzip -dมันบอกฉันว่า: " decompression OK, trailing garbage ละเว้น " (เหมือนกับการไปgzip -tซึ่งสามารถใช้เป็นวิธีการตรวจสอบว่ามีข้อมูลดังกล่าว)

ตอนนี้ฉันอยากทำความรู้จักกับขยะนี้ แต่ก็แปลกพอที่ฉันจะไม่สามารถแยกมันออกมาได้ gzip -l --verboseบอกฉันว่าขนาด "บีบอัด" ของไฟล์เก็บถาวรคือขนาดของไฟล์ (เช่นกับข้อมูลต่อท้าย) นั่นผิดและไม่เป็นประโยชน์ fileฉันก็ไม่ได้รับความช่วยเหลือฉันจะทำอย่างไรดี?

คิดออกตอนนี้วิธีการรับข้อมูลต่อท้าย

ฉันสร้าง Perl สคริปต์ซึ่งจะสร้างไฟล์ที่มีข้อมูลที่ต่อท้ายก็หนักขึ้นในhttps://bugs.debian.org/cgi-bin/bugreport.cgi?bug=604617#10 :

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}