ฉันชอบWMICและTASKLISTเครื่องมือ แต่พวกเขาไม่สามารถใช้ได้ในบ้าน / รุ่นพื้นฐานของ windows วิธีอื่นคือการใช้QPROCESSคำสั่งที่มีอยู่ในเกือบทุกเครื่อง windows (สำหรับคนที่มีบริการเทอร์มินัล - ฉันคิดว่าชนะ XP โดยไม่ต้อง SP2 เท่านั้น เครื่อง windows):
@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
:: QPROCESS can display only the first 12 symbols of the running process
:: If other tool is used the line bellow could be deleted
set process_to_check=%process_to_check:~0,12%
QPROCESS * | find /i "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
endlocal
QPROCESSคำสั่งไม่ได้มีประสิทธิภาพมากเท่าที่TASKLISTและ จำกัด ในการแสดงเพียง 12 สัญลักษณ์ของชื่อกระบวนการ แต่ควรนำมาพิจารณาหากTASKLISTไม่สามารถใช้ได้
การใช้งานง่ายขึ้นซึ่งจะใช้ชื่อหากกระบวนการเป็นอาร์กิวเมนต์ ( .exeคำต่อท้ายมีผลบังคับใช้ในกรณีนี้เมื่อคุณส่งชื่อปฏิบัติการ):
@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
:: .exe suffix is mandatory
set "process_to_check=%~1"
QPROCESS "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
endlocal
ความแตกต่างระหว่างการQPROCESSใช้งานสองวิธีคือQPROCESS *จะแสดงรายการกระบวนการทั้งหมดในขณะที่QPROCESS some.exeจะกรองเฉพาะกระบวนการสำหรับผู้ใช้ปัจจุบัน
การใช้WMIวัตถุผ่าน windows script host exe แทนที่จะWMICเป็นตัวเลือกนอกจากนี้ยังควรรันบนเครื่อง windows ทุกเครื่อง (ยกเว้นอันที่ WSH ถูกปิด แต่นี่เป็นกรณีที่หายาก) ไฟล์ค้างคาวที่แสดงรายการกระบวนการทั้งหมดผ่าน WMI คลาสและสามารถใช้แทนQPROCESSสคริปต์ด้านบน (เป็นไฮบริด jscript / bat และควรบันทึกเป็น.bat):
@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off
cscript //E:JScript //nologo "%~f0"
exit /b
************** end of JSCRIPT COMMENT **/
var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes = new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
var process=processes.item();
WScript.Echo( process.processID + " " + process.Name );
}
และการดัดแปลงที่จะตรวจสอบว่ากระบวนการกำลังทำงานอยู่หรือไม่:
@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
cscript //E:JScript //nologo "%~f0" | find /i "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
exit /b
************** end of JSCRIPT COMMENT **/
var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes = new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
var process=processes.item();
WScript.Echo( process.processID + " " + process.Name );
}
TASKLISTสองตัวเลือกสามารถนำมาใช้ในเครื่องที่ไม่มี
MSHTAเทคนิคที่ดีที่สุดคือการใช้ สิ่งนี้จะทำงานในทุกเครื่อง windows จาก XP ขึ้นไปและไม่ขึ้นอยู่กับการตั้งค่าโฮสต์สคริปต์ windows การเรียกใช้MSHTAอาจลดประสิทธิภาพลงเล็กน้อย (ควรบันทึกเป็นแบ็ตอีกครั้ง):
@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
mshta "about:<script language='javascript' src='file://%~dpnxf0'></script>" | find /i "%process_to_check%" >nul 2>&1 && (
echo process %process_to_check% is running
) || (
echo process %process_to_check% is not running
)
endlocal
exit /b
************** end of JSCRIPT COMMENT **/
var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);
var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes = new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
var process=processes.item();
fso.Write( process.processID + " " + process.Name + "\n");
}
close();