การแทนที่สตริงในไฟล์แบตช์

เราสามารถแทนที่สตริงในไฟล์แบตช์โดยใช้คำสั่งต่อไปนี้

set str="jump over the chair"
set str=%str:chair=table%

เส้นเหล่านี้ใช้ได้ดีและเปลี่ยนสตริง "กระโดดข้ามเก้าอี้" เป็น "กระโดดข้ามโต๊ะ" ตอนนี้ฉันต้องการแทนที่คำว่า "เก้าอี้" ในสตริงด้วยตัวแปรบางตัวและฉันไม่รู้ว่าจะทำอย่างไร

set word=table
set str="jump over the chair"
??

ความคิดใด ๆ ?

คุณสามารถใช้ได้! แต่คุณต้องมีชุดสวิตช์ ENABLEDELAYEDEXPANSION

setlocal ENABLEDELAYEDEXPANSION
set word=table
set str="jump over the chair"
set str=%str:chair=!word!%

คุณสามารถใช้เคล็ดลับเล็ก ๆ น้อย ๆ ต่อไปนี้:

set word=table
set str="jump over the chair"
call set str=%%str:chair=%word%%%
echo %str%

สิ่งนี้callทำให้เกิดการขยายตัวของตัวแปรอีกชั้นทำให้จำเป็นต้องอ้างอิง%สัญญาณดั้งเดิมแต่ทุกอย่างได้ผลในที่สุด

ฉันสามารถใช้ Joey's Answer เพื่อสร้างฟังก์ชัน:

ใช้เป็น:

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

SET "MYTEXT=jump over the chair"
echo !MYTEXT!
call:ReplaceText "!MYTEXT!" chair table RESULT
echo !RESULT!

GOTO:EOF

และฟังก์ชั่นเหล่านี้ที่ด้านล่างของ Batch File ของคุณ

:FUNCTIONS
@REM FUNCTIONS AREA
GOTO:EOF
EXIT /B

:ReplaceText
::Replace Text In String
::USE:
:: CALL:ReplaceText "!OrginalText!" OldWordToReplace NewWordToUse  Result
::Example
::SET "MYTEXT=jump over the chair"
::  echo !MYTEXT!
::  call:ReplaceText "!MYTEXT!" chair table RESULT
::  echo !RESULT!
::
:: Remember to use the "! on the input text, but NOT on the Output text.
:: The Following is Wrong: "!MYTEXT!" !chair! !table! !RESULT!
:: ^^Because it has a ! around the chair table and RESULT
:: Remember to add quotes "" around the MYTEXT Variable when calling.
:: If you don't add quotes, it won't treat it as a single string
::
set "OrginalText=%~1"
set "OldWord=%~2"
set "NewWord=%~3"
call set OrginalText=%%OrginalText:!OldWord!=!NewWord!%%
SET %4=!OrginalText!
GOTO:EOF

และจำไว้ว่าคุณต้องเพิ่ม "SETLOCAL ENABLEDELAYEDEXPANSION" ที่ด้านบนของไฟล์แบตช์ของคุณมิฉะนั้นสิ่งนี้จะไม่ทำงานอย่างถูกต้อง

SETLOCAL ENABLEDELAYEDEXPANSION
@REM # Remember to add this to the top of your batch file.

ใช้งานได้ดี

@echo off    
set word=table    
set str=jump over the chair    
set rpl=%str:chair=%%word%    
echo %rpl%