วิธีส่งคืนผลลัพธ์จากฟังก์ชัน VBA

ฉันจะส่งคืนผลลัพธ์จากฟังก์ชันได้อย่างไร

ตัวอย่างเช่น:

Public Function test() As Integer
    return 1
End Function

สิ่งนี้ทำให้เกิดข้อผิดพลาดในการคอมไพล์

ฉันจะทำให้ฟังก์ชันนี้คืนค่าเป็นจำนวนเต็มได้อย่างไร

สำหรับประเภทการส่งคืนที่ไม่ใช่วัตถุคุณจะต้องกำหนดค่าให้กับชื่อฟังก์ชั่นของคุณดังนี้:

Public Function test() As Integer
    test = 1
End Function

ตัวอย่างการใช้งาน:

Dim i As Integer
i = test()

หากฟังก์ชันส่งคืนประเภทวัตถุคุณต้องใช้Setคำหลักเช่นนี้:

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

ตัวอย่างการใช้งาน:

Dim r As Range
Set r = testRange()

โปรดทราบว่าการกำหนดค่าส่งคืนให้กับชื่อฟังก์ชั่นจะไม่ยุติการใช้งานฟังก์ชันของคุณ Exit Functionหากคุณต้องการที่จะออกจากฟังก์ชั่นแล้วคุณจะต้องพูดอย่างชัดเจน ตัวอย่างเช่น:

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

เอกสารประกอบ: http://msdn.microsoft.com/en-us/library/office/gg264233%28v=office.14%29.aspx

ฟังก์ชั่น VBA ถือว่าชื่อฟังก์ชั่นของตัวเองเป็นประเภทของตัวแปร ดังนั้นแทนที่จะใช้returnคำสั่ง "" คุณจะพูดว่า:

test = 1

อย่างไรก็ตามขอให้สังเกตว่าสิ่งนี้ไม่ได้แยกออกจากฟังก์ชั่น รหัสใด ๆ หลังจากคำสั่งนี้จะถูกดำเนินการ ดังนั้นคุณสามารถมีคำสั่งมอบหมายจำนวนมากที่กำหนดค่าที่แตกต่างกันไปtestและสิ่งที่เป็นค่าเมื่อคุณถึงจุดสิ้นสุดของฟังก์ชั่นจะเป็นค่าที่ส่งกลับ

เพียงแค่ตั้งค่าส่งคืนเป็นชื่อฟังก์ชั่นยังคงไม่เหมือนกันกับคำสั่ง Java (หรืออื่น ๆ ) returnเพราะใน java returnออกจากฟังก์ชั่นดังนี้:

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

ใน VB ที่แน่นอนเทียบเท่าใช้เวลาสองเส้นถ้าคุณไม่ได้ตั้งค่าค่าตอบแทนในตอนท้ายของฟังก์ชั่นของคุณ ดังนั้นใน VB ข้อพิสูจน์ที่แน่นอนจะมีลักษณะเช่นนี้:

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function 

เนื่องจากเป็นกรณีนี้คุณควรใช้ตัวแปร return เช่นเดียวกับตัวแปรอื่น ๆ ในเมธอด แบบนี้:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function 

หรือตัวอย่างที่ดีที่สุดของการทำงานของตัวแปรส่งคืน(แต่ไม่จำเป็นต้องเป็นตัวอย่างที่ดีของวิธีที่คุณควรเขียนโค้ด) - สิ่งที่จะทำให้คุณตื่นขึ้นมาในตอนกลางคืน:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function

รหัสด้านล่างเก็บค่าส่งคืนในตัวแปรretValแล้วMsgBoxสามารถใช้เพื่อแสดงค่า:

Dim retVal As Integer
retVal = test()
Msgbox retVal