ไฮไลต์ตัวแปรเชลล์ภายในเครื่องหมายคำพูด

ในกลุ่มเอกสารต่อไปนี้จะทำให้$PWDบรรทัดบน 2 และ 3 เป็นสีในสองวิธีที่ต่างกัน:

#/bin/sh
echo "Current Directory: $PWD"
echo 'Current Directory: $PWD'

อินสแตนซ์แรกของ$PWDจะอยู่ในสีที่แตกต่างจากส่วนที่เหลือของสายมันสิ่งนี้ให้ข้อบ่งชี้ภาพที่ชัดเจนว่าตัวแปรจะขยายตัวมากกว่าถือว่าเป็นข้อความตัวอักษร ในทางตรงกันข้ามอินสแตนซ์ที่สองของ$PWDจะมีสีเหมือนกับส่วนที่เหลือของสตริงเนื่องจากเครื่องหมายคำพูดเดี่ยวทำให้ถือว่าเป็นข้อความตามตัวอักษร

มีโหมด emacs ที่มีอยู่แล้วหรือไม่ซึ่งให้ "การรับรู้ข้อความเปลือกหอย" ประเภทนี้?

รหัสด้านล่างใช้กฎตัวอักษรล็อคกับฟังก์ชั่นแทนการ regexp ฟังก์ชั่นการค้นหาสำหรับการเกิดขึ้น$VARแต่เฉพาะเมื่อพวกเขาอยู่ภายในสตริงที่ยกมาสองครั้ง ฟังก์ชั่นที่(syntax-ppss)ใช้ในการตรวจสอบนี้

กฎตัวอักษรล็อคใช้การprependตั้งค่าสถานะเพื่อเพิ่มตัวเองอยู่ด้านบนของการเน้นสตริงที่มีอยู่ (โปรดทราบว่าแพ็คเกจจำนวนมากใช้tสำหรับสิ่งนี้โชคไม่ดีที่สิ่งนี้จะเขียนทับทุกแง่มุมของการไฮไลต์ที่มีอยู่ตัวอย่างเช่นการใช้prependจะเก็บสีพื้นหลังของสตริง (หากมี) ในขณะที่เปลี่ยนสีพื้นหน้า)

(defun sh-script-extra-font-lock-is-in-double-quoted-string ()
  "Non-nil if point in inside a double-quoted string."
  (let ((state (syntax-ppss)))
    (eq (nth 3 state) ?\")))

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res
                   (re-search-forward
                    "\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\)"
                    limit t))
             (not (sh-script-extra-font-lock-is-in-double-quoted-string))))
    res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode
      (with-no-warnings
        (font-lock-fontify-buffer)))))

คุณสามารถเรียกใช้สิ่งนี้ได้โดยการเพิ่มฟังก์ชั่นสุดท้ายให้กับตะขอที่เหมาะสมตัวอย่างเช่น

(add-hook 'sh-mode-hook 'sh-script-extra-font-lock-activate)

ฉันปรับปรุงคำตอบของ @ Lindydancer ด้วยวิธีต่อไปนี้:

• Inlined sh-script-extra-font-lock-is-in-double-quoted-stringฟังก์ชั่นตามที่มันถูกใช้เพียงครั้งเดียว
• การหลีกเลี่ยงการทำงานของตัวแปร
• ตัวแปรที่เป็นตัวเลข ( $10, $1ฯลฯ ) เป็นไฮไลต์

ทำลายรหัส

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res (progn (if (eq (get-byte) ?$) (backward-char))
                              (re-search-forward
                               "[^\\]\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\|[[:digit:]]+\\)"
                               limit t)))
             (not (eq (nth 3 (syntax-ppss)) ?\")))) res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode (with-no-warnings (font-lock-fontify-buffer)))))