รับรายการอาร์กิวเมนต์ที่ส่งผ่านในสคริปต์ชุดงาน Windows (.bat)

ฉันต้องการหาชุดแบตช์ Windows ของ Bash $@ที่มีรายการอาร์กิวเมนต์ทั้งหมดที่ส่งผ่านไปยังสคริปต์

หรือฉันต้องรำคาญกับshift?

dancavallaroทำให้ถูกต้อง%*สำหรับพารามิเตอร์บรรทัดคำสั่งทั้งหมด (ยกเว้นชื่อสคริปต์เอง) คุณอาจพบว่ามีประโยชน์เหล่านี้:

%0- คำสั่งที่ใช้ในการเรียกไฟล์ batch (อาจจะfoo, ..\foo, c:\bats\foo.batฯลฯ )
%1เป็นพารามิเตอร์บรรทัดคำสั่งแรก
%2คือพารามิเตอร์บรรทัดคำสั่งที่สอง
และอื่น ๆ จน%9(และSHIFTสามารถนำมาใช้สำหรับผู้ที่หลังจากที่ 9)

%~nx0- ชื่อจริงของแบทช์ไฟล์โดยไม่คำนึงถึงวิธีการโทร (some-batch.bat)
%~dp0- ไดรฟ์และเส้นทางไปยังสคริปต์ (d: \ script)
%~dpnx0- เป็นชื่อพา ธ แบบเต็มของสคริปต์ (d: \ script \ some -batch.bat)

ตัวอย่างข้อมูลเพิ่มเติมได้ที่https://www.ss64.com/nt/syntax-args.htmlและhttps://www.robvanderwoude.com/parameters.html

%* ดูเหมือนว่าจะเก็บข้อโต้แย้งทั้งหมดที่ส่งผ่านไปยังสคริปต์

%1... %nและ%*ถืออาร์กิวเมนต์ แต่มันอาจเป็นเรื่องยากหากจะเข้าถึงเพราะเนื้อหาจะถูกตีความ
ดังนั้นจึงเป็นไปไม่ได้ที่จะจัดการบางอย่างเช่นนี้ด้วยข้อความปกติ

myBatch.bat "&"^&

แต่ละบรรทัดล้มเหลวเนื่องจาก cmd.exe พยายามเรียกใช้หนึ่งในเครื่องหมาย (เนื้อหาของ% 1 คือ"&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

แต่มีวิธีแก้ไขด้วยไฟล์ชั่วคราว

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

เคล็ดลับคือการเปิดใช้งานecho onและขยายคำสั่ง%1หลังrem(ยังทำงานได้กับ% 2 .. % *)
แต่เพื่อให้สามารถเปลี่ยนเส้นทางของเอาต์พุตecho onคุณต้องมี FOR-LOOPS สองรายการ

อักขระพิเศษ* #จะถูกใช้เพื่อความปลอดภัยต่อเนื้อหาเช่น/?(จะแสดงความช่วยเหลือสำหรับ REM)
หรือเครื่องหมายรูปหมวก ^ ที่ปลายบรรทัดสามารถทำงานเป็นอักขระหลายบรรทัดได้

FOR / F ควรทำงานโดยปิดการขยายล่าช้าหรือเนื้อหาอื่นที่มี "!" จะถูกทำลาย
หลังจากลบตัวละครพิเศษในparam1และคุณได้รับมัน

และใช้param1อย่างปลอดภัยเปิดใช้งานการขยายที่ล่าช้า

แก้ไข: หนึ่งคำพูดถึง% 0

%0มีคำสั่งที่ใช้เรียกแบทช์เก็บรักษาเคสเช่นในFoO.BaT
แต่หลังจากเรียกใช้ฟังก์ชัน%0และยัง%~0มีชื่อฟังก์ชัน (หรือดีกว่าสตริงที่ใช้เรียกฟังก์ชัน)
แต่%~f0คุณยังสามารถจำชื่อไฟล์ได้

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

เอาท์พุต

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

ฉันพบว่าครั้งต่อไปเมื่อคุณต้องการค้นหาข้อมูลเหล่านี้ แทนที่จะเปิดเบราว์เซอร์และ google คุณสามารถพิมพ์call /?cmd ของคุณและคุณจะได้รับมัน:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

วิธีดึงข้อมูล args ทั้งหมดไปยังสคริปต์อยู่ที่นี่:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

นี่เป็นวิธีที่ค่อนข้างง่ายในการรับ args และตั้งค่าให้เป็น env vars ในตัวอย่างนี้ฉันจะอ้างถึงพวกเขาว่าเป็นกุญแจและค่า

บันทึกตัวอย่างรหัสต่อไปนี้เป็น "args.bat" จากนั้นเรียกไฟล์แบตช์ที่คุณบันทึกจากบรรทัดคำสั่ง ตัวอย่าง: arg.bat --x 90 - ปี 120

ฉันได้จัดเตรียมคำสั่ง echo ไว้เพื่อให้คุณทำตามขั้นตอน แต่ผลลัพธ์สุดท้ายคือ --x จะมีค่า 90 และ --y จะมีค่าเท่ากับ 120 (นั่นคือถ้าคุณเรียกใช้ตัวอย่างตามที่ระบุไว้ข้างต้น ;-))

