Inno Setup: จะถอนการติดตั้งเวอร์ชันก่อนหน้านี้โดยอัตโนมัติได้อย่างไร?

ฉันใช้ Inno Setup เพื่อสร้างตัวติดตั้ง

ฉันต้องการให้โปรแกรมติดตั้งถอนการติดตั้งเวอร์ชันที่ติดตั้งก่อนหน้านี้โดยอัตโนมัติแทนที่จะเขียนทับ ฉันจะทำเช่นนั้นได้อย่างไร?

คุณควรจะสามารถอ่านสตริงการถอนการติดตั้งจากรีจิสตรีโดยระบุ AppId (เช่นค่าที่คุณใช้AppIDใน[Setup]-section) สามารถพบได้ภายใต้Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\(อาจเป็นอย่างใดอย่างหนึ่งHKLMหรือHKCUดังนั้นควรตรวจสอบทั้งสองอย่างให้ดีที่สุด) ซึ่ง{AppId}ควรแทนที่ด้วยค่าจริงที่คุณใช้ ค้นหาUninstallStringหรือQuietUninstallStringค่าและใช้Execฟังก์ชันเพื่อเรียกใช้จากInitializeSetup()ฟังก์ชันเหตุการณ์ของคุณ

อัปเดต:ลบโซลูชันทางเลือกที่ไม่ทำงานออกโดยใช้[Run]รายการ{uninstallexe}- ส่วนด้วย- ขอบคุณผู้แสดงความคิดเห็นทุกคนที่ชี้ให้เห็นสิ่งนี้!

ฉันได้ใช้สิ่งต่อไปนี้ ฉันไม่แน่ใจว่าเป็นวิธีที่ง่ายที่สุด แต่ได้ผล

