ฉันจะอ้างถึงคอลัมน์ที่ต่างกันสองคอลัมน์ในฟังก์ชัน COUNTIF ได้อย่างไร

ฉันจะพยายามอธิบายให้ดีที่สุด สมมติว่าฉันมีแผ่นงานที่มีลักษณะเช่นนี้ (ในตัวอย่างที่วางแผนไว้นี้สมมติว่าฉันส่งอีเมลการตลาดไปยังผู้คนต่าง ๆ ฉันรู้อายุและรหัสไปรษณีย์ของพวกเขาและฉันต้องการติดตามอัตราการคลิกในอีเมลเหล่านั้น):

        A   |    B        |    C  
  1     Age |    zip code |  click?  
  2     26  |    11111    |  true  
  3     27  |    11112    |  true  
  4     28  |    11111    |  false  
  5     27  |    22222    |  false  
  6     28  |    11112    |  false  
  7     26  |    22222    |  true  

ตอนนี้ฉันต้องการติดตามสถิติต่างๆ ในกรณีนี้ฉันต้องการติดตามอัตราการคลิกตามอายุและรหัสไปรษณีย์ ดังนั้นฉันจึงได้โต๊ะแบบนี้:

      E         F          G 
 1   Age  |  # sent  | # clicked
 2   26   |
 3   26   |
 4   27   |
 5   28   |

ดังนั้นโดยทั่วไปในคอลัมน์ "# ส่ง" ฉันสามารถใส่ (ใน F2 ตัวอย่าง):

=COUNTIF(A:A, E2)

และนี่จะส่งผลเป็น 2 ในเซลล์ F2 เนื่องจากมีเหตุการณ์ "26" สองรายการในคอลัมน์ A

แต่ตอนนี้ถ้าฉันต้องการทราบจำนวนคลิก? ฉันอยากจะพูดอะไรบางอย่างเช่น:

=COUNTIF(A:A == E2  AND  C:C == True, for the same row where A:A matched E2)

ฉันรู้ว่าฉันสามารถเพิ่มคอลัมน์ D อีกสูตรหนึ่งได้

=IF(C2, A2, "")

ซึ่งจะมี แต่อายุในคอลัมน์ D ถ้าคอลัมน์ C เป็นจริง แต่ฉันสามารถมีเกณฑ์ได้หลายอย่างและดูเหมือนว่าฉันไม่ควรเพิ่มคอลัมน์ "ปลอม" อีกคอลัมน์สำหรับแต่ละเกณฑ์ที่ฉันมี

มีวิธีทำเช่นนี้หรือไม่? ถ้าไม่อยู่ใน Google เอกสารใน Excel?

ใช้การรวมกันของการดำเนินการ ARRAYFORMULA, SUM และเลขคณิต

นี่คือฟังก์ชั่นเพื่อนับจำนวนคลิกทั้งหมดโดยอายุ 26 ปี:

=ARRAYFORMULA(sum((A:A=26) * (C:C="true")))

การดำเนินการนี้มี 3 ส่วน

• ARRAYFORMULAดูแลวนลูปในช่วงที่ระบุ
• SUMจัดการนับทั้งหมดของผลการค้นหาความจริง

โดยพื้นฐานแล้ว True กำลังถูกแปลงเป็น 1 และ false กำลังถูกแปลงเป็น 0 ตรรกะแบบบูลเสร็จสิ้นโดยใช้การดำเนินการทางคณิตศาสตร์

การดำเนินการANDใช้การคูณ:

• (1 * 1) = 1 - (True && True) = True
• (1 * 0) = 0 - (จริง && เท็จ) = เท็จ
• (0 * 0) = 0 - (เท็จ && เท็จ) = เท็จ

การดำเนินการORใช้การรวมกันของฟังก์ชั่น* SIGNและการเพิ่ม:

• เครื่องหมาย (1 + 1) = 1 - (จริง || จริง) = จริง
• เครื่องหมาย (1 + 0) = 1 - (จริง || เท็จ) = จริง
• sign (0 + 0) = 0 - (False || False) = False

หมายเหตุ: จำเป็นต้องใช้ฟังก์ชั่นเครื่องหมายเนื่องจากการเพิ่มบูลีนทำงานแตกต่างจากการบวกเลขคณิต โดยทั่วไปในการเพิ่มบูลีน 1 + 1 = 1 ในการบวกเลข 1 + 1 = 2 เห็นได้ชัดว่าการเพิ่มเลขคณิตจะทำให้จำนวนการนับยุ่งเหยิงดังนั้นคุณต้องเรียกใช้ผลลัพธ์ของการดำเนินการบวกผ่านฟังก์ชันเครื่องหมาย ฟังก์ชัน sign ส่งคืน 1 ถ้าค่าเป็นบวก, 0 ถ้าค่าเป็น 0 และ -1 ถ้าค่าเป็นลบ

ให้บอกว่าคุณต้องการนับจำนวนคลิกสำหรับผู้ใช้ทุกคนที่มีอายุระหว่าง 20-25 ปี:

=ARRAYFORMULA(sum(sign((A:A=20) + (A:A=21) + (A:A=22) + (A:A=23) + (A:A=24) + (A:A=25)) * (C:C="true")))

ณ ตอนนี้ Google ชีตใหม่รองรับ COUNTIFS ซึ่งสามารถจัดการงานที่ต้องการได้โดยตรง

=COUNTIFS(A:A, E2, C:C, "true")

แสดงรายการช่วงทั้งหมดและการเปรียบเทียบเพื่อแยกด้วยเครื่องหมายจุลภาค

ใน Excel ฉันจะใช้ SUMPRODUCT ใน Excel 2003 หรือ COUNTIFS (ที่มี "S") ใน Excel 2007 หรือใหม่กว่า ....... แต่ใน Google เอกสารลองสิ่งนี้

=arrayformula(sum((A:A=E2)*(C:C=TRUE)))

=COUNTA( IFERROR( FILTER('Guest List'!$G:$G ; 'Guest List'!$G:$G = "Yes" ; 'Guest List'!$L:$L = "USA" ) ) )

นี่เป็นสองคอลัมน์ - ฉันใช้สิ่งนี้สำหรับรายชื่อแขกงานแต่งงานของฉัน - ในกรณีนี้การทำเป็นตาราง "ใช่" เมื่อส่งการบันทึกวันที่และ "สหรัฐอเมริกา" สำหรับที่ตั้งเพื่อให้ฉันสามารถคำนวณไปรษณีย์ในภายหลัง อาจมีสูตรที่สั้นกว่านี้ แต่ดูเหมือนว่าจะใช้ได้ดังนั้นฉันจึงไม่ยุ่งกับมัน!

มีความสุขมาก

ใน Excel ฉันจะลืมสูตรและใช้ตาราง Pivot

คุณอาจต้องเพิ่มหนึ่งคอลัมน์ "ตัวนับ" ซึ่งสามารถใช้ซ้ำแล้วซ้ำอีกเป็นตัวแปรที่คุณรวมไว้เพื่อรับผลลัพธ์

คุณสามารถเพิ่มอาร์เรย์ที่คุณต้องการทดสอบเป็น {}

ในตัวอย่างด้านล่าง:

=countif({F2,H2,J2,L2,N2,P2,R2,T2,V2,W2},"TRUE")