SQL Server: กรองผลลัพธ์ของ sp_who2

ภายใต้ SQL Server มีวิธีง่าย ๆ ในการกรองผลลัพธ์ของ sp_who2 หรือไม่ สมมติว่าฉันต้องการแสดงแถวสำหรับฐานข้อมูลบางตัวเช่น

คุณสามารถลองสิ่งที่ชอบ

DECLARE @Table TABLE(
        SPID INT,
        Status VARCHAR(MAX),
        LOGIN VARCHAR(MAX),
        HostName VARCHAR(MAX),
        BlkBy VARCHAR(MAX),
        DBName VARCHAR(MAX),
        Command VARCHAR(MAX),
        CPUTime INT,
        DiskIO INT,
        LastBatch VARCHAR(MAX),
        ProgramName VARCHAR(MAX),
        SPID_1 INT,
        REQUESTID INT
)

INSERT INTO @Table EXEC sp_who2

SELECT  *
FROM    @Table
WHERE ....

และกรองสิ่งที่คุณต้องการ

คุณสามารถ บันทึกผลลัพธ์ลงในตารางชั่วคราวได้แต่จะเป็นการดีกว่าถ้าไปที่แหล่งที่มาmaster.dbo.sysprocessesโดยตรง

ต่อไปนี้เป็นข้อความค้นหาที่จะส่งคืนผลลัพธ์เกือบจะเหมือนกับsp_who2:

SELECT  spid,
        sp.[status],
        loginame [Login],
        hostname, 
        blocked BlkBy,
        sd.name DBName, 
        cmd Command,
        cpu CPUTime,
        physical_io DiskIO,
        last_batch LastBatch,
        [program_name] ProgramName   
FROM master.dbo.sysprocesses sp 
JOIN master.dbo.sysdatabases sd ON sp.dbid = sd.dbid
ORDER BY spid 

ตอนนี้คุณสามารถเพิ่มใด ๆORDER BYหรือWHEREคำสั่งที่คุณต้องการที่จะได้รับการส่งออกที่มีความหมาย

หรือคุณอาจลองใช้การตรวจสอบกิจกรรมใน SSMS ( Ctrl+ Alt+ A) เช่นกัน

วิธีหนึ่งคือการสร้างตารางชั่วคราว:

CREATE TABLE #sp_who2 
(
   SPID INT,  
   Status VARCHAR(1000) NULL,  
   Login SYSNAME NULL,  
   HostName SYSNAME NULL,  
   BlkBy SYSNAME NULL,  
   DBName SYSNAME NULL,  
   Command VARCHAR(1000) NULL,  
   CPUTime INT NULL,  
   DiskIO INT NULL,  
   LastBatch VARCHAR(1000) NULL,  
   ProgramName VARCHAR(1000) NULL,  
   SPID2 INT
) 
GO

INSERT INTO #sp_who2
EXEC sp_who2
GO

SELECT *
FROM #sp_who2
WHERE Login = 'bla'
GO

DROP TABLE #sp_who2
GO

อิงจากhttp://web.archive.org/web/20080218124946/http://sqlserver2005.databases.aspfaq.com/how-do-i-mimic-sp-who2.html

ฉันได้สร้างสคริปต์ต่อไปนี้
ซึ่งจะช่วยแก้ไขการค้นหา การเชื่อมต่อที่ใช้งานกับดาต้าเบสใด ๆ ที่ใช้ DMV สามารถทำงานได้ภายใต้ sql 2005, 2008 และ 2008R2

สคริปต์ต่อไปนี้ใช้sys.dm_exec_sessions , sys.dm_exec_requests , sys.dm_exec_connections , sys.dm_tran_locks

Declare @dbName varchar(1000)
set @dbName='abc'

