จะวางตารางผู้ใช้ทั้งหมดได้อย่างไร

ฉันจะวางตารางผู้ใช้ทั้งหมดใน oracle ได้อย่างไร

ฉันมีปัญหากับข้อ จำกัด เมื่อฉันปิดการใช้งานทั้งหมดมันยังคงเป็นไปไม่ได้

BEGIN
   FOR cur_rec IN (SELECT object_name, object_type
                   FROM user_objects
                   WHERE object_type IN
                             ('TABLE',
                              'VIEW',
                              'MATERIALIZED VIEW',
                              'PACKAGE',
                              'PROCEDURE',
                              'FUNCTION',
                              'SEQUENCE',
                              'SYNONYM',
                              'PACKAGE BODY'
                             ))
   LOOP
      BEGIN
         IF cur_rec.object_type = 'TABLE'
         THEN
            EXECUTE IMMEDIATE 'DROP '
                              || cur_rec.object_type
                              || ' "'
                              || cur_rec.object_name
                              || '" CASCADE CONSTRAINTS';
         ELSE
            EXECUTE IMMEDIATE 'DROP '
                              || cur_rec.object_type
                              || ' "'
                              || cur_rec.object_name
                              || '"';
         END IF;
      EXCEPTION
         WHEN OTHERS
         THEN
            DBMS_OUTPUT.put_line ('FAILED: DROP '
                                  || cur_rec.object_type
                                  || ' "'
                                  || cur_rec.object_name
                                  || '"'
                                 );
      END;
   END LOOP;
   FOR cur_rec IN (SELECT * 
                   FROM all_synonyms 
                   WHERE table_owner IN (SELECT USER FROM dual))
   LOOP
      BEGIN
         EXECUTE IMMEDIATE 'DROP PUBLIC SYNONYM ' || cur_rec.synonym_name;
      END;
   END LOOP;
END;
/

หากคุณต้องการวิธีง่ายๆในการทำเช่นนี้ .. เป็นสคริปต์ที่ฉันเคยใช้ในอดีต

select 'drop table '||table_name||' cascade constraints;' from user_tables;

สิ่งนี้จะพิมพ์ชุดคำสั่งดรอปสำหรับตารางทั้งหมดในสคีมา สพูลผลลัพธ์ของแบบสอบถามนี้และดำเนินการ

ที่มา: https://forums.oracle.com/forums/thread.jspa?threadID=614090

เช่นเดียวกันหากคุณต้องการล้างตารางมากกว่าคุณสามารถแก้ไขสิ่งต่อไปนี้เพื่อให้เหมาะกับความต้องการของคุณ

select 'drop '||object_type||' '|| object_name || ';' from user_objects where object_type in ('VIEW','PACKAGE','SEQUENCE', 'PROCEDURE', 'FUNCTION', 'INDEX')

คำตอบที่ทำงานให้ฉันก็คือ (เครดิตเพื่อhttp://snipt.net/Fotinakis/drop-all-tables-and-constraints-within-an-oracle-schema/ )

BEGIN

FOR c IN (SELECT table_name FROM user_tables) LOOP
EXECUTE IMMEDIATE ('DROP TABLE "' || c.table_name || '" CASCADE CONSTRAINTS');
END LOOP;

FOR s IN (SELECT sequence_name FROM user_sequences) LOOP
EXECUTE IMMEDIATE ('DROP SEQUENCE ' || s.sequence_name);
END LOOP;

END;

โปรดทราบว่าวิธีนี้ใช้งานได้ทันทีหลังจากคุณเรียกใช้ มันไม่ได้ผลิตสคริปต์ที่คุณต้องนำไปวางที่ใดที่หนึ่ง (เช่นคำตอบอื่น ๆ ที่นี่) มันทำงานโดยตรงบนฐานข้อมูล

begin
  for i in (select 'drop table '||table_name||' cascade constraints' tbl from user_tables) 
  loop
     execute immediate i.tbl;
  end loop;
end;

วิธีที่ง่ายที่สุดคือการปล่อยผู้ใช้ที่เป็นเจ้าของวัตถุด้วยคำสั่ง cascade

DROP USER username CASCADE

วิธีที่ง่ายที่สุดคือการวาง tablespace จากนั้นสร้าง tablespace สำรอง แต่ฉันไม่ต้องการทำเช่นนั้น สิ่งนี้คล้ายกับของ Henry ยกเว้นว่าฉันเพิ่งทำสำเนา / วางบน resultset ใน gui ของฉัน

SELECT
  'DROP'
  ,object_type
  ,object_name
  ,CASE(object_type)
     WHEN 'TABLE' THEN 'CASCADE CONSTRAINTS;'
     ELSE ';'
   END
 FROM user_objects
 WHERE
   object_type IN ('TABLE','VIEW','PACKAGE','PROCEDURE','FUNCTION','SEQUENCE')

SELECT 'DROP TABLE "' || TABLE_NAME || '" CASCADE CONSTRAINTS;' 
FROM user_tables;

user_tables เป็นตารางระบบที่มีตารางทั้งหมดของผู้ใช้ส่วนคำสั่ง SELECT จะสร้างคำสั่ง DROP สำหรับทุกตารางที่คุณสามารถเรียกใช้สคริปต์

ในการลบวัตถุทั้งหมดใน oracle:

1) แบบไดนามิก

DECLARE
CURSOR IX IS
SELECT * FROM ALL_OBJECTS WHERE OBJECT_TYPE ='TABLE' 
AND OWNER='SCHEMA_NAME';
 CURSOR IY IS
 SELECT * FROM ALL_OBJECTS WHERE OBJECT_TYPE 
IN ('SEQUENCE',
'PROCEDURE',
'PACKAGE',
'FUNCTION',
'VIEW') AND  OWNER='SCHEMA_NAME';
 CURSOR IZ IS
 SELECT * FROM ALL_OBJECTS WHERE OBJECT_TYPE IN ('TYPE') AND  OWNER='SCHEMA_NAME';
BEGIN
 FOR X IN IX LOOP
   EXECUTE IMMEDIATE('DROP '||X.OBJECT_TYPE||' SCHEMA_NAME.'||X.OBJECT_NAME|| ' CASCADE CONSTRAINT');
 END LOOP;
 FOR Y IN IY LOOP
   EXECUTE IMMEDIATE('DROP '||Y.OBJECT_TYPE||' SCHEMA_NAME.'||Y.OBJECT_NAME);
 END LOOP;
 FOR Z IN IZ LOOP
   EXECUTE IMMEDIATE('DROP '||Z.OBJECT_TYPE||' SCHEMA_NAME.'||Z.OBJECT_NAME||' FORCE ');
 END LOOP;
END;
/

2) แบบคงที่

    SELECT 'DROP TABLE "' || TABLE_NAME || '" CASCADE CONSTRAINTS;' FROM user_tables
        union ALL
        select 'drop '||object_type||' '|| object_name || ';' from user_objects 
        where object_type in ('VIEW','PACKAGE','SEQUENCE', 'PROCEDURE', 'FUNCTION')
        union ALL
        SELECT 'drop '
        ||object_type
        ||' '
        || object_name
        || ' force;'
        FROM user_objects
        WHERE object_type IN ('TYPE');

กรุณาทำตามขั้นตอนด้านล่าง

begin
  for i in (select 'drop table '||table_name||' cascade constraints' tb from user_tables) 
  loop
     execute immediate i.tb;
  end loop;
  commit;
end;
purge RECYCLEBIN;