ข้อผิดพลาด AppleScript ที่ใช้ Adobe Photoshop CC เป็นชุดแปลงโปรไฟล์ CMYK

ฉันใช้ AppleScript เพื่อประมวลผลโฟลเดอร์ภาพ TIFF ที่ต้องแปลงเป็นโปรไฟล์ CMYK ที่เฉพาะเจาะจงใน Photoshop สคริปต์จะถามหาโฟลเดอร์ที่มีรูปภาพก่อนจากนั้นจะแจ้งตำแหน่งโฟลเดอร์เอาท์พุท อย่างไรก็ตามฉันได้รับข้อผิดพลาดต่อไปนี้เมื่อเรียกใช้สคริปต์:

Adobe Photoshop CC 2015 มีข้อผิดพลาด: ไม่สามารถรับเอกสารปัจจุบัน

สิ่งแรกที่ฉันพยายามคือลบออกcurrentจากคำสั่งบันทึก มันดู Photoshop เป็นจริงการเปิดและบันทึกเอกสาร (s) หลังจากที่ทำนี้ แต่ TIFFs newFilePathไม่ได้อยู่ในโฟลเดอร์ที่ระบุใน ไม่แน่ใจว่าฉันควรจัดการกับเรื่องนี้อย่างไรเพราะควรประมวลผลหลายไฟล์ สคริปต์ปัจจุบันอยู่ด้านล่าง:

on run
    tell me to open {choose folder}
end run

on open droppedItems
    set destFolder to choose folder with prompt "Select Output Folder"
    repeat with anItem in droppedItems
        tell application "Finder"
            -- Make sure each item is processed by this script is a folder
            if class of item anItem is not folder then
                -- Not a folder, notify the user of the error
                display dialog "Please drop folders containing images"
            else
                -- A folder, get the Adobe Photoshop files and process them
                set fileList to (every file of anItem) as alias list
            end if
        end tell
        HPConvert(fileList, destFolder)
    end repeat
end open

-- fileList is a list of aliases to Photoshop files
-- destFolder is an alias to a folder where the converted TIFFs are to be saved
on HPConvert(fileList, destFolder)
    set destPath to destFolder as string
    repeat with aFile in fileList
        tell application "Finder" to set fileName to name of aFile
        set newFilePath to destPath & fileName
        tell application "Adobe Photoshop CC 2015"
            open aFile
            convert to profile "CGATS21_CRPC6 V2" intent absolute colorimetric with dithering
            save current document in file newFilePath as TIFF with options {embed color profile:true, save layers:true, save spot colors:true} appending lowercase extension
            close current document saving no
        end tell
    end repeat
end HPConvert

ปัญหาที่เกิดขึ้นเป็นตัวเลือกที่ tiff

มันหายไปด้านหน้าของวัตถุ class:TIFF save options,

บรรทัดนั้นโดยรวม (เท่าที่ควรจะเป็น):

save current document in file newFilePath as TIFF with options {class:TIFF save options, embed color profile:true, save layers:true, save spot colors:true} appending lowercase extension

ฉันคิดออกได้อย่างไร:

ขั้นตอนที่ 1:

สิ่งแรกที่ฉันทำคือเปิดไฟล์ใหม่ในเครื่องมือแก้ไขสคริปต์และเรียกใช้:

tell application "Adobe Photoshop CC 2017"

    return current document

end tell

ส่งคืนชื่อเอกสารเพียงพอที่เปิดเอกสารใน PS ดังนั้นจึงไม่มีความประหลาดใจ

ขั้นตอนที่ 2.

เอาสคริปต์ของคุณและถอดออกไปทั้งหมดยกเว้นสิ่งจำเป็นและแทนที่อินพุตและเอาต์พุตด้วยค่าสแตติก ในทางเทคนิคแล้วอินพุตเป็นเพียงเอกสารเปิด ...

set fileName to "Filename.tif"
set newFilePath to "/Users/joonaspaakko/Desktop/test/output/" & fileName
tell application "Adobe Photoshop CC 2017"

    convert to profile "High Quality Print" intent absolute colorimetric with dithering

    save current document in file newFilePath as TIFF with options {embed color profile:true, save layers:true, save spot colors:true} appending lowercase extension

    close current document saving no

end tell

ยังคงบ่นเกี่ยวกับเอกสาร แต่ฉันรู้ว่าไม่ใช่ปัญหาจากการทดสอบครั้งแรกของฉัน

ขั้นตอนที่ 3

ดังนั้นฉันจึงดูเอกสารอ้างอิงสำหรับ applescriptและในนั้นฉันดูตัวอย่างการบันทึก tif สามารถพบได้หากคุณค้นหา: save current document in file myFile as TIFFใน pdf

ฉันไม่เคยมีประสบการณ์กับ Applescript โดยทั่วไปในการเขียนสคริปต์ Photoshop ด้วยตัวเองเพียงอย่างเดียว ... ดังนั้นฉันไม่รู้ว่ามีวิธีที่ดีกว่าในการดีบักโค้ดหรือไม่ แต่ Editor Editor ก็บ่นเกี่ยวกับsaveบรรทัดนั้นและเน้นมันดังนั้นฉันจึงคิดว่า นั่นคือที่ที่ข้อผิดพลาดจะต้อง ... หรือบริเวณนั้น

เพียงแค่ค้นหาความแตกต่างและข้อผิดพลาดทางไวยากรณ์ที่เป็นไปได้ด้วยตนเองและฉันพบว่ามันหายไปclass:TIFF save options,ในจุดเริ่มต้นของวัตถุตัวเลือก tif และเพิ่มในการแก้ไขข้อผิดพลาด