;WITH DBConn(SPID,[Status],[Login],HostName,DBName,Command,LastBatch,ProgramName)
As
(
SELECT 
    SPID = s.session_id,
    Status = UPPER(COALESCE
        (
            r.status,
            ot.task_state,
            s.status, 
        '')),
    [Login] = s.login_name,
    HostName = COALESCE
        (
            s.[host_name],
            '  .'
        ),
    DBName = COALESCE
        (
            DB_NAME(COALESCE
            (
                r.database_id,
                t.database_id
            )),
            ''
        ),
    Command = COALESCE
        (
            r.Command,
            r.wait_type,
            wt.wait_type,
            r.last_wait_type,
            ''
        ),
    LastBatch = COALESCE
        (
            r.start_time,
            s.last_request_start_time
        ),
    ProgramName = COALESCE
        (
            s.program_name, 
            ''
        )
FROM
    sys.dm_exec_sessions s
LEFT OUTER JOIN
    sys.dm_exec_requests r
ON
    s.session_id = r.session_id
LEFT OUTER JOIN
    sys.dm_exec_connections c
ON
    s.session_id = c.session_id
LEFT OUTER JOIN
(
    SELECT 
        request_session_id,
        database_id = MAX(resource_database_id)
    FROM
        sys.dm_tran_locks
    GROUP BY
        request_session_id
) t
ON
    s.session_id = t.request_session_id
LEFT OUTER JOIN
    sys.dm_os_waiting_tasks wt
ON 
    s.session_id = wt.session_id
LEFT OUTER JOIN
    sys.dm_os_tasks ot
ON 
    s.session_id = ot.session_id
LEFT OUTER JOIN
(
    SELECT
        ot.session_id,
        CPU_Time = MAX(usermode_time)
    FROM
        sys.dm_os_tasks ot
    INNER JOIN
        sys.dm_os_workers ow
    ON
        ot.worker_address = ow.worker_address
    INNER JOIN
        sys.dm_os_threads oth
    ON
        ow.thread_address = oth.thread_address
    GROUP BY
        ot.session_id
) tt
ON
    s.session_id = tt.session_id
WHERE
    COALESCE
    (
        r.command,
        r.wait_type,
        wt.wait_type,
        r.last_wait_type,
        'a'
    ) >= COALESCE
    (
        '', 
        'a'
    )
)

Select * from DBConn
where DBName like '%'+@dbName+'%'

ปรับปรุงเล็กน้อยเพื่อตอบ Astander ของ ฉันชอบที่จะวางเงื่อนไขของฉันที่ด้านบนและทำให้ง่ายต่อการใช้ซ้ำทุกวัน:

DECLARE @Spid INT, @Status VARCHAR(MAX), @Login VARCHAR(MAX), @HostName VARCHAR(MAX), @BlkBy VARCHAR(MAX), @DBName VARCHAR(MAX), @Command VARCHAR(MAX), @CPUTime INT, @DiskIO INT, @LastBatch VARCHAR(MAX), @ProgramName VARCHAR(MAX), @SPID_1 INT, @REQUESTID INT

    --SET @SPID = 10
    --SET @Status = 'BACKGROUND'
    --SET @LOGIN = 'sa'
    --SET @HostName = 'MSSQL-1'
    --SET @BlkBy = 0
    --SET @DBName = 'master'
    --SET @Command = 'SELECT INTO'
    --SET @CPUTime = 1000
    --SET @DiskIO = 1000
    --SET @LastBatch = '10/24 10:00:00'
    --SET @ProgramName = 'Microsoft SQL Server Management Studio - Query'
    --SET @SPID_1 = 10
    --SET @REQUESTID = 0

    SET NOCOUNT ON 
    DECLARE @Table TABLE(
            SPID INT,
            Status VARCHAR(MAX),
            LOGIN VARCHAR(MAX),
            HostName VARCHAR(MAX),
            BlkBy VARCHAR(MAX),
            DBName VARCHAR(MAX),
            Command VARCHAR(MAX),
            CPUTime INT,
            DiskIO INT,
            LastBatch VARCHAR(MAX),
            ProgramName VARCHAR(MAX),
            SPID_1 INT,
            REQUESTID INT
    )
    INSERT INTO @Table EXEC sp_who2
    SET NOCOUNT OFF
    SELECT  *
    FROM    @Table
    WHERE
    (@Spid IS NULL OR SPID = @Spid)
    AND (@Status IS NULL OR Status = @Status)
    AND (@Login IS NULL OR Login = @Login)
    AND (@HostName IS NULL OR HostName = @HostName)
    AND (@BlkBy IS NULL OR BlkBy = @BlkBy)
    AND (@DBName IS NULL OR DBName = @DBName)
    AND (@Command IS NULL OR Command = @Command)
    AND (@CPUTime IS NULL OR CPUTime >= @CPUTime)
    AND (@DiskIO IS NULL OR DiskIO >= @DiskIO)
    AND (@LastBatch IS NULL OR LastBatch >= @LastBatch)
    AND (@ProgramName IS NULL OR ProgramName = @ProgramName)
    AND (@SPID_1 IS NULL OR SPID_1 = @SPID_1)
    AND (@REQUESTID IS NULL OR REQUESTID = @REQUESTID)

