คุณตรวจสอบประเภทของตัวแปรใน Elixir อย่างไร

ใน Elixir คุณจะตรวจสอบประเภทเช่นใน Python ได้อย่างไร:

>>> a = "test"
>>> type(a)
<type 'str'>
>>> b =10
>>> type(b)
<type 'int'>

ฉันอ่าน Elixir แล้วมีตัวตรวจสอบชนิดเช่น 'is_bitstring', 'is_float', 'is_list', 'is_map' ฯลฯ แต่ถ้าคุณไม่รู้ว่าควรเป็นประเภทใด

ไม่มีวิธีโดยตรงในการรับชนิดของตัวแปรใน Elixir / Erlang

คุณมักจะต้องการทราบชนิดของตัวแปรเพื่อที่จะดำเนินการตามนั้น คุณสามารถใช้is_*ฟังก์ชั่นเพื่อดำเนินการตามชนิดของตัวแปร

เรียนรู้คุณบ้าง Erlang มีบทที่ดีเกี่ยวกับการพิมพ์ใน Erlang (และใน Elixir)

วิธีที่ใช้สำนวนที่สุดในการใช้is_*ตระกูลฟังก์ชันอาจจะใช้ในการจับคู่รูปแบบ:

def my_fun(arg) when is_map(arg), do: ...
def my_fun(arg) when is_list(arg), do: ...
def my_fun(arg) when is_integer(arg), do: ...
# ...and so on

การเริ่มต้นใน elixir 1.2 จะมีiคำสั่งใน iex ที่จะแสดงรายการประเภทและตัวแปร Elixir ใด ๆ

iex> foo = "a string" 
iex> i foo 
Term
 "a string"
Data type
 BitString
Byte size
 8
Description
 This is a string: a UTF-8 encoded binary. It's printed surrounded by
 "double quotes" because all UTF-8 encoded codepoints in it are        printable.
Raw representation
  <<97, 32, 115, 116, 114, 105, 110, 103>>
Reference modules
  String, :binary

หากคุณมองหารหัสสำหรับiคำสั่งคุณจะเห็นว่ามีการใช้งานผ่านโปรโตคอล

https://github.com/elixir-lang/elixir/blob/master/lib/iex/lib/iex/info.ex

ถ้าคุณต้องการที่จะใช้ฟังก์ชั่นสำหรับชนิดข้อมูลใด ๆ ใน Elixir วิธีที่จะทำคือการกำหนดโปรโตคอลและการใช้งานของโปรโตคอลสำหรับประเภทข้อมูลทั้งหมดที่คุณต้องการให้ฟังก์ชั่นทำงาน น่าเสียดายที่คุณไม่สามารถใช้ฟังก์ชันโปรโตคอลในการ์ด อย่างไรก็ตามโพรโทคอล "ประเภท" ง่าย ๆ จะตรงไปตรงมามากในการใช้

นอกจากนี้สำหรับวัตถุประสงค์ในการแก้ไขข้อบกพร่องหากคุณไม่ได้อยู่ใน iex คุณสามารถโทรหาได้โดยตรง:

IEx.Info.info(5)
=> ["Data type": "Integer", "Reference modules": "Integer"]

อีกวิธีคือใช้การจับคู่รูปแบบ สมมติว่าคุณใช้ Timex ซึ่งใช้โครงสร้าง%DateTime{}และคุณต้องการดูว่าองค์ประกอบนั้นเป็นองค์ประกอบหรือไม่ คุณสามารถค้นหาการจับคู่โดยใช้การจับคู่รูปแบบในวิธีการ

def is_a_datetime?(%DateTime{}) do
  true
end

def is_a_datetime?(_) do
  false
end

ฉันจะออกจากที่นี่เพื่อเห็นแก่ใครบางคนหวังว่าจะหาเวอร์ชั่นที่มีสติจริง ๆ ในขณะนี้ยังไม่มีคำตอบที่ดีเกี่ยวกับเรื่องนี้เกิดขึ้นบน google ...

defmodule Util do
    def typeof(self) do
        cond do
            is_float(self)    -> "float"
            is_number(self)   -> "number"
            is_atom(self)     -> "atom"
            is_boolean(self)  -> "boolean"
            is_binary(self)   -> "binary"
            is_function(self) -> "function"
            is_list(self)     -> "list"
            is_tuple(self)    -> "tuple"
            true              -> "idunno"
        end    
    end
end

เพื่อความสมบูรณ์กรณีทดสอบ:

cases = [
    1.337, 
    1337, 
    :'1337', 
    true, 
    <<1, 3, 3, 7>>, 
    (fn(x) -> x end), 
    {1, 3, 3, 7}
]

Enum.each cases, fn(case) -> 
    IO.puts (inspect case) <> " is a " <> (Util.typeof case)
end

นี่คือทางออกของโปรโตคอล ฉันไม่แน่ใจว่าพวกเขาเร็วขึ้นหรือไม่ (ฉันหวังว่าพวกเขาจะไม่วนซ้ำทุกประเภท) แต่มันก็น่าเกลียดมาก (และเปราะบางถ้าพวกเขาเพิ่มหรือลบประเภทพื้นฐานหรือเปลี่ยนชื่อมันจะทำลายมัน)

defprotocol Typeable, do: def typeof(self)
defimpl Typeable, for: Atom, do: def typeof(_), do: "Atom"
defimpl Typeable, for: BitString, do: def typeof(_), do: "BitString"
defimpl Typeable, for: Float, do: def typeof(_), do: "Float"
defimpl Typeable, for: Function, do: def typeof(_), do: "Function"
defimpl Typeable, for: Integer, do: def typeof(_), do: "Integer"
defimpl Typeable, for: List, do: def typeof(_), do: "List"
defimpl Typeable, for: Map, do: def typeof(_), do: "Map"
defimpl Typeable, for: PID, do: def typeof(_), do: "PID"
defimpl Typeable, for: Port, do: def typeof(_), do: "Port"
defimpl Typeable, for: Reference, do: def typeof(_), do: "Reference"
defimpl Typeable, for: Tuple, do: def typeof(_), do: "Tuple"

IO.puts Typeable.typeof "Hi"
IO.puts Typeable.typeof :ok

ฉันเพิ่งวางรหัสจากhttps://elixirforum.com/t/just-created-a-typeof-module/2583/5 :)

defmodule Util do
  types = ~w[function nil integer binary bitstring list map float atom tuple pid port reference]
  for type <- types do
    def typeof(x) when unquote(:"is_#{type}")(x), do: unquote(type)
  end
end

ฉันเจอสถานการณ์ต้องตรวจสอบพารามิเตอร์จะต้องเป็นประเภทที่แน่นอน อาจใช้งานวิธีที่ดีกว่า

แบบนี้:

@required [{"body", "binary"},{"fee", "integer"}, ...]
defp match_desire?({value, type}) do
  apply(Kernel, :"is_#{type}", [value])
end

การใช้งาน:

Enum.map(@required, &(match_desire?/1))

เพียงเพราะไม่มีใครพูดถึงมัน

IO.inspect/1

ส่งออกไปยังคอนโซลวัตถุ ... เกือบจะเท่ากับ JSON.stringify

มีประโยชน์มากเมื่อคุณไม่สามารถใช้ชีวิตของคุณเพื่อค้นหาว่าวัตถุมีลักษณะอย่างไรในการทดสอบ