วิธีสร้างและเขียนไปยังไฟล์ txt โดยใช้ VBA

ฉันมีไฟล์ที่เพิ่มหรือแก้ไขด้วยตนเองตามอินพุต เนื่องจากเนื้อหาส่วนใหญ่ซ้ำซากในไฟล์นั้นมีเพียงค่าฐานสิบหกเท่านั้นที่เปลี่ยนแปลงฉันจึงต้องการให้มันเป็นไฟล์ที่สร้างด้วยเครื่องมือ

ฉันต้องการเขียนรหัส c ที่จะพิมพ์ในไฟล์. txtนั้น

คำสั่งในการสร้างไฟล์. txtโดยใช้ VBA คืออะไรและฉันจะเขียนมันได้อย่างไร

เพื่ออธิบายรายละเอียดเกี่ยวกับคำตอบของ Ben :

หากคุณเพิ่มการอ้างอิงMicrosoft Scripting Runtimeและพิมพ์ตัวแปรfอย่างถูกต้องคุณสามารถใช้ประโยชน์จากการเติมข้อความอัตโนมัติ (Intellisense) และค้นพบคุณสมบัติที่ยอดเยี่ยมอื่น ๆ ของFileSystemObject .

นี่คือโมดูลตัวอย่างที่สมบูรณ์:

Option Explicit

' Go to Tools -> References... and check "Microsoft Scripting Runtime" to be able to use
' the FileSystemObject which has many useful features for handling files and folders
Public Sub SaveTextToFile()

    Dim filePath As String
    filePath = "C:\temp\MyTestFile.txt"

    ' The advantage of correctly typing fso as FileSystemObject is to make autocompletion
    ' (Intellisense) work, which helps you avoid typos and lets you discover other useful
    ' methods of the FileSystemObject
    Dim fso As FileSystemObject
    Set fso = New FileSystemObject
    Dim fileStream As TextStream

    ' Here the actual file is created and opened for write access
    Set fileStream = fso.CreateTextFile(filePath)

    ' Write something to the file
    fileStream.WriteLine "something"

    ' Close it, so it is not locked anymore
    fileStream.Close

    ' Here is another great method of the FileSystemObject that checks if a file exists
    If fso.FileExists(filePath) Then
        MsgBox "Yay! The file was created! :D"
    End If

    ' Explicitly setting objects to Nothing should not be necessary in most cases, but if
    ' you're writing macros for Microsoft Access, you may want to uncomment the following
    ' two lines (see https://stackoverflow.com/a/517202/2822719 for details):
    'Set fileStream = Nothing
    'Set fso = Nothing

End Sub

ใช้ FSO เพื่อสร้างไฟล์และเขียนลงในไฟล์

Dim fso as Object
Set fso = CreateObject("Scripting.FileSystemObject")
Dim oFile as Object
Set oFile = FSO.CreateTextFile(strPath)
oFile.WriteLine "test" 
oFile.Close
Set fso = Nothing
Set oFile = Nothing    

ดูเอกสารที่นี่:

• http://technet.microsoft.com/en-us/library/ee198742.aspx
• http://technet.microsoft.com/en-us/library/ee198716.aspx

Open ThisWorkbook.Path & "\template.txt" For Output As #1
Print #1, strContent
Close #1

ข้อมูลมากกว่านี้:

• Microsoft Docs: Openคำสั่ง
• Microsoft Docs: Print #คำสั่ง
• Microsoft Docs: Closeคำสั่ง
• wellsr.com: VBA เขียนลงในไฟล์ข้อความด้วยPrintStatement
• การสนับสนุนสำนักงาน: Workbook.Pathทรัพย์สิน

วิธีง่ายๆโดยไม่ต้องมีความซ้ำซ้อนมาก

    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")

    Dim Fileout As Object
    Set Fileout = fso.CreateTextFile("C:\your_path\vba.txt", True, True)
    Fileout.Write "your string goes here"
    Fileout.Close

Dim SaveVar As Object

Sub Main()

    Console.WriteLine("Enter Text")

    Console.WriteLine("")

    SaveVar = Console.ReadLine

    My.Computer.FileSystem.WriteAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt", "Text: " & SaveVar & ", ", True)

    Console.WriteLine("")

    Console.WriteLine("File Saved")

    Console.WriteLine("")

    Console.WriteLine(My.Computer.FileSystem.ReadAllText("N:\A-Level Computing\2017!\PPE\SaveFile\SaveData.txt"))
    Console.ReadLine()

End Sub()