มีผู้ใช้ sp_who3 ที่ดีอยู่บ้างที่เก็บขั้นตอนไว้ที่นั่น - ฉันแน่ใจว่า Adam Machanic ทำได้ดีมาก AFAIK

อดัมเรียกมันว่า Who is Active: http://whoisactive.com

คล้ายกับคำตอบของ KyleMitมันเป็นไปได้ที่จะเลือกตารางที่ใช้โดย SP_WHO2 โดยตรงแม้ว่าฉันคิดว่ามันจำเป็นต้องมีตาราง dbo.sys เท่านั้น

ถ้ามีคนเปิด SP นี้มันสามารถเข้าใจได้ว่ามันทำอะไร นี่คือการเลือกที่ดีที่สุดของฉันที่จะมีผลลัพธ์ที่คล้ายกันเป็น SP_WHO2

select convert(char(5),sp.spid) as SPID
        ,  CASE lower(sp.status)
                 When 'sleeping' Then lower(sp.status)
                 Else  upper(sp.status)
              END as Status
        , convert(sysname, rtrim(sp.loginame)) as LOGIN
        , CASE sp.hostname
                 When Null  Then '  .'
                 When ' ' Then '  .'
                 Else    rtrim(sp.hostname)
              END as HostName
        , CASE isnull(convert(char(5),sp.blocked),'0')
                 When '0' Then '  .'
                 Else isnull(convert(char(5),sp.blocked),'0')
              END as BlkBy
        , case when sp.dbid = 0 then null when sp.dbid <> 0 then db_name(sp.dbid) end as DBName
        , sp.cmd as Command
        , sp.cpu as CPUTime
        , sp.physical_io as DiskIO
        , sp.last_batch as LastBatch
        , sp.program_name as ProgramName 
        from master.dbo.sysprocesses sp (nolock)
  ;

เหนือการเลือกนี้คุณสามารถเลือกเขตข้อมูลที่คุณต้องการและมีลำดับที่คุณต้องการ

วิธีที่ง่ายมากที่จะทำคือสร้างลิงค์ ODBC ใน EXCEL และรัน SP_WHO2 จากที่นั่น

คุณสามารถรีเฟรชทุกครั้งที่คุณต้องการและเพราะมันเป็น EXCEL ทุกอย่างสามารถจัดการได้อย่างง่ายดาย!

ใช่โดยการจับเอาท์พุทของ sp_who2 ลงในตารางแล้วเลือกจากตาราง แต่นั่นจะเป็นวิธีที่ไม่ดีในการทำ อันดับแรกเนื่องจาก sp_who2 แม้จะได้รับความนิยมขั้นตอนที่ไม่มีเอกสารและคุณไม่ควรเชื่อถือขั้นตอนที่ไม่มีเอกสาร ข้อที่สองเพราะ sp_who2 ทั้งหมดสามารถทำได้และอื่น ๆ อีกมากมายสามารถรับได้จากsys.dm_exec_requestsและ DMV อื่น ๆ และการแสดงสามารถกรองสั่งเข้าร่วมและสินค้าอื่น ๆ ที่มาพร้อมกับแถวที่น่าสงสัย

