SQL Server: สร้างเคส UPPER ทั้งหมดให้เป็น Case / Title Case ที่เหมาะสม

Question 1

ฉันมีตารางที่นำเข้าเป็น UPPER CASE ทั้งหมดและต้องการเปลี่ยนเป็นกรณีที่เหมาะสม คุณใช้สคริปต์อะไรในการทำสิ่งนี้

Question 2

นี่คือ UDF ที่จะทำเคล็ดลับ ...

create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
  declare @Reset bit;
  declare @Ret varchar(8000);
  declare @i int;
  declare @c char(1);

  if @Text is null
    return null;

  select @Reset = 1, @i = 1, @Ret = '';

  while (@i <= len(@Text))
    select @c = substring(@Text, @i, 1),
      @Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
      @Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
      @i = @i + 1
  return @Ret
end

คุณยังคงต้องใช้เพื่ออัปเดตข้อมูลของคุณ

Question 3

ฟังก์ชันนี้:

"กรณีที่เหมาะสม" คำ "UPPER CASE" ทั้งหมดที่คั่นด้วยช่องว่าง
ทิ้ง "คำตัวพิมพ์เล็ก" ไว้เพียงอย่างเดียว
ทำงานได้อย่างถูกต้องแม้กระทั่งสำหรับตัวอักษรที่ไม่ใช่ภาษาอังกฤษ
เป็นแบบพกพาที่ไม่ใช้คุณสมบัติแฟนซีของเซิร์ฟเวอร์ SQL เวอร์ชันล่าสุด
สามารถเปลี่ยนไปใช้ NCHAR และ NVARCHAR สำหรับการรองรับ Unicode ได้อย่างง่ายดายรวมถึงความยาวพารามิเตอร์ที่คุณเห็นว่าเหมาะสม
สามารถกำหนดค่านิยามพื้นที่สีขาวได้

CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

ผลลัพธ์:

dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ

Question 4

UPDATE titles
  SET title =
      UPPER(LEFT(title, 1)) +
        LOWER(RIGHT(title, LEN(title) - 1))

http://sqlmag.com/t-sql/how-title-case-column-value

Question 5

หากคุณสามารถเปิดใช้งาน CLR ใน SQL Server (ต้องใช้ปี 2005 หรือใหม่กว่า) คุณสามารถสร้างฟังก์ชัน CLRที่ใช้ TextInfo ToTitleCaseซึ่งจะช่วยให้คุณสร้างวิธีที่คำนึงถึงวัฒนธรรมในการทำสิ่งนี้ได้ในไม่กี่แห่ง บรรทัดของรหัส

Question 6

ฉันรู้ว่านี่เป็นกระทู้ที่ล่าช้าในหัวข้อนี้ แต่ก็คุ้มค่า ฟังก์ชั่นนี้ใช้ได้กับฉันตลอดกาล เลยคิดว่าเอามาแบ่งปัน

CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char = SUBSTRING(@InputString, @Index, 1)
    IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
    IF @Index + 1 <= LEN(@InputString)
