ฉันใช้bindkey -v(สำหรับ bash-ers set -o viฉันคิดว่ามันใช้งานได้ในโหมด zsh ด้วย) หรือโหมด vi (m) แต่มันทำให้ฉันสับสนว่าฉันไม่มีคิวภาพใด ๆ ที่จะบอกฉันว่าฉันอยู่ในโหมดแทรกหรือโหมดคำสั่ง ไม่มีใครรู้ว่าฉันจะทำให้โหมดการแสดงพร้อมท์ของฉันปรากฏขึ้นได้อย่างไร?

ผมพบว่านี้ผ่านSU นี่คือตัวอย่างพื้นฐานแม้ว่าฉันจะยังคงปรับแต่งมันเอง:

function zle-line-init zle-keymap-select {
    RPS1="${${KEYMAP/vicmd/-- NORMAL --}/(main|viins)/-- INSERT --}"
    RPS2=$RPS1
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

ฉันจะอธิบายมันยกเว้นฉันยังไม่เข้าใจจริงๆ

คุณพบแล้วzle-keymap-selectซึ่งจะถูกดำเนินการเมื่อใดก็ตามที่มีการเปลี่ยนแปลงโหมด คุณสามารถใช้มันเพื่อตั้งค่าตัวบ่งชี้ภาพอื่น ๆ กว่าการแจ้งเตือนขึ้นอยู่กับสิ่งที่เทอร์มินัลของคุณรองรับ

มีความสามารถ terminfoมาตรฐานเพื่อเปลี่ยนรูปร่างของเคอร์เซอร์ อย่างไรก็ตามเทอร์มินัลบางตัวแสดงเคอร์เซอร์เดียวกันในทั้งสองโหมด ความคิดของ Xterm เกี่ยวกับเคอร์เซอร์ที่มองเห็นได้น้อยคือการทำให้มันกระพริบ (และสิ่งนี้จะต้องเปิดใช้งานด้วย-bcอาร์กิวเมนต์บรรทัดคำสั่งหรือcursorBlinkทรัพยากร)

zle-keymap-select () {
  case $KEYMAP in
    vicmd) print -rn -- $terminfo[cvvis];; # block cursor
    viins|main) print -rn -- $terminfo[cnorm];; # less visible cursor
  esac
}

สำหรับเทอร์มินัลบางตัวคุณสามารถเปลี่ยนสีเคอร์เซอร์ด้วยprint -n '\e]12;pink\a'(ตามชื่อสี) หรือprint -n '\e]12;#abcdef\a'(ตามข้อกำหนด RGB) ลำดับเหล่านี้อธิบายไว้ในเอกสาร xterm ในctlseqsไฟล์; เทอร์มินัลอีมูเลเตอร์สมัยใหม่มักเลียนแบบ xterm แม้ว่าพวกเขาอาจจะไม่รองรับคุณสมบัติทั้งหมดของมัน

สำหรับผู้ที่มีปัญหาในการใช้ reset-prompt พร้อมกับ multiline prompt สิ่งนี้ใช้ได้กับฉัน: http://zeitlens.com/posts/2014-06-29-howto-zsh-vi-style.htmlร่วมกับhttps: // stackoverflow.com/questions/3622943/zsh-vi-mode-status-lineฉันสิ้นสุดที่ทำ:

terminfo_down_sc=$terminfo[cud1]$terminfo[cuu1]$terminfo[sc]$terminfo[cud1]

function insert-mode () { echo "-- INSERT --" }
function normal-mode () { echo "-- NORMAL --" }

precmd () {
    # yes, I actually like to have a new line, then some stuff and then 
    # the input line
    print -rP "
[%D{%a, %d %b %Y, %H:%M:%S}] %n %{$fg[blue]%}%m%{$reset_color%}"

    # this is required for initial prompt and a problem I had with Ctrl+C or
    # Enter when in normal mode (a new line would come up in insert mode,
    # but normal mode would be indicated)
    PS1="%{$terminfo_down_sc$(insert-mode)$terminfo[rc]%}%~ $ "
}
function set-prompt () {
    case ${KEYMAP} in
      (vicmd)      VI_MODE="$(normal-mode)" ;;
      (main|viins) VI_MODE="$(insert-mode)" ;;
      (*)          VI_MODE="$(insert-mode)" ;;
    esac
    PS1="%{$terminfo_down_sc$VI_MODE$terminfo[rc]%}%~ $ "
}

function zle-line-init zle-keymap-select {
    set-prompt
    zle reset-prompt
}
preexec () { print -rn -- $terminfo[el]; }

zle -N zle-line-init
zle -N zle-keymap-select

คุณสามารถลองVimMode

นี่คือสิ่งที่ฉันใช้เพื่อเปลี่ยนเคอร์เซอร์ระหว่างรูปร่าง 'Block' และ 'Beam' ใน zsh:

(ทดสอบด้วยปลวก , gnome-terminalและmate-terminal )

# vim mode config
# ---------------

# Activate vim mode.
bindkey -v

# Remove mode switching delay.
KEYTIMEOUT=5

# Change cursor shape for different vi modes.
function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] ||
     [[ $1 = 'block' ]]; then
    echo -ne '\e[1 q'

  elif [[ ${KEYMAP} == main ]] ||
       [[ ${KEYMAP} == viins ]] ||
       [[ ${KEYMAP} = '' ]] ||
       [[ $1 = 'beam' ]]; then
    echo -ne '\e[5 q'
  fi
}
zle -N zle-keymap-select

# Use beam shape cursor on startup.
echo -ne '\e[5 q'

