ฉันจะส่งผ่านข้อโต้แย้งไปยังไฟล์แบตช์ได้อย่างไร

ฉันต้องส่ง ID และรหัสผ่านไปยังไฟล์แบตช์ในขณะที่ทำงานมากกว่าการเข้ารหัสลงในไฟล์

นี่คือลักษณะบรรทัดคำสั่ง:

test.cmd admin P@55w0rd > test-log.txt

เคล็ดลับที่มีประโยชน์อีกข้อหนึ่งคือใช้%*เพื่อหมายถึง "ทั้งหมด" ตัวอย่างเช่น:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

เมื่อคุณทำงาน:

test-command admin password foo bar

ไฟล์แบทช์ด้านบนจะทำงาน:

fake-command /u admin /p password admin password foo bar

ฉันอาจมีไวยากรณ์ผิดเล็กน้อย แต่นี่เป็นแนวคิดทั่วไป

นี่คือวิธีที่ฉันทำ:

@fake-command /u %1 /p %2

นี่คือลักษณะของคำสั่ง:

test.cmd admin P@55w0rd > test-log.txt

%1นำไปใช้กับพารามิเตอร์แรก%2(และนี่คือส่วนที่ยุ่งยาก) นำไปใช้กับที่สอง คุณสามารถส่งพารามิเตอร์ถึง 9 พารามิเตอร์ด้วยวิธีนี้

หากคุณต้องการจัดการพารามิเตอร์ที่หายไปอย่างชาญฉลาดคุณสามารถทำสิ่งต่อไปนี้:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

การเข้าถึงพารามิเตอร์แบตช์สามารถทำได้ง่ายด้วย% 1,% 2, ... % 9 หรือยัง% *
แต่เฉพาะในกรณีที่เนื้อหานั้นง่าย

ไม่มีวิธีที่ง่ายสำหรับเนื้อหาที่ซับซ้อนเช่น"&"^&เนื่องจากไม่สามารถเข้าถึง% 1 ได้โดยไม่เกิดข้อผิดพลาด

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

เส้นขยายเป็น

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

และแต่ละบรรทัดล้มเหลวเนื่องจากหนึ่งใน&นั้นอยู่นอกเครื่องหมายคำพูด

มันสามารถแก้ไขได้ด้วยการอ่านจากไฟล์ชั่วคราวเป็นรุ่นที่กล่าวถึงของพารามิเตอร์

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

เคล็ดลับคือการเปิดใช้งานecho onและขยาย% 1 หลังremคำสั่ง (ใช้ได้กับ%2 .. %*)
ดังนั้นแม้"&"&จะสามารถสะท้อนได้โดยไม่เกิดข้อผิดพลาดตามที่ได้กล่าวไว้

แต่เพื่อให้สามารถเปลี่ยนเส้นทางเอาต์พุตของecho onคุณต้องใช้ for-loops สองรายการ

อักขระพิเศษ* #จะถูกใช้เพื่อความปลอดภัยต่อเนื้อหาเช่น/?(จะแสดงความช่วยเหลือสำหรับREM)
หรือเครื่องหมาย ^ remที่ปลายสายสามารถทำงานเป็นตัวละครหลายแม้ในหลังจากที่

จากนั้นอ่านเอาต์พุตพารามิเตอร์ remจากไฟล์ แต่อย่างระมัดระวัง
FOR / F ควรทำงานด้วยการขยายเวลาออกล่าช้าส่วนเนื้อหาอื่น ๆ ที่มี "!" จะถูกทำลาย
หลังจากลบอักขระพิเศษในparam1คุณได้รับมัน

และใช้param1อย่างปลอดภัยเปิดใช้งานการขยายที่ล่าช้า

อ้อและก็ไม่ลืมที่จะใช้ตัวแปรเช่น%%1เมื่อใช้ifและforและแก๊ง

หากคุณลืมคู่%คุณจะแทนค่าในอาร์กิวเมนต์บรรทัดคำสั่ง (อาจเป็นโมฆะ) และคุณจะได้รับข้อความแสดงข้อผิดพลาดที่ทำให้เกิดความสับสน

ไม่จำเป็นต้องซับซ้อนไม่ได้ มันเป็นเพียงคำสั่งพารามิเตอร์% 1% 2 ตัวอย่างเช่น

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

"หยุด" แสดงสิ่งที่ไฟล์แบทช์ได้ทำและรอให้คุณกดปุ่มใด ๆ บันทึกเป็น xx.bat ในโฟลเดอร์ Windows

หากต้องการใช้งานให้พิมพ์ตัวอย่างเช่น:

xx c:\f\30\*.* f:\sites\30

ไฟล์แบทช์นี้ดูแลพารามิเตอร์ที่จำเป็นทั้งหมดเช่นการคัดลอกเฉพาะไฟล์ที่ใหม่กว่าเป็นต้นฉันใช้ตั้งแต่ Windows มาก่อน หากคุณต้องการดูชื่อไฟล์ขณะที่กำลังถูกคัดลอกให้ปล่อยQพารามิเตอร์ออก