ส่วนขยายของคำตอบแรกและดีที่สุด ... ฉันได้สร้างกระบวนงานที่เก็บไว้ในฐานข้อมูลหลักที่คุณสามารถส่งพารามิเตอร์ไปยัง .. เช่นชื่อของฐานข้อมูล:

USE master
GO

CREATE PROCEDURE sp_who_db
(
    @sDBName varchar(200)   = null,
    @sStatus varchar(200)   = null,
    @sCommand varchar(200)  = null,
    @nCPUTime int           = null
)
AS
DECLARE @Table TABLE
(
    SPID INT,
    Status VARCHAR(MAX),
    LOGIN VARCHAR(MAX),
    HostName VARCHAR(MAX),
    BlkBy VARCHAR(MAX),
    DBName VARCHAR(MAX),
    Command VARCHAR(MAX),
    CPUTime INT,
    DiskIO INT,
    LastBatch VARCHAR(MAX),
    ProgramName VARCHAR(MAX),
    SPID_1 INT,
    REQUESTID INT
)

INSERT INTO @Table EXEC sp_who2

SELECT  *
    FROM    @Table
    WHERE   (@sDBName IS NULL OR DBName = @sDBName)
    AND     (@sStatus IS NULL OR Status = @sStatus)
    AND     (@sCommand IS NULL OR Command = @sCommand)
    AND     (@nCPUTime IS NULL OR CPUTime > @nCPUTime)
GO 

ฉันอาจขยายมันเพื่อเพิ่มคำสั่งซื้อโดยพารามิเตอร์หรือแม้กระทั่งฆ่าพารามิเตอร์เพื่อฆ่าการเชื่อมต่อทั้งหมดไปยังข้อมูลเฉพาะ

ฉันกำลังเขียนที่นี่เพื่อใช้งานในอนาคตของฉันเอง มันใช้ sp_who2 และแทรกลงในตัวแปรตารางแทนตารางชั่วคราวเพราะไม่สามารถใช้ตารางชั่วคราวสองครั้งได้หากคุณไม่ทำมัน และแสดงบล็อคและตัวบล็อกในบรรทัดเดียวกัน

--blocked: waiting becaused blocked by blocker
--blocker: caused blocking
declare @sp_who2 table(
    SPID int,
    Status varchar(max),
    Login varchar(max),
    HostName varchar(max),
    BlkBy varchar(max),
    DBName varchar(max),
    Command varchar(max),
    CPUTime int,
    DiskIO int,
    LastBatch varchar(max),
    ProgramName varchar(max),
    SPID_2 int,
    REQUESTID int
)
insert into @sp_who2 exec sp_who2
select  w.SPID blocked_spid, w.BlkBy blocker_spid, tblocked.text blocked_text, tblocker.text blocker_text
from    @sp_who2 w
        inner join sys.sysprocesses pblocked on w.SPID = pblocked.spid
        cross apply sys.dm_exec_sql_text(pblocked.sql_handle) tblocked
        inner join sys.sysprocesses pblocker on case when w.BlkBy = '  .' then 0 else cast(w.BlkBy as int) end = pblocker.spid
        cross apply sys.dm_exec_sql_text(pblocker.sql_handle) tblocker
where   pblocked.Status = 'SUSPENDED'

นี่เป็นวิธีแก้ปัญหาสำหรับคุณ: http://blogs.technet.com/b/wardpond/archive/2005/08/01/the-openrowset-trick-accessing-stored-procedure-output-in-a-select-statement ขอบ

select * from openrowset ('SQLOLEDB', '192.168.x.x\DATA'; 'user'; 'password', 'sp_who')