BEGIN
    IF @Char != ''''
    OR
    UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
    SET @OutputString =
    STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
    SET @Index = @Index + 1
END

RETURN ISNULL(@OutputString,'')
END

ทดสอบการโทร:

select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test

ผล:

ป้อนคำอธิบายภาพที่นี่

Question 7

ฉันเล่นเกมช้าไปหน่อย แต่ฉันเชื่อว่ามันใช้งานได้มากกว่าและใช้ได้กับทุกภาษารวมถึงรัสเซียเยอรมันไทยเวียดนามเป็นต้นมันจะทำให้อะไรเป็นตัวพิมพ์ใหญ่หลังจาก 'หรือ - หรือ หรือ (หรือ) หรือช่องว่าง (ชัดเจน :)

CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos    int = 1
      , @pos2   int

if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
    set @name = lower(rtrim(@name))
    while (1 = 1)
    begin
        set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
        set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
        set @pos += @pos2
        if (isnull(@pos2, 0) = 0 or @pos > len(@name))
            break
    end
end

return @name
END
GO

Question 8

หากคุณอยู่ใน SSIS การนำเข้าข้อมูลที่มีการผสมกันและจำเป็นต้องทำการค้นหาในคอลัมน์ด้วยกรณีที่เหมาะสมคุณจะสังเกตเห็นว่าการค้นหาล้มเหลวเมื่อมีการผสมแหล่งที่มาและแหล่งที่มาของการค้นหานั้นเหมาะสม คุณจะสังเกตเห็นว่าคุณไม่สามารถใช้ฟังก์ชันด้านขวาและด้านซ้ายคือ SSIS สำหรับ SQL Server 2008r2 สำหรับคอลัมน์ที่ได้รับ นี่เป็นวิธีแก้ปัญหาที่เหมาะกับฉัน:

UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))

Question 9

นี่คือเวอร์ชันที่ใช้ตารางลำดับหรือตัวเลขแทนการวนซ้ำ คุณสามารถแก้ไขส่วนคำสั่ง WHERE เพื่อให้เหมาะกับกฎส่วนบุคคลของคุณเมื่อใดที่จะแปลงอักขระเป็นตัวพิมพ์ใหญ่ ฉันเพิ่งรวมชุดง่ายๆที่จะพิมพ์ใหญ่ตัวอักษรใด ๆ ที่ดำเนินการโดยไม่ใช่ตัวอักษรยกเว้นเครื่องหมายอะพอสทรอฟี นี่หมายความว่า 123apple จะจับคู่กับ "a" ได้อย่างไรเนื่องจาก "3" ไม่ใช่ตัวอักษร หากคุณต้องการเพียงแค่พื้นที่สีขาว (ช่องว่าง, แท็บผลตอบแทนการขนส่งสายฟีด) คุณสามารถเปลี่ยนรูปแบบด้วย'[^a-z]''[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'

CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN

-- 1. Convert all letters to lower case
    DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);

-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
    SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
    FROM (
        SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
        FROM       (SELECT 0 AS n UNION SELECT    1 UNION SELECT    2 UNION SELECT    3 UNION SELECT    4 UNION SELECT    5 UNION SELECT    6 UNION SELECT    7 UNION SELECT    8 UNION SELECT    9) AS    n1
        CROSS JOIN (SELECT 0 AS n UNION SELECT   10 UNION SELECT   20 UNION SELECT   30 UNION SELECT   40 UNION SELECT   50 UNION SELECT   60 UNION SELECT   70 UNION SELECT   80 UNION SELECT   90) AS   n10
        CROSS JOIN (SELECT 0 AS n UNION SELECT  100 UNION SELECT  200 UNION SELECT  300 UNION SELECT  400 UNION SELECT  500 UNION SELECT  600 UNION SELECT  700 UNION SELECT  800 UNION SELECT  900) AS  n100
        CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000)                                                                                                             AS n1000
        ) AS Sequence
    WHERE 
        n BETWEEN 1 AND Len( @InitCap )
    AND SubString( @InitCap, n, 1 ) LIKE '[a-z]'                 /* this character is a letter */
    AND (
        n = 1                                                    /* this character is the first `character` */
        OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]'           /* the previous character is NOT a letter */
        )
    AND (
        n < 3                                                    /* only test the 3rd or greater characters for this exception */
        OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
        )

-- 3. Return the modified version of the input
    RETURN @InitCap

END

Question 10

ลิงก์ที่ฉันโพสต์ไว้ข้างต้นเป็นตัวเลือกที่ยอดเยี่ยมในการแก้ไขปัญหาหลักนั่นคือเราไม่สามารถเขียนบัญชีแบบเป็นโปรแกรมสำหรับทุกกรณี (Smith-Jones, von Haussen, John Smith MD) อย่างน้อยก็ไม่ใช่ในลักษณะที่สวยงาม โทนี่แนะนำแนวคิดเกี่ยวกับข้อยกเว้น / ตัวละครเพื่อจัดการกับกรณีเหล่านี้ อย่างไรก็ตามจากความคิดของ Cervo (ตัวอักษรด้านล่างทั้งหมดที่นำหน้าด้วยช่องว่าง) คำสั่งแทนที่สามารถรวมอยู่ในการแทนที่ตามตารางเดียวแทน จริงๆแล้วการผสมอักขระต่ำ / ขึ้นสามารถแทรกลงใน @alpha และคำสั่งจะไม่เปลี่ยนแปลง:

declare @str    nvarchar(8000)
declare @alpha  table (low nchar(1), up nchar(1))


set @str = 'ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'

-- stage the alpha (needs number table)
insert into @alpha
    -- A-Z / a-z
    select      nchar(n+32),
                nchar(n)
    from        dbo.Number
    where       n between 65 and 90 or
                n between 192 and 223

-- append space at start of str
set @str = lower(' ' + @str)

-- upper all lower case chars preceded by space
select  @str = replace(@str, ' ' + low, ' ' + up) 
from    @Alpha

select @str

Question 11

มันจะสมเหตุสมผลที่จะรักษาข้อยกเว้นในการดูแล The von Neumann's, McCain's, DeGuzman's และ Johnson-Smith's

Question 12

ยืมและปรับปรุงในคำตอบ @Richard Sayakanit สิ่งนี้จัดการกับคำหลายคำ เช่นเดียวกับคำตอบของเขาสิ่งนี้ไม่ได้ใช้ UDF ใด ๆ มีเพียงฟังก์ชันในตัว ( STRING_SPLITและSTRING_AGG) และมันค่อนข้างเร็ว STRING_AGGต้องใช้ SQL Server 2017 แต่คุณสามารถใช้STUFF/XMLเคล็ดลับได้ตลอดเวลา จะไม่จัดการทุกข้อยกเว้น แต่สามารถทำงานได้ดีสำหรับข้อกำหนดต่างๆ

SELECT StateName = 'North Carolina' 
INTO #States
UNION ALL
SELECT 'Texas'


;WITH cteData AS 
(
    SELECT 
        UPPER(LEFT(value, 1)) +
            LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
    FROM   #States op
    CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT 
    STRING_AGG(value, ' ')
FROM cteData c 
GROUP BY StateName

Question 13

หากคุณรู้ว่าข้อมูลทั้งหมดเป็นเพียงคำเดียวนี่คือทางออก ขั้นแรกให้อัปเดตคอลัมน์ให้ต่ำลงทั้งหมดแล้วเรียกใช้สิ่งต่อไปนี้

    update tableName set columnName = 
    upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName

Question 14

ปรับเปลี่ยนเล็กน้อยเพื่อ @ คำตอบของ Galwegian - ซึ่งจะเปลี่ยนเช่นSt Elizabeth'sเข้าSt Elizabeth'Sเข้า

การแก้ไขนี้ทำให้เครื่องหมายวรรคตอน - s เป็นตัวพิมพ์เล็กโดยที่ s มาที่ท้ายสตริงที่จัดเตรียมไว้หรือ s ตามด้วยช่องว่าง (และเฉพาะในกรณีเหล่านั้นเท่านั้น)

create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
    declare @reset int;
    declare @ret varchar(8000);
    declare @i int;
    declare @c char(1);
    declare @d char(1);

    if @text is null
    return null;

    select @reset = 1, @i = 1, @ret = '';

    while (@i <= len(@text))
    select
        @c = substring(@text, @i, 1),
        @d = substring(@text, @i+1, 1),
        @ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
        @reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
        @i = @i + 1
    return @ret
end

ปรากฎว่า:

st elizabeth's เป็น St Elizabeth's
o'keefe เป็น O'Keefe
o'sullivan เป็น O'Sullivan

ความคิดเห็นของผู้อื่นว่าวิธีการแก้ปัญหาที่แตกต่างกันนั้นดีกว่าสำหรับการป้อนข้อมูลที่ไม่ใช่ภาษาอังกฤษยังคงเป็นเช่นนั้น

Question 15

ฉันคิดว่าคุณจะพบว่าสิ่งต่อไปนี้มีประสิทธิภาพมากกว่า:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
    SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

คำสั่งแทนที่สามารถตัดและวางลงในแบบสอบถาม SQL ได้โดยตรง เป็นเรื่องที่น่าเกลียดมากอย่างไรก็ตามการแทนที่ @str ด้วยคอลัมน์ที่คุณสนใจคุณจะไม่จ่ายราคาสำหรับเคอร์เซอร์โดยปริยายเช่นเดียวกับที่คุณทำกับ udfs ที่โพสต์ไว้ ฉันพบว่าแม้แต่การใช้ UDF ของฉันมันก็มีประสิทธิภาพมากขึ้น

โอ้และแทนที่จะสร้างคำสั่งแทนที่ด้วยมือให้ใช้สิ่งนี้:

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
    SET @c = CHAR(ASCII('a') + @x)
    SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
    SET @x = @x + 1
END
PRINT @sql

ทั้งนี้ขึ้นอยู่กับจำนวนแถว ฉันหวังว่าคุณจะทำได้แค่ s / \ b ([az]) / uc $ 1 / แต่เราทำงานกับเครื่องมือที่เรามีได้ดี

โปรดทราบว่าคุณจะต้องใช้สิ่งนี้เนื่องจากคุณจะต้องใช้เป็น .... SELECT dbo.ProperCase (LOWER (คอลัมน์)) เนื่องจากคอลัมน์เป็นตัวพิมพ์ใหญ่ มันใช้งานได้ค่อนข้างเร็วบนตาราง 5,000 รายการของฉัน (ไม่แม้แต่วินาทีเดียว) แม้จะต่ำกว่าก็ตาม

ในการตอบสนองต่อความคิดเห็นที่วุ่นวายเกี่ยวกับการทำให้เป็นสากลฉันขอนำเสนอการใช้งานต่อไปนี้ที่จัดการกับอักขระ ascii ทุกตัวที่อาศัยการใช้งานบนและล่างของ SQL Server เท่านั้น โปรดจำไว้ว่าตัวแปรที่เราใช้ที่นี่คือ VARCHAR ซึ่งหมายความว่าสามารถเก็บค่า ASCII ได้เท่านั้น ในการใช้ตัวอักษรสากลเพิ่มเติมคุณต้องใช้ NVARCHAR ตรรกะจะคล้ายกัน แต่คุณจะต้องใช้ UNICODE และ NCHAR แทน ASCII AND CHAR และคำสั่งแทนที่จะใหญ่กว่ามาก ...

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000),
    @count  INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
    SET @c = CHAR(@x)
    -- Only generate replacement expression for characters where upper and lowercase differ
    IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
    BEGIN
        SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
        SET @count = @count + 1
    END
    SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)

โดยพื้นฐานแล้วหลักฐานของวิธีการของฉันคือการซื้อขายคอมพิวเตอร์ล่วงหน้าเพื่อประสิทธิภาพ การใช้งาน ASCII แบบเต็มมีดังนี้:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
SET @str =     REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

Question 16

สายเกินไปหรือไม่ที่จะกลับไปรับข้อมูลที่ไม่มีตัวพิมพ์ใหญ่

ฐานลูกค้าของคุณ von Neumann, McCain, DeGuzman และ Johnson-Smith ของคุณอาจไม่ชอบผลการประมวลผลของคุณ ...

นอกจากนี้ฉันคาดเดาว่านี่เป็นการอัปเกรดข้อมูลเพียงครั้งเดียว? อาจจะง่ายกว่าในการส่งออกกรอง / แก้ไขและนำเข้าชื่อที่แก้ไขไปยังฐานข้อมูลอีกครั้งจากนั้นคุณสามารถใช้วิธีที่ไม่ใช่ SQL เพื่อแก้ไขชื่อ ...

Question 17

นี่คือรูปแบบอื่นที่ฉันพบในฟอรัม SQLTeam.com @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID=47718

create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END

--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int

--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90

WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END

IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END

SET @ctr = @ctr + 1

WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END

END
RETURN @output
END



GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO

Question 18

ฉันรู้ว่าปีศาจอยู่ในรายละเอียด (โดยเฉพาะอย่างยิ่งในกรณีที่ข้อมูลส่วนบุคคลของผู้คนเกี่ยวข้อง) และเป็นเรื่องดีมากที่จะมีชื่อตัวพิมพ์ใหญ่อย่างถูกต้อง แต่ความยุ่งยากข้างต้นคือสาเหตุที่พวกเราใช้สิ่งต่อไปนี้ :

SELECT UPPER('Put YoUR O'So oddLy casED McWeird-nAme von rightHERE here')

จากประสบการณ์ของฉันผู้คนเห็นชื่อของพวกเขาดี ... แม้ว่าจะผ่านไปครึ่งประโยคแล้วก็ตาม

อ้างถึง: ชาวรัสเซียใช้ดินสอ!

Question 19

เพิ่งเรียนรู้เกี่ยวกับ InitCap() .

นี่คือโค้ดตัวอย่างบางส่วน:

SELECT ID
      ,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable

Question 20

สิ่งนี้ใช้ได้ใน SSMS:

Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]

Question 21

เมื่อเร็ว ๆ นี้ต้องจัดการกับสิ่งนี้และเกิดสิ่งต่อไปนี้หลังจากที่ไม่มีอะไรกระทบทุกอย่างที่ฉันต้องการ สิ่งนี้จะทำทั้งประโยคกรณีสำหรับการจัดการคำพิเศษ นอกจากนี้เรายังมีปัญหาเกี่ยวกับ 'คำ' อักขระเดี่ยวที่วิธีการที่ง่ายกว่าจำนวนมากจัดการ แต่ไม่ใช่วิธีที่ซับซ้อนกว่านั้น ตัวแปรผลตอบแทนเดียวไม่มีลูปหรือเคอร์เซอร์อย่างใดอย่างหนึ่ง

CREATE FUNCTION ProperCase(@Text AS NVARCHAR(MAX))
RETURNS NVARCHAR(MAX)
AS BEGIN

    DECLARE @return NVARCHAR(MAX)

    SELECT @return = COALESCE(@return + ' ', '') + Word FROM (
         SELECT CASE
            WHEN LOWER(value) = 'llc' THEN UPPER(value)
            WHEN LOWER(value) = 'lp' THEN UPPER(value) --Add as many new special cases as needed
            ELSE
               CASE WHEN LEN(value) = 1
               THEN UPPER(value)
               ELSE UPPER(LEFT(value, 1)) + (LOWER(RIGHT(value, LEN(value) - 1)))
              END
            END AS Word
         FROM STRING_SPLIT(@Text, ' ')
     ) tmp

     RETURN @return
END

Question 22

คัดลอกและวางข้อมูลของคุณลงใน MS Word และใช้การแปลงข้อความในตัวเพื่อ "ใช้อักษรตัวพิมพ์ใหญ่ในแต่ละคำ" เปรียบเทียบกับข้อมูลเดิมของคุณเพื่อระบุข้อยกเว้น มองไม่เห็นวิธีใด ๆ ในการหลีกเลี่ยงข้อยกเว้นประเภท "MacDonald" และ "IBM" ด้วยตนเอง แต่นี่คือวิธีที่ฉันทำ FWIW

Question 23

ในเซิร์ฟเวอร์เซิร์ฟเวอร์ 2016 และใหม่กว่าคุณสามารถใช้STRING_SPLIT


with t as (
    select 'GOOFYEAR Tire and Rubber Company' as n
    union all
    select 'THE HAPPY BEAR' as n
    union all
    select 'MONK HOUSE SALES' as n
    union all
    select 'FORUM COMMUNICATIONS' as n
)
select
    n,
    (
        select ' ' + (
            upper(left(value, 1))
            + lower(substring(value, 2, 999))
        )
        from (
            select value
            from string_split(t.n, ' ')
        ) as sq
        for xml path ('')
    ) as title_cased
from t