จะตรวจสอบได้อย่างไรว่าบริการกำลังทำงานผ่านไฟล์แบตช์และเริ่มทำงานหากไม่ได้ทำงาน

ฉันต้องการเขียนแบตช์ไฟล์ที่ดำเนินการดังต่อไปนี้:

• ตรวจสอบว่าบริการกำลังทำงานอยู่หรือไม่
  • หากกำลังทำงานอยู่ให้ออกจากชุดงาน
  • หากยังไม่ทำงานให้เริ่มบริการ

ตัวอย่างโค้ดที่ฉัน googled จนถึงขณะนี้ใช้งานไม่ได้ดังนั้นฉันจึงตัดสินใจที่จะไม่โพสต์

การเริ่มต้นบริการทำได้โดย:

net start "SERVICENAME"

1. ฉันจะตรวจสอบได้อย่างไรว่าบริการกำลังทำงานอยู่และจะสร้างคำสั่ง if ใน batchfile ได้อย่างไร
2. ฉันสับสนนิดหน่อย อะไรคือข้อโต้แย้งที่ฉันต้องส่งต่อไปยัง net start? ชื่อบริการหรือชื่อที่แสดง?

sc query <SERVICE_NAME>หากต้องการตรวจสอบสถานะการให้บริการของการใช้งาน เพราะว่าถ้าบล็อกในไฟล์ชุดตรวจสอบเอกสาร

รหัสต่อไปนี้จะตรวจสอบสถานะของบริการMyServiceNameและเริ่มต้นหากไม่ทำงาน (บล็อก if จะถูกเรียกใช้งานหากบริการไม่ทำงาน):

for /F "tokens=3 delims=: " %%H in ('sc query "MyServiceName" ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (
   REM Put your code you want to execute here
   REM For example, the following line
   net start "MyServiceName"
  )
)

คำอธิบายว่ามันทำอะไร:

1. สอบถามคุณสมบัติของบริการ
2. ค้นหาบรรทัดที่มีข้อความ "STATE"
3. สร้างโทเค็นบรรทัดนั้นและดึงโทเค็นที่ 3 ออกมาซึ่งเป็นโทเค็นที่มีสถานะของบริการ
4. ทดสอบสถานะผลลัพธ์เทียบกับสตริง "RUNNING"

สำหรับคำถามที่สองอาร์กิวเมนต์ที่คุณต้องการส่งผ่านnet startคือชื่อบริการไม่ใช่ชื่อที่แสดง

ในการสลับบริการให้ใช้ดังต่อไปนี้

NET START "ผู้ประสานงานธุรกรรมแบบกระจาย" || NET STOP "ผู้ประสานงานธุรกรรมแบบกระจาย"

คุณสามารถใช้คำสั่งต่อไปนี้เพื่อดูว่าบริการกำลังทำงานอยู่หรือไม่:

sc query [ServiceName] | findstr /i "STATE"

เมื่อฉันเรียกใช้สำหรับ NOD32 Antivirus ฉันจะได้รับ:

STATE                       : 4 RUNNING

หากหยุดทำงานฉันจะได้รับ:

STATE                       : 1 STOPPED

คุณสามารถใช้สิ่งนี้ในตัวแปรเพื่อกำหนดว่าคุณใช้ NET START หรือไม่

ชื่อบริการควรเป็นชื่อบริการไม่ใช่ชื่อที่แสดง

ที่ควรทำ:

FOR %%a IN (%Svcs%) DO (SC query %%a | FIND /i "RUNNING"
IF ERRORLEVEL 1 SC start %%a)

ภาษาเวอร์ชันอิสระ

@Echo Off
Set ServiceName=Jenkins


SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(
    echo %ServiceName% not running 
    echo Start %ServiceName%

    Net start "%ServiceName%">nul||(
        Echo "%ServiceName%" wont start 
        exit /b 1
    )
    echo "%ServiceName%" started
    exit /b 0
)||(
    echo "%ServiceName%" working
    exit /b 0
)

ฉันเพิ่งพบหัวข้อนี้และต้องการเพิ่มในการสนทนาหากบุคคลนั้นไม่ต้องการใช้ไฟล์แบตช์เพื่อเริ่มบริการใหม่ ใน Windows มีตัวเลือกถ้าคุณไปที่บริการคุณสมบัติของบริการแล้วกู้คืน คุณสามารถตั้งค่าพารามิเตอร์สำหรับบริการได้ที่นี่ ต้องการเริ่มบริการใหม่หากบริการหยุดลง นอกจากนี้คุณยังสามารถพยายามล้มเหลวครั้งที่สองเพื่อทำสิ่งที่แตกต่างออกไปเช่นในการรีสตาร์ทคอมพิวเตอร์

Cuando se ใช้ Windows en Español, el código debe quedar asi (เมื่อใช้ Windows เป็นภาษาสเปนรหัสคือ):

for /F "tokens=3 delims=: " %%H in ('sc query MYSERVICE ^| findstr "        ESTADO"') do (
  if /I "%%H" NEQ "RUNNING" (
    REM Put your code you want to execute here
    REM For example, the following line
    net start MYSERVICE
  )
)

Reemplazar MYSERVICE con el nombre del servicio que se desea procesar. Puedes ver el nombre del servicio viendo las propiedades del servicio (แทนที่ MYSERVICE ด้วยชื่อของบริการที่จะดำเนินการคุณสามารถดูชื่อของบริการในคุณสมบัติของบริการ)

@echo off

color 1F


@sc query >%COMPUTERNAME%_START.TXT


find /I "AcPrfMgrSvc" %COMPUTERNAME%_START.TXT >nul

IF ERRORLEVEL 0 EXIT

IF ERRORLEVEL 1 NET START "AcPrfMgrSvc"

สำหรับ Windows Server 2012 ด้านล่างคือสิ่งที่ใช้ได้ผลสำหรับฉัน แทนที่ "SERVICENAME" ด้วยชื่อบริการจริงเท่านั้น:

@ECHO OFF
SET SvcName=SERVICENAME

SC QUERYEX "%SvcName%" | FIND "STATE" | FIND /v "RUNNING" > NUL && (
    ECHO %SvcName% is not running 
    ECHO START %SvcName%

    NET START "%SvcName%" > NUL || (
        ECHO "%SvcName%" wont start 
        EXIT /B 1
    )
    ECHO "%SvcName%" is started
    EXIT /B 0
) || (
    ECHO "%SvcName%" is running
    EXIT /B 0
)

ฉันต้องการอีเมลที่ส่งไปหากบริการเริ่มต้นด้วยวิธีนี้ดังนั้นจึงเพิ่มรหัส @Ic เพียงเล็กน้อยแค่คิดว่าฉันจะโพสต์ไว้เผื่อว่าจะช่วยใครได้ ฉันใช้ SendMail แต่มีตัวเลือกบรรทัดคำสั่งอื่น ๆจะส่งอีเมลธรรมดาจากไฟล์แบตช์ Windows ได้อย่างไร

set service=MyServiceName

for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (

    net start %service%

    for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
      if /I "%%H" EQ "RUNNING" (
        SendMail /smtpserver localhost /to me@mydomain.com /from watchdog@mydomain.com /subject Service Autostart Notification /body Autostart on service %service% succeded.
      ) else (
        SendMail /smtpserver localhost /to me@mydomain.com /from watchdog@mydomain.com /subject Service Autostart Notification /body Autostart on service %service% failed.
      )
    )

  )
)

เริ่มต้นบริการโดยใช้สคริปต์ Powershell คุณสามารถเชื่อมโยงสิ่งนี้กับตัวกำหนดตารางเวลางานและเรียกใช้เป็นช่วง ๆ หรือตามต้องการ สร้างไฟล์นี้เป็นไฟล์ PS1 เช่นไฟล์ที่มีนามสกุล PS1 จากนั้นปล่อยให้ไฟล์นี้ถูกทริกเกอร์จากตัวกำหนดตารางเวลางาน

เพื่อเริ่มหยุดให้บริการ

ในตัวกำหนดตารางเวลางานหากคุณกำลังใช้บนเซิร์ฟเวอร์ให้ใช้สิ่งนี้ในอาร์กิวเมนต์

-noprofile -executionpolicy บายพาส -file "C: \ Service Restart Scripts \ StopService.PS1"

ตรวจสอบโดยการรันเหมือนกันบน cmd ว่ามันใช้งานได้หรือไม่ควรทำงานกับตัวกำหนดตารางเวลางานด้วย

$Password = "Enter_Your_Password"
$UserAccount = "Enter_Your_AccountInfor"
$MachineName = "Enter_Your_Machine_Name"
$ServiceList = @("test.SocketService","test.WcfServices","testDesktopService","testService")
$PasswordSecure = $Password | ConvertTo-SecureString -AsPlainText -Force
$Credential = new-object -typename System.Management.Automation.PSCredential -argumentlist $UserAccount, $PasswordSecure 

$LogStartTime = Get-Date -Format "MM-dd-yyyy hh:mm:ss tt"
$FileDateTimeStamp = Get-Date -Format "MM-dd-yyyy_hh"
$LogFileName = "C:\Users\krakhil\Desktop\Powershell\Logs\StartService_$FileDateTimeStamp.txt" 


