วางสตริงที่มีศูนย์นำหน้าเพื่อให้มีความยาว 3 อักขระใน SQL Server 2008

ฉันมีสตริงที่ยาวไม่เกิน 3 อักขระเมื่อสร้างขึ้นครั้งแรกใน SQL Server 2008 R2

ฉันต้องการซับด้วยศูนย์นำหน้าดังนั้นถ้าค่าเดิมเป็น '1' ดังนั้นค่าใหม่จะเป็น '001' หรือถ้าค่าเดิมเป็น '23' ค่าใหม่คือ '023' หรือถ้าค่าเดิมเป็น '124' ค่าใหม่จะเหมือนกับค่าเดิม

ฉันใช้ SQL Server 2008 R2 ฉันจะทำสิ่งนี้โดยใช้ T-SQL ได้อย่างไร

ถ้าเขตข้อมูลเป็นสตริงอยู่แล้วสิ่งนี้จะทำงาน

 SELECT RIGHT('000'+ISNULL(field,''),3)

หากคุณต้องการให้ค่า Null แสดงเป็น '000'

มันอาจจะเป็นจำนวนเต็ม - แล้วคุณจะต้องการ

 SELECT RIGHT('000'+CAST(field AS VARCHAR(3)),3)

ตามคำถามที่ต้องการคำตอบนี้ใช้ได้เฉพาะในกรณีที่ความยาว <= 3 ถ้าคุณต้องการบางสิ่งที่ใหญ่กว่าคุณต้องเปลี่ยนค่าคงที่สตริงและค่าคงที่จำนวนเต็มสองค่าเป็นความกว้างที่ต้องการ เช่น'0000' and VARCHAR(4)),4

แม้ว่าคำถามคือสำหรับ SQL Server 2008 R2 ในกรณีที่มีใครบางคนที่อ่านข้อความนี้กับรุ่นปี 2012 และข้างต้นตั้งแต่นั้นมาก็กลายเป็นเรื่องง่ายโดยใช้รูปแบบ

คุณสามารถส่งสตริงรูปแบบตัวเลขมาตรฐานหรือสตริงรูปแบบตัวเลขที่กำหนดเองเป็นอาร์กิวเมนต์รูปแบบ (ขอบคุณVadim Ovchinnikovสำหรับคำแนะนำนี้)

สำหรับคำถามนี้เช่นรหัสเช่น

DECLARE @myInt INT = 1;
-- One way using a standard numeric format string
PRINT FORMAT(@myInt,'D3');
-- Other way using a custom numeric format string
PRINT FORMAT(@myInt,'00#');

เอาท์พุท

001
001

วิธีที่ปลอดภัย:

SELECT REPLACE(STR(n,3),' ','0')

นี่เป็นข้อดีของการคืนค่าสตริง'***'สำหรับ n <0 หรือ n> 999 ซึ่งเป็นตัวบ่งชี้ที่ดีและชัดเจนของอินพุตนอกขอบเขต วิธีอื่น ๆ ที่แสดงไว้ที่นี่จะล้มเหลวอย่างเงียบ ๆ โดยตัดทอนอินพุตให้กับสตริงย่อย 3 อักขระ

นี่เป็นเทคนิคทั่วไปสำหรับการเว้นระยะห่างจากซ้ายไปจนถึงความกว้างที่ต้องการ:

declare @x     int     = 123 -- value to be padded
declare @width int     = 25  -- desired width
declare @pad   char(1) = '0' -- pad character

select right_justified = replicate(
                           @pad ,
                           @width-len(convert(varchar(100),@x))
                           )
                       + convert(varchar(100),@x)

อย่างไรก็ตามหากคุณกำลังจัดการกับค่าลบและการเติมด้วยเลขศูนย์นำหน้าไม่ว่าจะเป็นแบบนี้หรือเทคนิคอื่น ๆ ที่แนะนำจะใช้งานได้ คุณจะได้รับสิ่งที่มีลักษณะเช่นนี้:

00-123

[อาจไม่ใช่สิ่งที่คุณต้องการ]

ดังนั้น…คุณจะต้องข้ามห่วงเพิ่มเติมนี่คือวิธีหนึ่งที่จะจัดรูปแบบจำนวนลบได้อย่างถูกต้อง:

declare @x     float   = -1.234
declare @width int     = 20
declare @pad   char(1) = '0'