เพื่อนคนหนึ่งถามฉันเกี่ยวกับเรื่องนี้เมื่อเร็ว ๆ นี้ดังนั้นฉันคิดว่าฉันโพสต์ว่าฉันจัดการกับอาร์กิวเมนต์บรรทัดคำสั่งในไฟล์แบตช์ได้อย่างไร

เทคนิคนี้มีค่าใช้จ่ายเล็กน้อยอย่างที่คุณเห็น แต่มันทำให้แบทช์ไฟล์ของฉันง่ายต่อการเข้าใจและนำไปใช้อย่างรวดเร็ว เช่นเดียวกับการสนับสนุนโครงสร้างต่อไปนี้:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

jist ของมันจะมี:init, :parseและ:mainฟังก์ชั่น

ตัวอย่างการใช้งาน

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

หมายเหตุ: หาก"%1"==""จะทำให้เกิดปัญหาหาก%1อยู่ในเครื่องหมายคำพูด

ในกรณีนั้นให้ใช้IF [%1]==[]หรือใน NT 4 (SP6) และใหม่กว่าเท่านั้นIF "%~1"==""แทน

มาทำให้ง่ายกันเถอะ

นี่คือไฟล์. cmd

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

นี่คือ 3 สายจากบรรทัดคำสั่ง

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

สิ่งนี้จะวนรอบพารามิเตอร์ชุดงาน (% *) ไม่ว่าจะมีการอ้างอิงหรือไม่จากนั้นก็สะท้อนแต่ละพารามิเตอร์

ฉันเขียนสคริปต์ read_params ง่าย ๆ ที่สามารถเรียกได้ว่าเป็นฟังก์ชั่น (หรือภายนอก.bat) และจะทำให้ตัวแปรทั้งหมดเข้าสู่สภาพแวดล้อมปัจจุบัน มันจะไม่แก้ไขพารามิเตอร์ดั้งเดิมเพราะฟังก์ชั่นจะถูกcalled ด้วยสำเนาของพารามิเตอร์เดิม

ตัวอย่างเช่นให้คำสั่งต่อไปนี้:

myscript.bat some -random=43 extra -greeting="hello world" fluff

myscript.bat จะสามารถใช้ตัวแปรหลังจากเรียกใช้ฟังก์ชัน:

call :read_params %*

echo %random%
echo %greeting%

นี่คือฟังก์ชั่น:

:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B

ข้อ จำกัด

• -forceไม่สามารถโหลดข้อโต้แย้งที่ไม่มีค่าเช่น คุณสามารถใช้-force=trueแต่ฉันไม่สามารถคิดวิธีอนุญาตค่าว่างโดยไม่ทราบรายการพารามิเตอร์ล่วงหน้าที่ไม่มีค่า

การเปลี่ยนแปลง

• 2016/02/18
  • ไม่ต้องการการขยายที่ล่าช้าอีกต่อไป
  • ตอนนี้ทำงานร่วมกับอาร์กิวเมนต์บรรทัดคำสั่งอื่น ๆ โดยการค้นหา-ก่อนพารามิเตอร์

ในแบตช์ไฟล์

set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%

% 1 และ% 2 ส่งคืนค่าอาร์กิวเมนต์ที่หนึ่งและสองตามลำดับ

และในบรรทัดคำสั่งผ่าน arguemt

Directory> batchFileName admin P@55w0rd 

ผลผลิตจะได้

admin
P@55w0rd

หากต้องการอ้างถึงชุดตัวแปรในบรรทัดคำสั่งคุณจะต้องใช้%a%ตัวอย่างเช่น:

set a=100 
echo %a%  
rem output = 100 

หมายเหตุ: ใช้งานได้กับ Windows 7 pro

แรงบันดาลใจจากคำตอบที่อื่นโดย @ จอนฉันได้สร้างอัลกอริทึมทั่วไปมากขึ้นสำหรับการแยกพารามิเตอร์ที่มีชื่อค่าทางเลือกและสวิทช์

foobarให้เราบอกว่าเราต้องการที่จะใช้ยูทิลิตี้ มันต้องมีคำสั่งเริ่มต้น มันมีพารามิเตอร์ทางเลือก--fooซึ่งรับค่าตัวเลือก (ซึ่งไม่สามารถเป็นพารามิเตอร์อื่นได้) defaultถ้าค่าจะหายไปค่าเริ่มต้นของมัน นอกจากนี้ยังมีพารามิเตอร์ตัวเลือก--barที่จะใช้เวลาที่ต้องการความคุ้มค่า สุดท้ายสามารถใช้แฟล็ก--bazโดยไม่มีค่า โอ้และพารามิเตอร์เหล่านี้สามารถมาในลำดับใดก็ได้

กล่าวอีกนัยหนึ่งดูเหมือนว่า:

foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]

นี่คือทางออก:

@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1