#code to start the service

"`n####################################################################" > $LogFileName
"####################################################################" >> $LogFileName
"######################  STARTING SERVICE  ##########################" >> $LogFileName

for($i=0;$i -le 3; $i++)
{
"`n`n" >> $LogFileName
$ServiceName = $ServiceList[$i]
"$LogStartTime => Service Name: $ServiceName" >> $LogFileName

Write-Output "`n####################################"
Write-Output "Starting Service - " $ServiceList[$i]

"$LogStartTime => Starting Service: $ServiceName" >> $LogFileName
Start-Service $ServiceList[$i]

$ServiceState = Get-Service | Where-Object {$_.Name -eq $ServiceList[$i]}

if($ServiceState.Status -eq "Running")
{
"$LogStartTime => Started Service Successfully: $ServiceName" >> $LogFileName
Write-Host "`n Service " $ServiceList[$i] " Started Successfully"
}
else
{
"$LogStartTime => Unable to Stop Service: $ServiceName" >> $LogFileName
Write-Output "`n Service didn't Start. Current State is - "
Write-Host $ServiceState.Status
}
}

#code to stop the service

"`n####################################################################" > $LogFileName
"####################################################################" >> $LogFileName
"######################  STOPPING SERVICE  ##########################" >> $LogFileName

for($i=0;$i -le 3; $i++)
{
"`n`n" >> $LogFileName
$ServiceName = $ServiceList[$i]
"$LogStartTime => Service Name: $ServiceName" >> $LogFileName

Write-Output "`n####################################"
Write-Output "Stopping Service - " $ServiceList[$i]

"$LogStartTime => Stopping Service: $ServiceName" >> $LogFileName
Stop-Service $ServiceList[$i]

$ServiceState = Get-Service | Where-Object {$_.Name -eq $ServiceList[$i]}

if($ServiceState.Status -eq "Stopped")
{
"$LogStartTime => Stopped Service Successfully: $ServiceName" >> $LogFileName
Write-Host "`n Service " $ServiceList[$i] " Stopped Successfully"
}
else
{
"$LogStartTime => Unable to Stop Service: $ServiceName" >> $LogFileName
Write-Output "`nService didn't Stop. Current State is - "
Write-Host $ServiceState.Status
}
}

@Echo off

Set ServiceName=wampapache64

SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(

echo %ServiceName% not running
echo  

Net start "%ServiceName%"


    SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(
        Echo "%ServiceName%" wont start
    )
        echo "%ServiceName%" started

)||(
    echo "%ServiceName%" was working and stopping
    echo  

    Net stop "%ServiceName%"

)


pause

เกี่ยวข้องกับคำตอบโดย @DanielSerrano ฉันเพิ่งได้รับการแปลsc.exeคำสั่งเป็นภาษาสเปนเมื่อไม่นานมานี้ ข้อเสนอของฉันคือการปักหมุดบรรทัดและโทเค็นซึ่งมีสถานะการบริการที่เป็นตัวเลขและตีความซึ่งควรจะมีประสิทธิภาพมากกว่านี้:

@echo off

rem TODO: change to the desired service name
set TARGET_SERVICE=w32time

set SERVICE_STATE=
rem Surgically target third line, as some locales (such as Spanish) translated the utility's output
for /F "skip=3 tokens=3" %%i in ('""%windir%\system32\sc.exe" query "%TARGET_SERVICE%" 2>nul"') do (
  if not defined SERVICE_STATE set SERVICE_STATE=%%i
)
rem Process result
if not defined SERVICE_STATE (
  echo ERROR: could not obtain service state!
) else (
  rem NOTE: values correspond to "SERVICE_STATUS.dwCurrentState"
  rem https://msdn.microsoft.com/en-us/library/windows/desktop/ms685996(v=vs.85).aspx
  if not %SERVICE_STATE%==4 (
    echo WARNING: service is not running
    rem TODO: perform desired operation
    rem net start "%TARGET_SERVICE%"
  ) else (
    echo INFORMATION: service is running
  )
)

ทดสอบด้วย:

• Windows XP (32 บิต) ภาษาอังกฤษ
• Windows 10 (32 บิต) ภาษาสเปน
• Windows 10 (64 บิต) ภาษาอังกฤษ

อาจจะเป็นวิธีที่ง่ายกว่ามาก? เพียงเพิ่มในรายการคำตอบที่นี่:

@for /f "tokens=1,* delims=: " %%a in ('sc queryex state=Inactive') do net start "%%b"