select right_justified = stuff(
         convert(varchar(99),@x) ,                            -- source string (converted from numeric value)
         case when @x < 0 then 2 else 1 end ,                 -- insert position
         0 ,                                                  -- count of characters to remove from source string
         replicate(@pad,@width-len(convert(varchar(99),@x)) ) -- text to be inserted
         )

หนึ่งควรทราบว่าการconvert()โทรควรระบุ[n]varcharความยาวเพียงพอที่จะเก็บผลการแปลงด้วยการตัดทอน

นี่คือคำตอบที่แตกต่างของโฮแกนที่ฉันใช้ใน SQL Server Express 2012:

SELECT RIGHT(CONCAT('000', field), 3)

แทนที่จะต้องกังวลว่าฟิลด์นั้นเป็นสตริงหรือไม่ฉันก็CONCATเลยเพราะมันจะส่งออกสตริงอยู่ดี นอกจากนี้ถ้าเขตข้อมูลสามารถ a NULL, ISNULLอาจจำเป็นต้องใช้เพื่อหลีกเลี่ยงการให้ฟังก์ชันรับNULLผลลัพธ์

SELECT RIGHT(CONCAT('000', ISNULL(field,'')), 3)

ฉันพบวิธีต่อไปนี้เพื่อเป็นประโยชน์เสมอ

REPLICATE('0', 5 - LEN(Job.Number)) + CAST(Job.Number AS varchar) as 'NumberFull'

ใช้ฟังก์ชั่นนี้ที่เหมาะสมกับทุกสถานการณ์

CREATE FUNCTION dbo.fnNumPadLeft (@input INT, @pad tinyint)
RETURNS VARCHAR(250)
AS BEGIN
    DECLARE @NumStr VARCHAR(250)

    SET @NumStr = LTRIM(@input)

    IF(@pad > LEN(@NumStr))
        SET @NumStr = REPLICATE('0', @Pad - LEN(@NumStr)) + @NumStr;

    RETURN @NumStr;
END

ตัวอย่างผลลัพธ์

SELECT [dbo].[fnNumPadLeft] (2016,10) -- returns 0000002016
SELECT [dbo].[fnNumPadLeft] (2016,5) -- returns 02016
SELECT [dbo].[fnNumPadLeft] (2016,2) -- returns 2016
SELECT [dbo].[fnNumPadLeft] (2016,0) -- returns 2016 

สำหรับผู้ที่ต้องการอัปเดตข้อมูลที่มีอยู่ที่นี่เป็นคำถาม:

update SomeEventTable set eventTime=RIGHT('00000'+ISNULL(eventTime, ''),5)

สำหรับจำนวนเต็มคุณสามารถใช้การแปลงโดยนัยจาก int ถึง varchar:

SELECT RIGHT(1000 + field, 3)

ฉันรู้ว่าตั๋วเก่าของฉันฉันเพิ่งคิดที่จะแบ่งปัน

ฉันพบรหัสนี้เพื่อค้นหาวิธีแก้ไข ไม่แน่ใจว่าใช้ได้กับ MSSQL ทุกรุ่นหรือไม่ฉันมี MSSQL 2016

declare @value as nvarchar(50) = 23
select REPLACE(STR(CAST(@value AS INT) + 1,4), SPACE(1), '0') as Leadingzero

ส่งคืน "0023" 4 ในฟังก์ชัน STR คือความยาวทั้งหมดรวมถึงค่า ตัวอย่างที่ 4, 23 และ 123 ทั้งหมดจะมี 4 ใน STR และจำนวนศูนย์ที่ถูกต้องจะถูกเพิ่มเข้าไป คุณสามารถเพิ่มหรือลดได้ ไม่จำเป็นต้องมีความยาวในวันที่ 23

แก้ไข: ฉันเห็นข้อความเหมือนกับ @Anon โพสต์

ฉันมีปัญหาคล้ายกันกับคอลัมน์จำนวนเต็มเป็นอินพุตเมื่อฉันต้องการเอาต์พุต varchar (หรือสตริง) ขนาดคงที่ ตัวอย่างเช่น 1 ถึง '01', 12 ถึง '12' รหัสนี้ใช้งานได้:

SELECT RIGHT(CONCAT('00',field::text),2)

หากอินพุตยังเป็นคอลัมน์ของ varchar คุณสามารถหลีกเลี่ยงส่วนที่หล่อได้

สำหรับวิธีการแบบไดนามิกมากขึ้นลองสิ่งนี้

declare @val varchar(5)
declare @maxSpaces int
set @maxSpaces = 3
set @val = '3'
select concat(REPLICATE('0',@maxSpaces-len(@val)),@val)

ลองใช้ความยาวคงที่

select right('000000'+'123',5)

select REPLICATE('0', 5 - LEN(123)) + '123'

เขียนสิ่งนี้เพราะฉันมีความต้องการไม่เกินความยาวที่กำหนด (9) วางแผ่นด้านซ้ายด้วย @pattern เท่านั้นเมื่ออินพุตต้องการการเติมเต็ม ควรส่งคืนความยาวที่กำหนดใน @ รูปแบบเสมอ

declare @charInput as char(50) = 'input'

--always handle NULL :)
set @charInput = isnull(@charInput,'')

declare @actualLength as int = len(@charInput)

declare @pattern as char(50) = '123456789'
declare @prefLength as int = len(@pattern)

if @prefLength > @actualLength
    select Left(Left(@pattern, @prefLength-@actualLength) + @charInput, @prefLength)
else
    select @charInput

ส่งคืน 1234 อินพุต

ง่าย ๆ ก็คือ

ชอบ:

DECLARE @DUENO BIGINT
SET @DUENO=5

SELECT 'ND'+STUFF('000000',6-LEN(RTRIM(@DueNo))+1,LEN(RTRIM(@DueNo)),RTRIM(@DueNo)) DUENO

ฉันมาที่นี่โดยเฉพาะเพื่อหาวิธีที่ฉันสามารถแปลง timezoneoffset เป็นสตริงเขตเวลาสำหรับการแปลงวันที่เป็น DATETIMEOFFSET ใน SQL Server 2008 ขั้นต้น แต่จำเป็น

ดังนั้นฉันต้องการ 1 วิธีที่จะรับมือกับจำนวนลบและบวกจัดรูปแบบพวกเขาเป็นสองตัวอักษรด้วยศูนย์นำถ้าจำเป็น คำตอบไม่ได้ทำให้ฉันเข้าใกล้ แต่ค่าเขตเวลาเชิงลบจะออกมา0-5มากกว่าที่จำเป็น-05

ดังนั้นด้วยการปรับแต่งเล็กน้อยในคำตอบของเขาสิ่งนี้ใช้ได้กับการแปลงชั่วโมงทุกช่วงเวลา

DECLARE @n INT = 13 -- Works with -13, -5, 0, 5, etc
SELECT CASE 
    WHEN @n < 0 THEN '-' + REPLACE(STR(@n * -1 ,2),' ','0') 
    ELSE '+' + REPLACE(STR(@n,2),' ','0') END + ':00'

ฉันสร้างฟังก์ชั่นนี้ซึ่งเหมาะสำหรับ bigint และหนึ่งตัวอักษรนำศูนย์หรืออักขระเดี่ยวอื่น ๆ (สูงสุด 20 ตัวอักษรที่ส่งคืน) และอนุญาตให้ความยาวของผลลัพธ์น้อยกว่าความยาวของจำนวนอินพุต:

create FUNCTION fnPadNum (
  @Num BIGINT --Number to be padded, @sLen BIGINT --Total length of results , @PadChar varchar(1))
  RETURNS VARCHAR(20)
  AS
  --Pads bigint with leading 0's
            --Sample:  "select dbo.fnPadNum(201,5,'0')" returns "00201"
            --Sample:  "select dbo.fnPadNum(201,5,'*')" returns "**201"
            --Sample:  "select dbo.fnPadNum(201,5,' ')" returns "  201"
   BEGIN
     DECLARE @Results VARCHAR(20)
     SELECT @Results = CASE 
     WHEN @sLen >= len(ISNULL(@Num, 0))
     THEN replicate(@PadChar, @sLen - len(@Num)) + CAST(ISNULL(@Num, 0) AS VARCHAR)
     ELSE CAST(ISNULL(@Num, 0) AS VARCHAR)
     END

     RETURN @Results
     END
     GO

     --Usage:
      SELECT dbo.fnPadNum(201, 5,'0')
      SELECT dbo.fnPadNum(201, 5,'*')
      SELECT dbo.fnPadNum(201, 5,' ')