• ใช้SETLOCALเพื่อไม่ให้ตัวแปรหลุดเข้าไปในสภาพแวดล้อมการโทร
• อย่าลืมเริ่มต้นตัวแปรSET FOO=ฯลฯ ในกรณีที่มีคนกำหนดไว้ในสภาพแวดล้อมการโทร
• ใช้%~1เพื่อลบเครื่องหมายคำพูด
• ใช้IF "%ARG%" == ""และไม่ใช่IF [%ARG%] == []เพราะ[และ]ไม่เล่นเลยด้วยค่าที่ลงท้ายด้วยช่องว่าง
• แม้ว่าคุณจะSHIFTอยู่ในIFบล็อก แต่เนื้อหาปัจจุบันเช่น%~1ไม่ได้รับการอัปเดตจะถูกพิจารณาเมื่อIFมีการแยกวิเคราะห์ คุณสามารถใช้%~1และ%~2ภายในIFบล็อก SHIFTแต่มันจะทำให้เกิดความสับสนเพราะคุณมี คุณสามารถวางส่วนSHIFTท้ายของบล็อกเพื่อความชัดเจน แต่นั่นอาจทำให้หลงทางและ / หรือทำให้ผู้คนสับสนเช่นกัน ดังนั้น "การจับภาพ" %~1และ%~1นอกบล็อกจึงน่าจะดีที่สุด
• IF NOT "%ARG:~0,2%" == "--"คุณไม่ต้องการที่จะใช้พารามิเตอร์ในสถานที่ของค่าพารามิเตอร์ตัวของผู้อื่นให้คุณต้องตรวจสอบ
• ระวังเฉพาะSHIFTเมื่อคุณใช้พารามิเตอร์อย่างใดอย่างหนึ่ง
• รหัสซ้ำกันSET FOO=%DEFAULT_FOO%เป็นเรื่องน่าเศร้า แต่ทางเลือกอื่นคือการเพิ่มบล็อกIF "%FOO%" == "" SET FOO=%DEFAULT_FOO%นอก IF NOT "%ARG%" == ""อย่างไรก็ตามเนื่องจากนี้ยังคงอยู่ภายในIF "%PARAM%" == "--foo"บล็อกที่%FOO%คุ้มค่าที่จะได้รับการประเมินและการตั้งค่าก่อนที่คุณเคยเข้ามาบล็อกดังนั้นคุณจะไม่เคยตรวจพบว่าทั้ง--fooพารามิเตอร์เป็นปัจจุบันและยังว่า%FOO%คุ้มค่าที่ขาดหายไป
• โปรดทราบว่าECHO Missing bar value. 1>&2ส่งข้อความข้อผิดพลาดไปยัง stderr
• ต้องการบรรทัดว่างในไฟล์แบตช์ของ Windows หรือไม่ คุณต้องใช้ECHO:หรือรูปแบบใดรูปแบบหนึ่ง

สร้างไฟล์แบตช์ใหม่ (ตัวอย่าง: openclass.bat) และเขียนบรรทัดนี้ในไฟล์:

java %~n1

จากนั้นวางไฟล์แบตช์ไว้ในโฟลเดอร์ system32 ไปที่ไฟล์คลาส Java ของคุณคลิกขวาคุณสมบัติเปิดด้วย ... จากนั้นค้นหาไฟล์แบตช์เลือกและนั่นคือ ...

มันใช้งานได้สำหรับฉัน

PS: ฉันไม่สามารถหาวิธีปิดหน้าต่าง cmd เมื่อฉันปิดคลาส Java สำหรับตอนนี้...

วิธีแก้ปัญหาง่าย ๆ (แม้ว่าคำถามจะเก่า)

Test1.bat

echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause

CallTest1.bat

call "C:\Temp\Test1.bat" pass123

เอาท์พุต

YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .

โดยที่ YourLocalPath เป็นเส้นทางไดเรกทอรีปัจจุบัน

เพื่อให้ง่ายต่อการจัดเก็บคำสั่งพารามิเตอร์ในตัวแปรและใช้ตัวแปรเพื่อเปรียบเทียบ

มันไม่เพียง แต่เขียนได้ง่าย แต่ยังง่ายต่อการบำรุงรักษาด้วยดังนั้นหากต่อมามีคนอื่นหรือคุณอ่านสคริปต์หลังจากผ่านไปนานมันจะง่ายต่อการเข้าใจและบำรุงรักษา

วิธีเขียนโค้ดแบบอินไลน์: ดูคำตอบอื่น ๆ

สำหรับใช้ลูปรับอาร์กิวเมนต์ทั้งหมดและในแบทช์บริสุทธิ์:

Obs:สำหรับใช้โดยไม่ต้อง:?*&<>

@echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && (
     call set "_arg_[!_cnt!]=!_arg_!" && for /l %%l in (!_cnt! 1 !_cnt!
     )do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

รหัสของคุณพร้อมที่จะทำบางสิ่งด้วยหมายเลขอาร์กิวเมนต์ที่ต้องการเช่น ...

 @echo off && setlocal EnableDelayedExpansion

 for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"
 )

 fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt