ข้อผิดพลาด - ไม่สามารถรับสิทธิ์การเข้าถึงแบบเอกสิทธิ์เฉพาะบุคคลเนื่องจากฐานข้อมูลถูกใช้งาน

ฉันพยายามสร้างสคริปต์ (ใน Sql Server 2008) เพื่อกู้คืนฐานข้อมูลหนึ่งฐานข้อมูลจากไฟล์สำรองหนึ่งไฟล์ ฉันสร้างรหัสต่อไปนี้และฉันได้รับข้อผิดพลาด -

Msg 3101, Level 16, State 1, Line 3
Exclusive access could not be obtained because 
the database is in use.
Msg 3013, Level 16, State 1, Line 3
RESTORE DATABASE is terminating abnormally.

ฉันจะแก้ไขปัญหานี้ได้อย่างไร?

IF DB_ID('AdventureWorksDW') IS NOT NULL 
BEGIN 
RESTORE DATABASE [AdventureWorksDW] 
FILE = N'AdventureWorksDW_Data' 
FROM  
DISK = N'C:\Program Files\Microsoft SQL Server\
MSSQL10_50.SS2008\MSSQL\Backup\AdventureWorksDW.bak' 
WITH  FILE = 1, 
MOVE N'AdventureWorksDW_Data' 
TO N'C:\Program Files\Microsoft SQL Server\
MSSQL10_50.SS2008\MSSQL\DATA\AdventureWorksDW.mdf', 
MOVE N'AdventureWorksDW_Log'  
TO N'C:\Program Files\Microsoft SQL Server\
MSSQL10_50.SS2008\MSSQL\DATA\AdventureWorksDW_0.LDF', 
NOUNLOAD,  STATS = 10 
END

ฉันจะถือว่าถ้าคุณกำลังกู้คืนฐานข้อมูลคุณจะไม่สนใจเกี่ยวกับธุรกรรมที่มีอยู่ในฐานข้อมูลนั้น ขวา? หากเป็นเช่นนั้นสิ่งนี้จะเหมาะกับคุณ:

USE master
GO

ALTER DATABASE AdventureWorksDW
SET SINGLE_USER
--This rolls back all uncommitted transactions in the db.
WITH ROLLBACK IMMEDIATE
GO

RESTORE DATABASE AdventureWorksDW
FROM ...
...
GO

ตอนนี้อีกหนึ่งรายการที่ต้องระวัง หลังจากที่คุณตั้งค่า db เป็นโหมดผู้ใช้คนเดียวอาจมีคนอื่นพยายามเชื่อมต่อกับฐานข้อมูล หากดำเนินการสำเร็จคุณจะไม่สามารถดำเนินการกู้คืนได้ เป็นการแข่งขัน! คำแนะนำของฉันคือเรียกใช้ทั้งสามคำสั่งในครั้งเดียว

1. กำหนดเส้นทางเพื่อกู้คืนไฟล์
2. คลิก "ตัวเลือก" ทางด้านซ้ายมือ
3. ยกเลิกการเลือก "สำรองข้อมูลหางล็อกก่อนกู้คืน"
4. ทำเครื่องหมายในช่อง - "ปิดการเชื่อมต่อกับฐานข้อมูลปลายทางที่มีอยู่"
5. คลิกตกลง

เรียกใช้แบบสอบถามนี้ก่อนที่จะกู้คืนฐานข้อมูล:

alter database [YourDBName] 
set offline with rollback immediate

และสิ่งนี้หลังจากกู้คืน:

  alter database [YourDBName] 
  set online

สำหรับฉันวิธีแก้ปัญหาคือ:

1. เลือกเขียนทับฐานข้อมูลที่มีอยู่ (WITH REPLACE) ในแท็บออปโป้ทางด้านซ้ายมือ

2. ยกเลิกการเลือกตัวเลือกอื่น ๆ ทั้งหมด

3. เลือกฐานข้อมูลต้นทางและปลายทาง

4. คลิกตกลง

แค่นั้นแหละ.

ใช้สคริปต์ต่อไปนี้เพื่อค้นหาและฆ่าการเชื่อมต่อที่เปิดอยู่ทั้งหมดไปยังฐานข้อมูลก่อนที่จะกู้คืนฐานข้อมูล

declare @sql as varchar(20), @spid as int

select @spid = min(spid)  from master..sysprocesses  where dbid = db_id('<database_name>') 
and spid != @@spid    

while (@spid is not null)
begin
    print 'Killing process ' + cast(@spid as varchar) + ' ...'
    set @sql = 'kill ' + cast(@spid as varchar)
    exec (@sql)

    select 
        @spid = min(spid)  
    from 
        master..sysprocesses  
    where 
        dbid = db_id('<database_name>') 
        and spid != @@spid
end 

print 'Process completed...'

หวังว่านี่จะช่วยได้ ...

ฉันคิดว่าคุณต้องตั้งค่าฐานข้อมูลเป็นโหมดผู้ใช้คนเดียวก่อนที่จะพยายามกู้คืนเช่นด้านล่างตรวจสอบให้แน่ใจว่าคุณใช้ master

USE master
GO
ALTER DATABASE AdventureWorksDW
SET SINGLE_USER

ฉันเพิ่งรีสตาร์ทบริการ sqlexpress จากนั้นการกู้คืนเสร็จสมบูรณ์

Use Master
alter database databasename set offline with rollback immediate;

--Do Actual Restore
RESTORE DATABASE databasename
FROM DISK = 'path of bak file'
WITH MOVE 'datafile_data' TO 'D:\newDATA\data.mdf',
MOVE 'logfile_Log' TO 'D:\newDATA\DATA_log.ldf',replace

alter database databasename set online with rollback immediate;
GO

โซลูชันที่ 1: เริ่มบริการ SQL ใหม่และพยายามกู้คืน DB โซลูชันที่ 2: รีสตาร์ทระบบ / เซิร์ฟเวอร์และพยายามกู้คืน DB โซลูชัน 3: นำฐานข้อมูลปัจจุบันกลับลบฐานข้อมูลปัจจุบัน / ปลายทางและพยายามกู้คืน DB

การตั้งค่าฐานข้อมูลเป็นโหมดผู้ใช้คนเดียวไม่ได้ผลสำหรับฉัน แต่การทำให้เป็นแบบออฟไลน์แล้วนำกลับมาออนไลน์ก็ใช้งานได้ ในเมนูคลิกขวาของ DB ใต้ Tasks

อย่าลืมตรวจสอบตัวเลือก 'Drop All Active Connections' ในกล่องโต้ตอบ

การใช้ฐานข้อมูลต้นฉบับไปยังออฟไลน์ได้ผลสำหรับฉัน

นี่คือวิธีที่ฉันทำการกู้คืนฐานข้อมูลจากการผลิตไปสู่การพัฒนา:

หมายเหตุ: ฉันกำลังทำผ่านงาน SSAS เพื่อผลักดันฐานข้อมูลการผลิตไปสู่การพัฒนาทุกวัน:

ขั้นตอนที่ 1: ลบข้อมูลสำรองของวันก่อนหน้าในการพัฒนา:

declare @sql varchar(1024);

set @sql = 'DEL C:\ProdAEandAEXdataBACKUP\AE11.bak'
exec master..xp_cmdshell @sql

ขั้นตอนที่ 2: คัดลอกฐานข้อมูลการผลิตไปยังการพัฒนา:

declare @cmdstring varchar(1000)
set @cmdstring = 'copy \\Share\SQLDBBackup\AE11.bak C:\ProdAEandAEXdataBACKUP'
exec master..xp_cmdshell @cmdstring 

ขั้นตอนที่ 3: กู้คืนโดยการเรียกใช้สคริปต์. sql

SQLCMD -E -S dev-erpdata1 -b -i "C:\ProdAEandAEXdataBACKUP\AE11_Restore.sql"

รหัสที่อยู่ในไฟล์ AE11_Restore.sql:

RESTORE DATABASE AE11
FROM DISK = N'C:\ProdAEandAEXdataBACKUP\AE11.bak'
WITH MOVE 'AE11' TO 'E:\SQL_DATA\AE11.mdf',
MOVE 'AE11_log' TO 'D:\SQL_LOGS\AE11.ldf',
RECOVERY;

ฉันได้รับข้อผิดพลาดนี้เมื่อมีเนื้อที่ดิสก์ไม่เพียงพอที่จะกู้คืน Db การทำความสะอาดพื้นที่บางส่วนสามารถแก้ไขได้