จากนั้นคุณสามารถใช้คำสั่งแบบมีเงื่อนไข 'หากกำหนดไว้' เพื่อพิจารณาว่าจะเรียกใช้การบล็อกรหัสของคุณหรือไม่ ดังนั้นให้เรียกใช้: "arg.bat --x hello-world" ฉันสามารถใช้คำสั่ง "IF DEFINED --x echo% - x%" และผลลัพธ์จะเป็น "hello-world" ควรสมเหตุสมผลถ้าคุณเรียกใช้ชุดงาน

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

สำหรับการใช้การวนซ้ำเพื่อรับอาร์กิวเมนต์ทั้งหมดและในแบทช์บริสุทธิ์:

Obs:สำหรับใช้โดยไม่ต้อง:?*&<>

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof 

รหัสของคุณพร้อมที่จะทำบางสิ่งด้วยหมายเลขอาร์กิวเมนต์ที่ต้องการเช่น ...

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

รหัสต่อไปนี้จำลองอาร์เรย์ (' params') - รับพารามิเตอร์ที่ได้รับจากสคริปต์และเก็บไว้ในตัวแปรparams_1.. params_n, โดยที่n= params_0= จำนวนองค์ประกอบของอาร์เรย์:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

หากคุณมีพารามิเตอร์ในเครื่องหมายคำพูดที่มีช่องว่าง%*จะทำงานไม่ถูกต้อง ทางออกที่ดีที่สุดที่ฉันพบคือการวนซ้ำที่รวมอาร์กิวเมนต์ทั้งหมด: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

คุณสามารถใช้ได้ For Commad เพื่อรับรายการของ Arg

ช่วยเหลือ: For /? ช่วยเหลือ:Setlocal /?

นี่คือวิธีของฉัน =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

ไม่ต้องการคำสั่ง Shift

@ ปิดเสียง
: เริ่มต้น

:: ใส่รหัสของคุณที่นี่
echo. %% 1 คือตอนนี้:% ~ 1
:: ท้ายใส่รหัสของคุณที่นี่

ถ้า "% ~ 2" NEQ "" (
    เปลี่ยน
    ไปที่: เริ่มต้น
)

ข้อมูลข้างต้นทำให้ฉันค้นคว้าเพิ่มเติมและท้ายที่สุดคำตอบของฉันดังนั้นฉันต้องการมีส่วนร่วมในสิ่งที่ฉันทำด้วยความหวังว่ามันจะช่วยคนอื่น:

• ฉันต้องการส่งตัวแปรจำนวนมากไปยังไฟล์แบตช์เพื่อให้สามารถประมวลผลภายในไฟล์ได้

• ฉันโอเคที่จะส่งต่อพวกเขาไปยังแฟ้มแบตช์โดยใช้เครื่องหมายคำพูด