สิ่งนี้ใช้{#emit SetupSetting("AppId")}ซึ่งอาศัยตัวประมวลผลล่วงหน้าของ Inno Setup หากคุณไม่ใช้สิ่งนั้นให้ตัดและวางรหัสแอปของคุณโดยตรง

[Code]

{ ///////////////////////////////////////////////////////////////////// }
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;


{ ///////////////////////////////////////////////////////////////////// }
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;


{ ///////////////////////////////////////////////////////////////////// }
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
{ Return Values: }
{ 1 - uninstall string is empty }
{ 2 - error executing the UnInstallString }
{ 3 - successfully executed the UnInstallString }

  { default return value }
  Result := 0;

  { get the uninstall string of the old app }
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

{ ///////////////////////////////////////////////////////////////////// }
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

ทางเลือก

ดูบล็อกโพสต์นี้ "Inno Setup Script Sample for Version Comparison"ซึ่งก้าวไปอีกขั้นและอ่านหมายเลขเวอร์ชันของเวอร์ชันที่ติดตั้งก่อนหน้านี้และเปรียบเทียบหมายเลขเวอร์ชันนั้นกับแพ็กเกจการติดตั้งปัจจุบัน

หากคุณ "เพียงแค่ต้องการลบไอคอนเก่า" (เนื่องจากของคุณมีการเปลี่ยนแปลง / อัปเดต) คุณสามารถใช้สิ่งนี้:

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

นี่คือรัน "ที่จุดเริ่มต้นของการติดตั้ง" ดังนั้นโดยพื้นฐานแล้วจะลบไอคอนเก่าและไอคอนใหม่ของคุณจะยังคงถูกติดตั้งที่นั่นหลังจากเสร็จสิ้นทั้งหมด

ฉันทำสิ่งนี้กับทุกการติดตั้งไอคอน "ในกรณีที่มีการเปลี่ยนแปลง" อย่างชาญฉลาด (ทุกอย่างได้รับการติดตั้งใหม่อยู่ดี)

เมื่อใช้ Inno Setup ไม่มีเหตุผลที่จะถอนการติดตั้งเวอร์ชันก่อนหน้าเว้นแต่เวอร์ชันนั้นจะติดตั้งโดยโปรแกรมติดตั้งอื่น มิฉะนั้นการอัปเกรดจะได้รับการจัดการโดยอัตโนมัติ

คำตอบของ Craig McQueen นั้นสามารถใช้ได้ แม้ว่าฉันจะเพิ่มความคิดเห็นเหล่านั้น:

• {#emit SetupSetting("AppId")}รหัสไม่ทำงานสำหรับฉันดังนั้นฉันเพียงแค่เพิ่มรหัสแอปของฉัน
• ฉันไม่ต้องการเรียกใช้โปรแกรมถอนการติดตั้งเพราะฉันมีไฟล์กำหนดค่า INI ที่เก็บไว้ในโฟลเดอร์ AppData / ซึ่งโปรแกรมถอนการติดตั้งถูกลบออกและฉันไม่ต้องการให้มันถูกลบเมื่อติดตั้งเวอร์ชันใหม่ ดังนั้นฉันจึงแก้ไขโค้ดที่ Craig McQueen ให้มาเล็กน้อยเพื่อลบไดเร็กทอรีที่ติดตั้งโปรแกรมหลังจากดึงเส้นทาง

ดังนั้นเกี่ยวกับรหัสของ Craig McQueen การเปลี่ยนแปลงคือ:

• ดึงInstallLocationคีย์แทนUninstallStringคีย์
• ใช้DelTreeฟังก์ชันแทนExec(sUnInstallString, ...)

สำหรับใครก็ตามที่ใช้คำGetUninstallString()แนะนำข้างต้นเพื่อบังคับถอนการติดตั้งภายในCurStepChanged()และมีปัญหาในการแคชดิสก์โปรดดูวิธีแก้ไขปัญหาที่เกี่ยวข้องซึ่งต้องรอสักครู่หลังจากถอนการติดตั้งเพื่อให้ exe ถอนการติดตั้งถูกลบ!

ปัญหาการแคชดิสก์ด้วยการไม่ตั้งค่า?

คุณสามารถเรียกใช้โปรแกรมถอนการติดตั้งได้ในส่วน [รหัส] คุณต้องหาวิธีรับเส้นทางไปยังโปรแกรมถอนการติดตั้งที่มีอยู่ เพื่อความเรียบง่ายเมื่อฉันติดตั้งแอปของฉันฉันเพิ่มค่าสตริงรีจิสทรีที่ชี้ไปยังโฟลเดอร์ที่มีโปรแกรมถอนการติดตั้งและเพียงแค่เรียกใช้โปรแกรมถอนการติดตั้งในการเรียกกลับ InitializeWizard

โปรดทราบว่าชื่อโปรแกรมถอนการติดตั้งการติดตั้ง Inno เป็นรูปแบบ uninsnnn.exe ทั้งหมดคุณต้องคำนึงถึงสิ่งนั้นในรหัสของคุณ

ฉันได้รับการแก้ไขรหัส @Crain Mc-Queen ฉันคิดว่ารหัสนี้ดีกว่าเพราะไม่จำเป็นต้องแก้ไขในโครงการอื่น:

[Code]
function GetNumber(var temp: String): Integer;
var
  part: String;
  pos1: Integer;
begin
  if Length(temp) = 0 then
  begin
    Result := -1;
    Exit;
  end;
    pos1 := Pos('.', temp);
    if (pos1 = 0) then
    begin
      Result := StrToInt(temp);
    temp := '';
    end
    else
    begin
    part := Copy(temp, 1, pos1 - 1);
      temp := Copy(temp, pos1 + 1, Length(temp));
      Result := StrToInt(part);
    end;
end;

function CompareInner(var temp1, temp2: String): Integer;
var
  num1, num2: Integer;
begin
    num1 := GetNumber(temp1);
  num2 := GetNumber(temp2);
  if (num1 = -1) or (num2 = -1) then
  begin
    Result := 0;
    Exit;
  end;
      if (num1 > num2) then
      begin
        Result := 1;
      end
      else if (num1 < num2) then
      begin
        Result := -1;
      end
      else
      begin
        Result := CompareInner(temp1, temp2);
      end;
end;

function CompareVersion(str1, str2: String): Integer;
var
  temp1, temp2: String;
begin
    temp1 := str1;
    temp2 := str2;
    Result := CompareInner(temp1, temp2);
end;

function InitializeSetup(): Boolean;
var
  oldVersion: String;
  uninstaller: String;
  ErrorCode: Integer;
  vCurID      :String;
  vCurAppName :String;
begin
  vCurID:= '{#SetupSetting("AppId")}';
  vCurAppName:= '{#SetupSetting("AppName")}';
  //remove first "{" of ID
  vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
  //
  if RegKeyExists(HKEY_LOCAL_MACHINE,
    'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
  begin
    RegQueryStringValue(HKEY_LOCAL_MACHINE,
      'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
      'DisplayVersion', oldVersion);
    if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then      
    begin
      if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
        mbConfirmation, MB_YESNO) = IDYES then
      begin
        Result := False;
      end
      else
      begin
          RegQueryStringValue(HKEY_LOCAL_MACHINE,
            'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
            'UninstallString', uninstaller);
          ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
          Result := True;
      end;
    end
    else
    begin
      MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
        mbInformation, MB_OK);
      Result := False;
    end;
  end
  else
  begin
    Result := True;
  end;
end;

ฉันต้องขาดอะไรบางอย่าง ใหม่ไฟล์จะถูกคัดลอกไปยังไดเรกทอรีเป้าหมายก่อนการกำจัดของการติดตั้งเก่าเกิดขึ้น จากนั้นโปรแกรมถอนการติดตั้งจะลบและลบไดเร็กทอรี

อย่าใช้ส่วน [Run] แต่เป็น [UninstallRun] Infact โปรแกรมภายใต้ [Run] จะทำงานหลังจากการติดตั้งทำให้ถอนการติดตั้งโปรแกรมของคุณทันทีหลังการติดตั้ง: - | แต่ส่วน [UninstallRun] จะได้รับการประเมินก่อนการติดตั้ง

ไปที่ลิงค์นี้: http://news.jrsoftware.org/news/innosetup/msg55323.html

ในฟังก์ชัน InitializeSetup () คุณสามารถเรียก "MSIEXEC / x {your program ID}" หลังจากแจ้งให้ผู้ใช้ถอนการติดตั้งเวอร์ชันเก่า