วนไฟล์ในโฟลเดอร์โดยใช้ VBA หรือไม่

ฉันต้องการวนไฟล์ของไดเรกทอรีโดยใช้ VBA ใน Excel 2010

ในลูปฉันจะต้อง:

• ชื่อไฟล์และ
• วันที่ซึ่งฟอร์แมตไฟล์

ฉันเขียนโค้ดต่อไปนี้ซึ่งใช้งานได้ดีหากโฟลเดอร์ไม่มีไฟล์มากกว่า 50 ไฟล์มิฉะนั้นจะช้าอย่างน่าขัน (ฉันต้องใช้เพื่อทำงานกับโฟลเดอร์ที่มีไฟล์> 10,000 ไฟล์) ปัญหาเดียวของรหัสนี้คือการดำเนินการเพื่อค้นหาfile.nameใช้เวลานานมาก

รหัสที่ใช้งานได้ แต่ waaaaaay ช้าเกินไป (15 วินาทีต่อ 100 ไฟล์):

Sub LoopThroughFiles()
   Dim MyObj As Object, MySource As Object, file As Variant
   Set MySource = MyObj.GetFolder("c:\testfolder\")
   For Each file In MySource.Files
      If InStr(file.name, "test") > 0 Then
         MsgBox "found"
         Exit Sub
      End If
   Next file
End Sub

แก้ไขปัญหา:

1. ปัญหาของฉันได้รับการแก้ไขโดยวิธีดังต่อไปนี้ใช้Dirในทางหนึ่ง (20 วินาทีสำหรับ 15000 ไฟล์) FileDateTimeและสำหรับการตรวจสอบการประทับเวลาใช้คำสั่ง
2. คำนึงถึงคำตอบอื่นจากด้านล่าง 20 วินาทีจะลดลงเหลือน้อยกว่า 1 วินาที

นี่คือการตีความของฉันในฐานะฟังก์ชั่นแทน:

'#######################################################################
'# LoopThroughFiles
'# Function to Loop through files in current directory and return filenames
'# Usage: LoopThroughFiles ActiveWorkbook.Path, "txt" 'inputDirectoryToScanForFile
'# /programming/10380312/loop-through-files-in-a-folder-using-vba
'#######################################################################
Function LoopThroughFiles(inputDirectoryToScanForFile, filenameCriteria) As String

    Dim StrFile As String
    'Debug.Print "in LoopThroughFiles. inputDirectoryToScanForFile: ", inputDirectoryToScanForFile

    StrFile = Dir(inputDirectoryToScanForFile & "\*" & filenameCriteria)
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        StrFile = Dir

    Loop

End Function

Dirรับไวลด์การ์ดเพื่อให้คุณสามารถสร้างความแตกต่างได้มากโดยเพิ่มตัวกรองtestไว้ด้านหน้า

Sub LoopThroughFiles()
    Dim StrFile As String
    StrFile = Dir("c:\testfolder\*test*")
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        StrFile = Dir
    Loop
End Sub

ดูเหมือนว่า Dir จะเร็วมาก

Sub LoopThroughFiles()
    Dim MyObj As Object, MySource As Object, file As Variant
   file = Dir("c:\testfolder\")
   While (file <> "")
      If InStr(file, "test") > 0 Then
         MsgBox "found " & file
         Exit Sub
      End If
     file = Dir
  Wend
End Sub

ฟังก์ชั่นผบ. เป็นวิธีที่จะไป แต่ปัญหาคือการที่คุณไม่สามารถใช้Dirฟังก์ชั่นซ้ำตามที่ระบุไว้ที่นี่ทางด้านล่าง

วิธีที่ฉันจัดการสิ่งนี้คือการใช้Dirฟังก์ชั่นเพื่อรับโฟลเดอร์ย่อยทั้งหมดสำหรับโฟลเดอร์เป้าหมายและโหลดลงในอาร์เรย์จากนั้นส่งอาร์เรย์ไปยังฟังก์ชันที่เกิดซ้ำ

นี่คือคลาสที่ฉันเขียนซึ่งทำสิ่งนี้ได้สำเร็จรวมถึงความสามารถในการค้นหาตัวกรอง ( คุณจะต้องให้อภัยสัญลักษณ์ของชาวฮังการีนี่เป็นลายลักษณ์อักษรเมื่อมันเป็นความเดือดดาลทั้งหมด )

Private m_asFilters() As String
Private m_asFiles As Variant
Private m_lNext As Long
Private m_lMax As Long

Public Function GetFileList(ByVal ParentDir As String, Optional ByVal sSearch As String, Optional ByVal Deep As Boolean = True) As Variant
    m_lNext = 0
    m_lMax = 0

    ReDim m_asFiles(0)
    If Len(sSearch) Then
        m_asFilters() = Split(sSearch, "|")
    Else
        ReDim m_asFilters(0)
    End If

    If Deep Then
        Call RecursiveAddFiles(ParentDir)
    Else
        Call AddFiles(ParentDir)
    End If

    If m_lNext Then
        ReDim Preserve m_asFiles(m_lNext - 1)
        GetFileList = m_asFiles
    End If

End Function

Private Sub RecursiveAddFiles(ByVal ParentDir As String)
    Dim asDirs() As String
    Dim l As Long
    On Error GoTo ErrRecursiveAddFiles
    'Add the files in 'this' directory!


    Call AddFiles(ParentDir)

    ReDim asDirs(-1 To -1)
    asDirs = GetDirList(ParentDir)
    For l = 0 To UBound(asDirs)
        Call RecursiveAddFiles(asDirs(l))
    Next l
    On Error GoTo 0
Exit Sub
ErrRecursiveAddFiles:
End Sub
Private Function GetDirList(ByVal ParentDir As String) As String()
    Dim sDir As String
    Dim asRet() As String
    Dim l As Long
    Dim lMax As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If
    sDir = Dir(ParentDir, vbDirectory Or vbHidden Or vbSystem)
    Do While Len(sDir)
        If GetAttr(ParentDir & sDir) And vbDirectory Then
            If Not (sDir = "." Or sDir = "..") Then
                If l >= lMax Then
                    lMax = lMax + 10
                    ReDim Preserve asRet(lMax)
                End If
                asRet(l) = ParentDir & sDir
                l = l + 1
            End If
        End If
        sDir = Dir
    Loop
    If l Then
        ReDim Preserve asRet(l - 1)
        GetDirList = asRet()
    End If
End Function
Private Sub AddFiles(ByVal ParentDir As String)
    Dim sFile As String
    Dim l As Long

    If Right(ParentDir, 1) <> "\" Then
        ParentDir = ParentDir & "\"
    End If

    For l = 0 To UBound(m_asFilters)
        sFile = Dir(ParentDir & "\" & m_asFilters(l), vbArchive Or vbHidden Or vbNormal Or vbReadOnly Or vbSystem)
        Do While Len(sFile)
            If Not (sFile = "." Or sFile = "..") Then
                If m_lNext >= m_lMax Then
                    m_lMax = m_lMax + 100
                    ReDim Preserve m_asFiles(m_lMax)
                End If
                m_asFiles(m_lNext) = ParentDir & sFile
                m_lNext = m_lNext + 1
            End If
            sFile = Dir
        Loop
    Next l
End Sub

Dir ฟังก์ชั่นสูญเสียโฟกัสได้อย่างง่ายดายเมื่อฉันจัดการและประมวลผลไฟล์จากโฟลเดอร์อื่น

FileSystemObjectฉันได้รับผลลัพธ์ที่ดีขึ้นกับองค์ประกอบ

ตัวอย่างเต็มรูปแบบได้รับที่นี่:

http://www.xl-central.com/list-files-fso.html

อย่าลืมตั้งค่าการอ้างอิงใน Visual Basic Editor เป็นMicrosoft Scripting Runtime (โดยใช้เครื่องมือ> การอ้างอิง)

ให้มันลอง!

ลองอันนี้. ( ลิงค์ )

Private Sub CommandButton3_Click()

Dim FileExtStr As String
Dim FileFormatNum As Long
Dim xWs As Worksheet
Dim xWb As Workbook
Dim FolderName As String
Application.ScreenUpdating = False
Set xWb = Application.ThisWorkbook
DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
FolderName = xWb.Path & "\" & xWb.Name & " " & DateString
MkDir FolderName
For Each xWs In xWb.Worksheets
    xWs.Copy
    If Val(Application.Version) < 12 Then
        FileExtStr = ".xls": FileFormatNum = -4143
    Else
        Select Case xWb.FileFormat
            Case 51:
                FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If Application.ActiveWorkbook.HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56:
                FileExtStr = ".xls": FileFormatNum = 56
            Case Else:
                FileExtStr = ".xlsb": FileFormatNum = 50
        End Select
    End If
    xFile = FolderName & "\" & Application.ActiveWorkbook.Sheets(1).Name & FileExtStr
    Application.ActiveWorkbook.SaveAs xFile, FileFormat:=FileFormatNum
    Application.ActiveWorkbook.Close False
Next
MsgBox "You can find the files in " & FolderName
Application.ScreenUpdating = True

End Sub