วิธีเชื่อมโยงโปรแกรม C ++ กับ Boost โดยใช้ CMake

ไฟล์ CMake ของฉันควรมีลักษณะอย่างไรสำหรับการเชื่อมโยงโปรแกรมของฉันกับไลบรารี Boost ภายใต้ Ubuntu

ข้อผิดพลาดที่แสดงระหว่างการทำงานmake:

main.cpp:(.text+0x3b): undefined reference to `boost::program_options::options_description::m_default_line_length'

ไฟล์หลักนั้นง่ายมาก:

#include <boost/program_options/options_description.hpp>
#include <boost/program_options/option.hpp>
using namespace std;
#include <iostream>

namespace po = boost::program_options;

int main(int argc, char** argv) {

    po::options_description desc("Allowed options");
    desc.add_options()
        ("help", "produce help message")
        ;

    return 0;
}

ฉันจัดการไปแล้ว บรรทัดเดียวที่ฉันเพิ่มลงในไฟล์ CMake คือ:

target_link_libraries(
my_target_file
${Boost_PROGRAM_OPTIONS_LIBRARY}
)

ใน CMake คุณสามารถใช้find_packageเพื่อค้นหาไลบรารีที่คุณต้องการ โดยปกติจะมีการFindBoost.cmakeติดตั้ง CMake ร่วมด้วย

เท่าที่ฉันจำได้มันจะถูกติดตั้ง/usr/share/cmake/Modules/พร้อมกับสคริปต์ค้นหาอื่น ๆ สำหรับไลบรารีทั่วไป คุณสามารถตรวจสอบเอกสารในไฟล์นั้นเพื่อดูข้อมูลเพิ่มเติมเกี่ยวกับวิธีการทำงาน

ตัวอย่างจากหัวของฉัน:

FIND_PACKAGE( Boost 1.40 COMPONENTS program_options REQUIRED )
INCLUDE_DIRECTORIES( ${Boost_INCLUDE_DIR} )

ADD_EXECUTABLE( anyExecutable myMain.cpp )

TARGET_LINK_LIBRARIES( anyExecutable LINK_PUBLIC ${Boost_LIBRARIES} )

ฉันหวังว่ารหัสนี้จะช่วยได้

• ที่นี่อย่างเป็นทางการเอกสารเกี่ยวกับ FindBoost.cmake
• และFindBoost.cmakeจริง(โฮสต์บน GitHub)

ต่อไปนี้คือการกำหนดค่าของฉัน:

cmake_minimum_required(VERSION 2.8)
set(Boost_INCLUDE_DIR /usr/local/src/boost_1_46_1)
set(Boost_LIBRARY_DIR /usr/local/src/boost_1_46_1/stage/lib)
find_package(Boost COMPONENTS system filesystem REQUIRED)
include_directories(${Boost_INCLUDE_DIR})
link_directories(${Boost_LIBRARY_DIR})

add_executable(main main.cpp)
target_link_libraries( main ${Boost_LIBRARIES} )

การปรับคำตอบ @MOnsDaR สำหรับไวยากรณ์ CMake สมัยใหม่ด้วยเป้าหมายที่นำเข้าสิ่งนี้จะเป็น:

find_package(Boost 1.40 COMPONENTS program_options REQUIRED)

add_executable(anyExecutable myMain.cpp)

target_link_libraries(anyExecutable Boost::program_options)

โปรดทราบว่าไม่จำเป็นต้องระบุไดเรกทอรีรวมด้วยตนเองเนื่องจากได้รับการดูแลผ่านเป้าหมายที่นำเข้าBoost::program_optionsแล้ว

ห้องสมุด Boost ใด หลายคนเป็นเทมเพลตที่บริสุทธิ์และไม่จำเป็นต้องมีการเชื่อมโยง

ตอนนี้มีตัวอย่างที่เป็นรูปธรรมซึ่งบอกเราว่าคุณต้องการตัวเลือกโปรแกรม Boost (และยิ่งบอกเราว่าคุณใช้ Ubuntu) คุณต้องทำสองสิ่ง:

1. ติดตั้งlibboost-program-options-devเพื่อให้คุณสามารถเชื่อมโยงกับมันได้
2. บอกจะเชื่อมโยงกับcmakelibboost_program_options

ฉันใช้ Makefiles เป็นส่วนใหญ่ดังนั้นนี่คือการใช้บรรทัดคำสั่งโดยตรง:

$ g++ boost_program_options_ex1.cpp -o bpo_ex1 -lboost_program_options
$ ./bpo_ex1
$ ./bpo_ex1 -h
$ ./bpo_ex1 --help
$ ./bpo_ex1 -help
$

ดูเหมือนว่าจะไม่ทำมากนัก

สำหรับ CMake คุณต้องเพิ่ม boost_program_options ในรายการไลบรารีและ IIRC จะทำผ่านSET(liblist boost_program_options)ในCMakeLists.txtไฟล์.

สองวิธีโดยใช้เส้นทางการติดตั้งเริ่มต้นของระบบโดยปกติ/usr/lib/x86_64-linux-gnu/:

find_package(Boost REQUIRED regex date_time system filesystem thread graph)
include_directories(${BOOST_INCLUDE_DIRS})
message("boost lib: ${Boost_LIBRARIES}")
message("boost inc:${Boost_INCLUDE_DIR}")

add_executable(use_boost use_boost.cpp)
target_link_libraries(use_boost
        ${Boost_LIBRARIES}
        )

หากคุณติดตั้ง Boost ในโลคัลไดเร็กทอรีหรือเลือกการติดตั้งภายในแทนการติดตั้งระบบคุณสามารถทำได้โดย:

set( BOOST_ROOT "/home/xy/boost_install/lib/" CACHE PATH "Boost library path" )
set( Boost_NO_SYSTEM_PATHS on CACHE BOOL "Do not search system for Boost" )

find_package(Boost REQUIRED regex date_time system filesystem thread graph)
include_directories(${BOOST_INCLUDE_DIRS})
message("boost lib: ${Boost_LIBRARIES}, inc:${Boost_INCLUDE_DIR}")

add_executable(use_boost use_boost.cpp)
target_link_libraries(use_boost
        ${Boost_LIBRARIES}
        )

โปรดทราบว่า dir ข้างต้น/home/xy/boost_install/lib/เป็นที่ที่ฉันติดตั้ง Boost:

xy@xy:~/boost_install/lib$ ll -th
total 16K
drwxrwxr-x 2 xy xy 4.0K May 28 19:23 lib/
drwxrwxr-x 3 xy xy 4.0K May 28 19:22 include/

xy@xy:~/boost_install/lib$ ll -th lib/
total 57M
drwxrwxr-x 2 xy xy 4.0K May 28 19:23 ./
-rw-rw-r-- 1 xy xy 2.3M May 28 19:23 libboost_test_exec_monitor.a
-rw-rw-r-- 1 xy xy 2.2M May 28 19:23 libboost_unit_test_framework.a
.......

xy@xy:~/boost_install/lib$ ll -th include/
total 20K
drwxrwxr-x 110 xy xy  12K May 28 19:22 boost/

หากคุณสนใจในการใช้ Boost ที่ติดตั้งในเครื่องคุณสามารถดูคำถามนี้ได้ฉันจะให้ CMake ค้นหาการติดตั้ง Boost ทางเลือกของฉันได้อย่างไร? .

นี่คือสิ่งที่ฉันใช้:

cmake_minimum_required(VERSION 3.15)

project(TryOuts LANGUAGES CXX)

find_package(Boost QUIET REQUIRED COMPONENTS program_options)

if(NOT Boost_FOUND)
    message(FATAL_ERROR "Boost Not found")
endif()

add_executable(helloworld main.cpp)

target_link_libraries(helloworld PUBLIC Boost::program_options)