ชื่อตารางเป็นตัวแปร

ฉันพยายามเรียกใช้แบบสอบถามนี้:

declare @tablename varchar(50)
set @tablename = 'test'
select * from @tablename

สิ่งนี้ทำให้เกิดข้อผิดพลาดดังต่อไปนี้:

เกี่ยวกับ 1087 ระดับ 16 สถานะ 1 บรรทัด 5

ต้องประกาศตัวแปรตาราง "@tablename"

วิธีที่ถูกต้องในการตั้งชื่อตารางเป็นแบบไดนามิกคืออะไร

สำหรับแบบสอบถามแบบคงที่เช่นเดียวกับคำถามของคุณชื่อตารางและชื่อคอลัมน์จะต้องคงที่

สำหรับเคียวรีแบบไดนามิกคุณควรสร้าง SQL แบบเต็มและใช้ sp_executesql เพื่อดำเนินการ

นี่คือตัวอย่างของสคริปต์ที่ใช้ในการเปรียบเทียบข้อมูลระหว่างตารางเดียวกันของฐานข้อมูลที่แตกต่างกัน:

แบบสอบถามแบบคงที่:

SELECT * FROM [DB_ONE].[dbo].[ACTY]
EXCEPT
SELECT * FROM [DB_TWO].[dbo].[ACTY]

เนื่องจากฉันต้องการเปลี่ยนชื่อ tha ของtableและschemaฉันได้สร้างการสืบค้นแบบไดนามิกนี้:

declare @schema varchar(50)
declare @table varchar(50)
declare @query nvarchar(500)

set @schema = 'dbo'
set @table = 'ACTY'

set @query = 'SELECT * FROM [DB_ONE].['+ @schema +'].[' + @table + '] EXCEPT SELECT * FROM [DB_TWO].['+ @schema +'].[' + @table + ']'

EXEC sp_executesql @query

เนื่องจากเคียวรีแบบไดนามิกมีรายละเอียดมากมายที่จำเป็นต้องพิจารณาและยากที่จะพูดได้ฉันขอแนะนำให้คุณอ่าน: คำสาปและพรของ SQL แบบไดนามิก

เปลี่ยนคำสั่งล่าสุดของคุณเป็น:

EXEC('SELECT * FROM ' + @tablename)

นี่คือวิธีที่ฉันทำในขั้นตอนการจัดเก็บ บล็อกแรกจะประกาศตัวแปรและตั้งชื่อตารางตามชื่อปีและเดือนปัจจุบันในกรณีนี้ TEST_2012OCTOBER จากนั้นฉันจะตรวจสอบว่ามันมีอยู่ในฐานข้อมูลแล้วหรือไม่ จากนั้นบล็อกถัดไปจะใช้คำสั่ง SELECT INTO เพื่อสร้างตารางและเติมข้อมูลด้วยระเบียนจากตารางอื่นที่มีพารามิเตอร์

--DECLARE TABLE NAME VARIABLE DYNAMICALLY
DECLARE @table_name varchar(max)
SET @table_name = 
    (SELECT 'TEST_'
            + DATENAME(YEAR,GETDATE())
            + UPPER(DATENAME(MONTH,GETDATE())) )

--DROP THE TABLE IF IT ALREADY EXISTS
IF EXISTS(SELECT name 
          FROM sysobjects 
          WHERE name = @table_name AND xtype = 'U')

BEGIN
    EXEC('drop table ' +  @table_name)
END

--CREATES TABLE FROM DYNAMIC VARIABLE AND INSERTS ROWS FROM ANOTHER TABLE
EXEC('SELECT * INTO ' + @table_name + ' FROM dbo.MASTER WHERE STATUS_CD = ''A''')

สายไปหาคำตอบ แต่ควรช่วยเหลือคนอื่น:

CREATE PROCEDURE [dbo].[GetByName]
    @TableName NVARCHAR(100)
    AS
BEGIN
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;
    DECLARE @sSQL nvarchar(500);

    SELECT @sSQL = N'SELECT * FROM' + QUOTENAME(@TableName);

    EXEC sp_executesql @sSQL



END

คุณไม่สามารถใช้ชื่อตารางสำหรับตัวแปรคุณต้องทำสิ่งนี้แทน:

DECLARE @sqlCommand varchar(1000)
SET @sqlCommand = 'SELECT * from yourtable'
EXEC (@sqlCommand)

คุณจะต้องสร้าง sql แบบไดนามิก:

declare @tablename varchar(50) 

set @tablename = 'test' 

declare @sql varchar(500)

set @sql = 'select * from ' + @tablename 

exec (@sql)

ใช้sp_executesqlเพื่อรัน SQL ใด ๆ เช่น

DECLARE @tbl    sysname,
        @sql    nvarchar(4000),
        @params nvarchar(4000),
        @count  int

DECLARE tblcur CURSOR STATIC LOCAL FOR
   SELECT object_name(id) FROM syscolumns WHERE name = 'LastUpdated'
   ORDER  BY 1
OPEN tblcur

WHILE 1 = 1
BEGIN
   FETCH tblcur INTO @tbl
   IF @@fetch_status <> 0
      BREAK

   SELECT @sql =
   N' SELECT @cnt = COUNT(*) FROM dbo.' + quotename(@tbl) +
   N' WHERE LastUpdated BETWEEN @fromdate AND ' +
   N'                           coalesce(@todate, ''99991231'')'
   SELECT @params = N'@fromdate datetime, ' +
                    N'@todate   datetime = NULL, ' +
                    N'@cnt      int      OUTPUT'
   EXEC sp_executesql @sql, @params, '20060101', @cnt = @count OUTPUT

   PRINT @tbl + ': ' + convert(varchar(10), @count) + ' modified rows.'
END

DEALLOCATE tblcur

นอกจากนี้คุณสามารถใช้สิ่งนี้ ...

DECLARE @SeqID varchar(150);
DECLARE @TableName varchar(150);  
SET @TableName = (Select TableName from Table);
SET @SeqID = 'SELECT NEXT VALUE FOR '+ @TableName + '_Data'
exec (@SeqID)

Declare  @tablename varchar(50) 
set @tablename = 'Your table Name' 
EXEC('select * from ' + @tablename)

คุณต้องใช้ SQL Server ไดนามิก SQL

DECLARE @table     NVARCHAR(128),
        @sql       NVARCHAR(MAX);

SET @table = N'tableName';

SET @sql = N'SELECT * FROM ' + @table;

ใช้EXECเพื่อรัน SQL ใด ๆ

EXEC (@sql)

ใช้EXEC sp_executesqlเพื่อรัน SQL ใด ๆ

EXEC sp_executesql @sql;

ใช้EXECUTE sp_executesqlเพื่อเรียกใช้งาน SQL ใด ๆ

EXECUTE sp_executesql @sql

Declare @fs_e int, @C_Tables CURSOR, @Table varchar(50)

SET @C_Tables = CURSOR FOR
        select name from sysobjects where OBJECTPROPERTY(id, N'IsUserTable') = 1 AND name like 'TR_%'
OPEN @C_Tables
FETCH @C_Tables INTO @Table
    SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'

WHILE ( @fs_e <> -1)
    BEGIN
        exec('Select * from '+ @Table)
        FETCH @C_Tables INTO @Table
        SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'
    END