• ฉันต้องการให้พวกเขาประมวลผลคล้ายกับด้านล่าง - แต่ใช้วนแทนการเขียนด้วยตนเอง:

ดังนั้นฉันต้องการที่จะดำเนินการนี้:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

และด้วยความมหัศจรรย์ของลูปสำหรับการทำเช่นนี้ภายในไฟล์แบทช์:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

ปัญหาที่ฉันเกิดขึ้นก็คือความพยายามทั้งหมดของฉันที่จะใช้สำหรับลูปไม่ได้ทำงาน ตัวอย่างด้านล่าง:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

จะทำ:

set "_appPath=C:\Services\Logs\PCAP"

และไม่:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

แม้หลังจากการตั้งค่า

SETLOCAL EnableDelayedExpansion

เหตุผลคือ for for loop อ่านทั้งบรรทัดและกำหนดพารามิเตอร์ที่สองของฉันให้กับ %% B ในระหว่างการวนซ้ำครั้งแรกของการวนซ้ำ เนื่องจาก% * แสดงถึงการขัดแย้งทั้งหมดมีเพียงบรรทัดเดียวเท่านั้นที่จะดำเนินการ - ดังนั้นจึงเกิดการวนรอบสำหรับลูปเพียงครั้งเดียว นี่คือการออกแบบโดยมันเปิดออกและตรรกะของฉันผิด

ดังนั้นฉันจึงหยุดพยายามที่จะใช้ลูป for และทำให้สิ่งที่ฉันพยายามทำได้ง่ายขึ้นโดยใช้ if, shift และคำสั่ง goto ตกลงเห็นด้วยกับการแฮ็ก แต่มันเหมาะกับความต้องการของฉันมากกว่า ฉันสามารถวนรอบอาร์กิวเมนต์ทั้งหมดแล้วใช้คำสั่ง if เพื่อเลื่อนออกจากลูปเมื่อฉันประมวลผลทั้งหมด

ข้อความที่ชนะเลิศสำหรับสิ่งที่ฉันพยายามทำ:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

อัปเดต - ฉันต้องแก้ไขด้านล่างแทนฉันได้เปิดเผยตัวแปรสภาพแวดล้อมทั้งหมดเมื่อพยายามอ้างอิง% 1 และใช้กะในลักษณะนี้:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

บางครั้งฉันต้องการแยกพารามิเตอร์บรรทัดคำสั่งหลายตัว แต่ไม่ใช่ทั้งหมดและไม่ใช่จากพารามิเตอร์แรก สมมติว่ามีสายต่อไปนี้:

Test.bat uno dos tres cuatro cinco seis siete

แน่นอนว่าส่วนขยาย ".bat" ไม่จำเป็นต้องมีอย่างน้อยคุณมี test.exe ในโฟลเดอร์เดียวกัน สิ่งที่เราต้องการคือการรับเอาท์พุท "tres cuatro cinco" (ไม่ว่าจะเป็นหนึ่งบรรทัดหรือสาม) เป้าหมายคือฉันต้องการเพียงสามพารามิเตอร์และเริ่มในพารามิเตอร์ที่สาม เพื่อให้มีตัวอย่างง่าย ๆ การกระทำสำหรับแต่ละรายการนั้นเป็นเพียง "เสียงสะท้อน" แต่คุณสามารถคิดในการดำเนินการที่ซับซ้อนกว่าพารามิเตอร์ที่เลือก

ฉันได้สร้างตัวอย่าง (ตัวเลือก) เพื่อให้คุณเห็นว่าคุณคิดว่าตัวไหนดีกว่าสำหรับคุณ น่าเสียดายที่ไม่มีวิธีที่ดี (หรือฉันไม่รู้) ที่ใช้สำหรับวนรอบช่วงเช่น "สำหรับ %% i ใน (% 3, 1,% 5)"

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

อาจเป็นไปได้ว่าคุณสามารถหาตัวเลือกเพิ่มเติมหรือรวมหลาย ๆ อย่างเข้าด้วยกัน สนุกกับพวกเขา

รุ่น Windows (ต้องใช้ socat)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

ตั้งค่า:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd