แก้ไขพา ธ สัมบูรณ์จากพา ธ สัมพัทธ์และ / หรือชื่อไฟล์

มีวิธีในสคริปต์แบทช์ของ Windows เพื่อส่งคืนพา ธ สัมบูรณ์จากค่าที่มีชื่อไฟล์และ / หรือเส้นทางสัมพัทธ์หรือไม่

ได้รับ:

"..\"
"..\somefile.txt"

ฉันต้องการพา ธ สัมบูรณ์ที่สัมพันธ์กับแบตช์ไฟล์

ตัวอย่าง:

• "somefile.txt" ตั้งอยู่ใน "C: \ Foo \"
• "test.bat" อยู่ใน "C: \ Foo \ Bar"
• ผู้ใช้เปิดหน้าต่างคำสั่งใน "C: \ Foo" และการโทร Bar\test.bat ..\somefile.txt
• ในแบตช์ไฟล์ "C: \ Foo \ somefile.txt" จะได้รับมาจาก %1

ในไฟล์แบตช์เช่นเดียวกับในโปรแกรม C มาตรฐานอาร์กิวเมนต์ 0 มีเส้นทางไปยังสคริปต์ที่กำลังดำเนินการอยู่ในปัจจุบัน คุณสามารถใช้%~dp0เพื่อรับเฉพาะส่วนของเส้นทางของอาร์กิวเมนต์ 0 (ซึ่งเป็นสคริปต์ปัจจุบัน) - เส้นทางนี้เป็นเส้นทางที่ผ่านการรับรองโดยสมบูรณ์เสมอ

คุณยังสามารถรับพา ธ ที่ผ่านการรับรองโดยสมบูรณ์ของอาร์กิวเมนต์แรกของคุณโดยใช้%~f1แต่จะให้พา ธ ตามไดเรกทอรีการทำงานปัจจุบันซึ่งเห็นได้ชัดว่าไม่ใช่สิ่งที่คุณต้องการ

โดยส่วนตัวแล้วฉันมักจะใช้%~dp0%~1สำนวนในไฟล์แบทช์ซึ่งตีความอาร์กิวเมนต์แรกที่สัมพันธ์กับเส้นทางของแบตช์ที่ดำเนินการ มันมีข้อบกพร่องแม้ว่ามันจะล้มเหลวอย่างน่าสังเวชถ้าอาร์กิวเมนต์แรกมีคุณสมบัติครบถ้วน

หากคุณต้องการสนับสนุนทั้งเส้นทางสัมพัทธ์และเส้นทางสัมบูรณ์คุณสามารถใช้ประโยชน์จากโซลูชันของFrédéricMénez : เปลี่ยนไดเรกทอรีการทำงานปัจจุบันชั่วคราว

นี่คือตัวอย่างที่แสดงให้เห็นถึงเทคนิคเหล่านี้:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

หากคุณบันทึกสิ่งนี้เป็น c: \ temp \ example.bat และเรียกใช้จาก c: \ Users \ Public เป็น

c: \ Users \ Public> \ temp \ example.bat .. \ windows

... คุณจะสังเกตผลลัพธ์ต่อไปนี้:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

เอกสารสำหรับชุดตัวดัดแปลงที่ได้รับอนุญาตในอาร์กิวเมนต์ชุดสามารถดูได้ที่นี่: https://docs.microsoft.com/en-us/windows-server/administrator/windows-commands/call

ฉันเจอความต้องการที่คล้ายกันเมื่อเช้านี้: วิธีการแปลงเส้นทางสัมพัทธ์เป็นเส้นทางที่แน่นอนภายในสคริปต์คำสั่งของ Windows

ต่อไปนี้เป็นเคล็ดลับ:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

คำตอบเหล่านี้ส่วนใหญ่ดูเหมือนจะบ้าไปกับสิ่งที่ซับซ้อนและมีความผิดพลาดสูงนี่คือของฉัน - มันทำงานได้กับตัวแปรสภาพแวดล้อมใด ๆ ไม่มี%CD%หรือPUSHD/ POPDหรือfor /fไร้สาระ - เพียงแค่ฟังก์ชั่นแบทช์เก่าแบบธรรมดา - ไดเรกทอรีและไฟล์ไม่จำเป็นต้องมีอยู่จริง

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~dpfn1
  EXIT /B

โดยไม่ต้องมีไฟล์แบตช์อื่นเพื่อส่งผ่านอาร์กิวเมนต์ไปยัง (และใช้ตัวดำเนินการอาร์กิวเมนต์) คุณสามารถใช้FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

ที่iในเป็นตัวแปรที่กำหนดไว้ใน%%~fi /F %%iเช่น. หากคุณเปลี่ยนสิ่ง/F %%aนั้นเป็นส่วนสุดท้ายก็จะเป็น%%~faเช่นนั้น

หากต้องการทำสิ่งเดียวกันที่พรอมต์คำสั่ง (และไม่ใช่ในไฟล์แบตช์) ให้แทนที่%%ด้วย%...

นี่คือการช่วยเติมช่องว่างในคำตอบของ Adrien Plisson (ซึ่งควรได้รับการอัปเดตทันทีที่เขาแก้ไข ;-):

คุณสามารถรับพา ธ ที่ผ่านการรับรองโดยสมบูรณ์ของอาร์กิวเมนต์แรกของคุณโดยใช้% ~ f1 แต่สิ่งนี้จะให้เส้นทางตามเส้นทางปัจจุบันซึ่งเห็นได้ชัดว่าไม่ใช่สิ่งที่คุณต้องการ

น่าเสียดายที่ฉันไม่รู้วิธีผสม 2 อย่างเข้าด้วยกัน ...

หนึ่งสามารถจัดการ%0และ%1เช่นเดียวกัน:

• %~dpnx0สำหรับไดรฟ์ที่มีคุณสมบัติครบถ้วนเส้นทาง + ชื่อ + ส่วนขยายของ batchfile ตัวเอง
  %~f0ก็พอเพียง;
• %~dpnx1สำหรับไดรฟ์ที่มีคุณสมบัติครบถ้วน + พา ธ + ชื่อ + ส่วนขยายของอาร์กิวเมนต์แรก [ถ้าเป็นชื่อไฟล์เลย]
  %~f1ก็เพียงพอแล้ว

%~f1จะทำงานโดยอิสระจากวิธีที่คุณระบุอาร์กิวเมนต์แรกของคุณ: กับพา ธ สัมพัทธ์หรือพา ธ สัมบูรณ์ (หากคุณไม่ระบุนามสกุลของไฟล์เมื่อตั้งชื่อ%1มันจะไม่ถูกเพิ่มแม้ว่าคุณจะใช้%~dpnx1- อย่างไรก็ตาม

แต่คุณจะตั้งชื่อไฟล์บนไดรฟ์อื่นอย่างไรถ้าคุณไม่ให้ข้อมูลเส้นทางแบบเต็มบน commandline ในตอนแรก

อย่างไรก็ตาม%~p0, %~n0, %~nx0และ%~x0อาจจะมาในที่มีประโยชน์ที่คุณควรจะสนใจในเส้นทาง (ไม่ driveletter) ชื่อไฟล์ (ไม่มีนามสกุล) ชื่อไฟล์เต็มรูปแบบที่มีนามสกุลนามสกุลหรือชื่อไฟล์เท่านั้น แต่ทราบว่าในขณะที่%~p1และ%~n1จะทำงานเพื่อหาเส้นทางหรือชื่อของอาร์กิวเมนต์แรก%~nx1และ%~x1จะไม่เพิ่ม + แสดงส่วนขยายเว้นแต่คุณจะใช้มันใน commandline แล้ว

คุณสามารถใช้ฟังก์ชั่นแบบแบตช์สำหรับสิ่งนี้:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

ปรับปรุงขนาดเล็กเพื่อแก้ปัญหาที่ดีเยี่ยมของ BrainSlugs83 ทั่วไปเพื่ออนุญาตให้ตั้งชื่อตัวแปรสภาวะแวดล้อมเอาต์พุตในการโทร

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

หากเรียกใช้จากC:\projectผลลัพธ์คือ:

C:\project\doc\build

ฉันไม่เห็นวิธีแก้ไขปัญหานี้มากมาย วิธีแก้ปัญหาบางอย่างใช้ประโยชน์จากการสำรวจเส้นทางโดยใช้ซีดีและอื่น ๆ ใช้ประโยชน์จากฟังก์ชั่นแบบกลุ่ม ความชอบส่วนตัวของฉันมีไว้สำหรับฟังก์ชั่นแบบแบตช์และโดยเฉพาะอย่างยิ่งฟังก์ชั่นMakeAbsoluteที่จัดทำโดย DosTips

ฟังก์ชั่นนี้มีประโยชน์บางประการเป็นหลักโดยที่ไม่เปลี่ยนแปลงไดเรกทอรีการทำงานปัจจุบันของคุณและอย่างที่สองที่เส้นทางที่ถูกประเมินไม่จำเป็นต้องมีอยู่ด้วยซ้ำ คุณสามารถอ่านเคล็ดลับที่มีประโยชน์เกี่ยวกับวิธีใช้ฟังก์ชันได้ที่นี่เช่นกัน

นี่คือตัวอย่างสคริปต์และผลลัพธ์:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

และผลลัพธ์:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

ฉันหวังว่าสิ่งนี้จะช่วย ... มันช่วยฉันได้แน่นอน :) PS ขอบคุณ DosTips อีกครั้ง! คุณร็อค!

คุณสามารถต่อพวกมันให้ต่อกันได้

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

มันดูแปลก ๆ กับ \ .. \ ที่อยู่กลางเส้นทางของคุณ แต่มันใช้ได้ ไม่ต้องทำอะไรบ้า ๆ :)

ในตัวอย่างของคุณจาก Bar \ test.bat DIR / B / S .. \ somefile.txt จะส่งคืนพา ธ เต็ม

PowerShell เป็นเรื่องธรรมดาในทุกวันนี้ดังนั้นฉันจึงใช้บ่อยครั้งเพื่อเรียกใช้ C # เนื่องจากมีฟังก์ชั่นสำหรับทุกสิ่งที่สวย

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

มันค่อนข้างช้า แต่ฟังก์ชั่นที่ได้รับนั้นยากที่จะเอาชนะเว้นแต่จะไม่มีการใช้ภาษาสคริปต์จริง

วิธีการแก้ปัญหาของ Stijn ทำงานร่วมกับโฟลเดอร์ย่อยภายใต้C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

ไฟล์ดูคำตอบอื่น ๆ ทั้งหมด

ไดเรกทอรี

ด้วย..การเป็นเส้นทางสัมพันธ์ของคุณและสมมติว่าคุณอยู่ในขณะนี้D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (เส้นทางสัมพัทธ์)

ส่งคืนพา ธ สัมบูรณ์เช่น

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b