# Use beam shape cursor for each new prompt.
preexec() {
   echo -ne '\e[5 q'
}

อีกวิธีหนึ่งในการเปลี่ยนรูปร่างเคอร์เซอร์ระหว่าง I-beam และ block (สำหรับขีดล่างใช้\033[4 q) ~/.zshrcเพิ่มไปของคุณ

zle-keymap-select () {
if [ $KEYMAP = vicmd ]; then
    printf "\033[2 q"
else
    printf "\033[6 q"
fi
}
zle -N zle-keymap-select
zle-line-init () {
zle -K viins
printf "\033[6 q"
}
zle -N zle-line-init
bindkey -v

ดัดแปลงจากhttps://bbs.archlinux.org/viewtopic.php?id=95078 ทดสอบใน gnome-terminal 3.22

ปรับปรุง

แต่การแก้ปัญหาอีกครั้งเพื่อให้การเปลี่ยนแปลงรูปร่างเคอร์เซอร์สามารถพบได้ที่นี่ เห็นได้ชัดว่าอันนี้ใช้งานได้กับ iTerm2 ซึ่งฉันไม่มีวิธีทดสอบ แต่เพิ่มไว้ที่นี่ในกรณีที่มันมีประโยชน์สำหรับคนอื่น นอกจากนี้สุดท้ายของคุณ~/.zshrcจะเป็น

function zle-keymap-select zle-line-init
{
    # change cursor shape in iTerm2
    case $KEYMAP in
        vicmd)      print -n -- "\E]50;CursorShape=0\C-G";;  # block cursor
        viins|main) print -n -- "\E]50;CursorShape=1\C-G";;  # line cursor
    esac

    zle reset-prompt
    zle -R
}

function zle-line-finish
{
    print -n -- "\E]50;CursorShape=0\C-G"  # block cursor
}

zle -N zle-line-init
zle -N zle-line-finish
zle -N zle-keymap-select

ฉันกำลังใช้ Zsh ด้วยธีมรถไฟหัวกระสุน ตามตัวอย่างที่ได้รับจากคำตอบของ Sebastian Blaskฉันลงเอยด้วยรหัสตะโกน

bindkey -v
KEYTIMEOUT=1

function zle-line-init zle-keymap-select {
    case ${KEYMAP} in
        (vicmd)      BULLETTRAIN_PROMPT_CHAR="N" ;;
        (main|viins) BULLETTRAIN_PROMPT_CHAR="I" ;;
        (*)          BULLETTRAIN_PROMPT_CHAR="I" ;;
    esac
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

สิ่งนี้จะเปลี่ยนค่าเริ่มต้น$เป็นตัวอักษรNเป็นโหมดปกติและฉันจะแทรกโหมด

ภาพนี้เป็นตัวอย่างเมื่ออยู่ในโหมดปกติฉันกดCtrl+ C:

ที่นี่ยังอีกรุ่นตามมาจากการโพสต์ของเซบาสเตียน Blask นี่เป็นจุดประสงค์ที่จะไม่เป็นการล่วงล้ำเท่าที่จะทำได้เช่นเดียวกับโซลูชันอื่น ๆ ทั้งหมดที่ฉันสามารถหาได้ใช้บรรทัดพิเศษสถานะทางด้านขวาหรืออักขระที่เพิ่มเข้ามา

สิ่งนี้จะเปลี่ยนสี$จากสีขาวเป็นสีแดงเมื่อเปิดใช้งานโหมดปกติ แก้ไขข้อความที่คุณชอบ

bindkey -v
function zle-line-init zle-keymap-select {
    case ${KEYMAP} in
        (vicmd)      PROMPT=$'%{\e[0;32m%}%~%{\e[0m%} %{\e[0;31m%}$%{\e[0m%} ' ;;
        (main|viins) PROMPT=$'%{\e[0;32m%}%~%{\e[0m%} $ ' ;;
        (*)          PROMPT=$'%{\e[0;32m%}%~%{\e[0m%} $ ' ;;
    esac
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

รุ่นสำหรับoh-my-zshผู้ใช้

มีปลั๊กอินสำหรับoh-my-zshเรียกvi-modeที่สามารถพบได้ที่นี่:

robbyrussell / โอ้-zsh ของฉัน / ปลั๊กอิน / vi โหมด

ฉันใช้ Antigen เพื่อจัดการปลั๊กอินของฉันดังนั้นการรวมมันก็ง่ายเหมือนการเพิ่มลงในของฉัน.zshrc:

antigen bundle vi-mode

zsh-เป็นกลุ่มโหมดปลั๊กอินสามารถแสดงตัวบ่งชี้สำหรับการแทรกคำสั่ง, การค้นหา, แทนที่และโหมดภาพ มันใช้เทคนิคพื้นฐานของคำตอบอื่น ๆ เพื่อขอเกี่ยวกับ hooks ZLE ต่างๆ (zle-keymap-select, zle-isearch-update, ฯลฯ ) มันจะตรวจสอบ[[ $ZLE_STATE = *overwrite* ]]โหมดแทนที่ มันตรวจสอบ$REGION_ACTIVEเพื่อระบุโหมดภาพ

ตรรกะมีความซับซ้อนโดยนิสัยใจคอบางอย่างของวิธี ZSH ยิงเหตุการณ์เมื่อออกจากโหมด isearch

อีกคุณสมบัติที่ดีของโมดูลคือความสามารถในการเปลี่ยนรูปร่างเคอร์เซอร์และสีตามโหมด ตัวอย่างเช่นคุณสามารถใช้แถบแนวตั้งในโหมด INSERT และขีดเส้นใต้กระพริบในโหมด SEARCH