กลุ่ม: การสร้างไดเร็กทอรีหลักเมื่อบันทึก

หากฉันวิงวอนvim foo/bar/somefileแต่foo/barไม่มีอยู่ Vim ก็ปฏิเสธที่จะบันทึก

ฉันรู้ว่าฉันสามารถเปลี่ยนเป็นเชลล์หรือทำ:!mkdir foo/barจาก Vim ได้ แต่ฉันขี้เกียจ :) มีวิธีทำให้ Vim ทำโดยอัตโนมัติเมื่อมันบันทึกบัฟเฟอร์หรือไม่?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

สังเกตเงื่อนไข: expand("<afile>")!~#'^\w\+:/'จะป้องกันไม่ให้กลุ่มสร้างไดเร็กทอรีสำหรับไฟล์เช่นftp://*และ!isdirectoryจะป้องกันการโทร mkdir ที่มีราคาแพง

อัปเดต : โซลูชันที่ดีกว่าอย่างเนียน ๆ ที่ตรวจสอบ buftype ที่ไม่ว่างเปล่าและการใช้งานmkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

ตามข้อเสนอแนะสำหรับคำถามของฉันนี่คือสิ่งที่ฉันลงเอยด้วย:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

สิ่งนี้กำหนด:Wคำสั่ง จะเป็นการดีที่ฉันต้องการที่จะมีทั้งหมดของ:w!, :wq, :wq!, :wallฯลฯ ทำงานเหมือนกัน แต่ผมไม่แน่ใจว่าถ้าเป็นไปได้โดยไม่ต้องพื้น reimplementing พวกเขาทั้งหมดที่มีฟังก์ชั่นที่กำหนดเอง

ฉันเพิ่มสิ่งนี้ใน ~ / .vimrc ของฉัน

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

ถ้าฉันต้องการสร้างไดเร็กทอรีที่ฉันกำลังพิมพ์อยู่:mk.และมันจะแทนที่ด้วย "! mkdir -p / path / to / my / file /" และอนุญาตให้ฉันตรวจสอบคำสั่งก่อนที่จะเรียกใช้

ฉัน:saveas!สร้างไดเร็กทอรีหากขาด: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

รหัสนี้จะแจ้งให้คุณสร้างไดเร็กทอรีด้วย:wหรือทำด้วย:w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

ฉันคิดว่าฉันสามารถทำได้ในสามบรรทัดโดยรวมสิ่งที่คนอื่นพูดกับคำตอบนี้

ดูเหมือนจะทำเคล็ดลับ:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

พยายามสร้างโฟลเดอร์โดยอัตโนมัติเมื่อบันทึกบัฟเฟอร์ หากมีสิ่งไม่ดีเกิดขึ้น (เช่นปัญหาการอนุญาต) มันก็จะปิดและปล่อยให้เขียนไฟล์ล้มเหลว

หากใครเห็นข้อบกพร่องที่ชัดเจนโปรดแสดงความคิดเห็น ฉันไม่ค่อยเชี่ยวชาญใน vimscript

แก้ไข: หมายเหตุขอบคุณ ZyX

• สิ่งนี้จะใช้ไม่ได้หากโฟลเดอร์ของคุณมีช่องว่าง (ดูเหมือนว่าจะไม่ถูกหลีกเลี่ยงอย่างถูกต้องหรือมีบางอย่าง)
• หรือหากคุณกำลังทำไฟล์หลอก
• หรือถ้าคุณกำลังจัดหา vimrc ของคุณ
• แต่ลูกชายมันสั้น