แทนที่แท็บด้วยช่องว่างในกลุ่ม

ฉันต้องการแปลงแท็บเป็นช่องว่างใน gVim ฉันเพิ่มบรรทัดต่อไปนี้ใน_vimrc:

set tabstop=2

มันทำงานเพื่อหยุดที่สองช่องว่าง แต่ก็ยังดูเหมือนว่าหนึ่งแท็บคีย์ถูกแทรก (ฉันพยายามใช้ปุ่ม h เพื่อนับช่องว่างหลังจากนั้น)

ฉันไม่แน่ใจว่าฉันควรทำอย่างไรเพื่อให้แท็บการแปลง gVim เป็นช่องว่าง

IIRC บางอย่างเช่น:

set tabstop=2 shiftwidth=2 expandtab

ควรทำเคล็ดลับ หากคุณมีแท็บอยู่แล้วให้ติดตามด้วย RE ทั่วโลกที่ดีเพื่อแทนที่ด้วยช่องว่างสองครั้ง

เมื่อคุณขยายแท็บตามคำตอบอื่น ๆ วิธีที่สะดวกที่สุดในการแปลงไฟล์ที่มีอยู่ตามการตั้งค่าใหม่ของคุณคือ:

:retab

มันจะทำงานกับบัฟเฟอร์ปัจจุบัน

ลอง

set expandtab

สำหรับแท็บนุ่ม

วิธีแก้ไขแท็บที่มีอยู่แล้ว:

:%s/\t/  /g

ฉันใช้สองช่องว่างตั้งแต่คุณตั้งค่า tabstop เป็น 2 ช่องว่าง

สิ่งนี้ใช้ได้กับฉัน:

คุณสามารถดูแท็บโดยทำสิ่งนี้ก่อน:

:set list

จากนั้นเพื่อให้สามารถแทนที่แท็บได้ให้ทำดังนี้:

:set expandtab

แล้วก็

:retab

ตอนนี้แท็บทั้งหมดถูกแทนที่ด้วยช่องว่างคุณสามารถกลับไปดูแบบปกติได้ดังนี้:

:set nolist

gg=G จะรวบรวมไฟล์ทั้งหมดใหม่อีกครั้งและจะลบออกมากที่สุดหากไม่มีแท็บทั้งหมดที่ฉันได้รับจากเพื่อนร่วมงาน

เพิ่มบรรทัดต่อไปนี้ใน. vimrc ของคุณ

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

เปิดไฟล์ในกลุ่มแล้วกด F2 แท็บจะถูกแปลงเป็น 4 ช่องว่างและไฟล์จะถูกบันทึกโดยอัตโนมัติ

หากคุณต้องการให้\tช่องเท่ากับ 8 ช่องว่างให้พิจารณาการตั้งค่า:

   set softtabstop=2 tabstop=8 shiftwidth=2

วิธีนี้จะทำให้คุณมีช่องว่างสองรายการต่อการ<TAB>กด แต่จริง\tในรหัสของคุณจะยังคงถูกดูเป็น 8 ตัวอักษร

มันทำให้ฉันทำงาน:

:set tabstop=2 shiftwidth=2 expandtab | retab

ขั้นแรกให้ค้นหาแท็บในไฟล์ของคุณ: / ^ I: set expandtab: retab

จะทำงาน.

บทความนี้มีสคริปต์ vimrc ที่ยอดเยี่ยมสำหรับการจัดการแท็บ + ช่องว่างและการแปลงระหว่างพวกเขา

คำสั่งเหล่านี้มีให้:

Space2Tab แปลงช่องว่างเป็นแท็บเฉพาะในการเยื้อง

Tab2Space แปลงแท็บเป็นช่องว่างเฉพาะในการเยื้อง

RetabIndent Execute Space2Tab (ถ้าตั้งค่า 'expandtab') หรือ Tab2Space (มิฉะนั้น)

แต่ละคำสั่งยอมรับอาร์กิวเมนต์ที่ระบุจำนวนช่องว่างในคอลัมน์แท็บ โดยค่าเริ่มต้นการตั้งค่า 'tabstop' จะถูกใช้

แหล่งที่มา: http://vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

สิ่งนี้ช่วยฉันได้มากกว่าคำตอบที่นี่เมื่อฉันไปค้นหาวิธีแก้ปัญหาเป็นครั้งแรก

expandเป็นยูทิลิตี้ยูนิกซ์ในการแปลงแท็บเป็นช่องว่าง หากคุณไม่ต้องการsetสิ่งใดใน vim คุณสามารถใช้คำสั่ง shell จาก vim:

:!% expand -t8