ฉันจะค้นหาว่าติดตั้ง JDK บนเครื่อง windows ได้อย่างไร

ฉันต้องรู้ว่า JDK อยู่ที่ใดในเครื่องของฉัน

ในการทำงานJava -versionในcmdมันจะแสดงรุ่นเป็น '1.6.xx' หากต้องการค้นหาตำแหน่งของ SDK นี้บนเครื่องของฉันฉันพยายามใช้echo %JAVA_HOME%แต่จะแสดงเฉพาะ 'JAVA_HOME' (เนื่องจากไม่มีชุด 'JAVA_PATH' var ในตัวแปรสภาพแวดล้อมของฉัน)

หากคุณใช้ Linux / Unix / Mac OS X:

ลองสิ่งนี้:

$ which java

ควรส่งออกตำแหน่งที่แน่นอน

หลังจากนั้นคุณสามารถตั้งค่าJAVA_HOMEตัวแปรสภาพแวดล้อมด้วยตนเอง

ในคอมพิวเตอร์ของฉัน (Mac OS X - Snow Leopard):

$ which java
/usr/bin/java
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 Nov  7 07:59 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

หากคุณใช้ Windows:

c:\> for %i in (java.exe) do @echo.   %~$PATH:i

Windows> เริ่ม> cmd>

C:> for %i in (javac.exe) do @echo.   %~$PATH:i

หากคุณมี JDK ติดตั้งอยู่ Path จะปรากฏขึ้น
ตัวอย่างเช่น:C:\Program Files\Java\jdk1.6.0_30\bin\javac.exe

ใน Windows ที่พรอมต์คำสั่ง

where javac

ใน windows ค่าเริ่มต้นคือ: C:\Program Files\Java\jdk1.6.0_14(ซึ่งตัวเลขอาจแตกต่างกันตามที่พวกเขาเป็นรุ่น)

ตัวติดตั้ง Java ทำให้หลายไฟล์ลงในโฟลเดอร์% WinDir% \ System32 (java.exe, javaws.exe และอื่น ๆ ) เมื่อคุณพิมพ์ java.exe ในบรรทัดคำสั่งหรือสร้างกระบวนการโดยไม่มีพา ธ เต็ม Windows จะใช้วิธีการเหล่านี้เป็นทางเลือกสุดท้ายหากไม่มีอยู่ในโฟลเดอร์% PATH%

คุณสามารถค้นหา Java ทุกรุ่นที่ติดตั้งในรีจิสตรี ดูสภาพแวดล้อมรันไทม์ของ HKLM \ SOFTWARE \ JavaSoft \ Java และสภาพแวดล้อมรันไทม์ HKLM \ SOFTWARE \ Wow6432Node \ JavaSoft \ Java สำหรับจาวาแบบ 32 บิตบน Windows 64 บิต

นี่คือวิธีที่จาวาค้นพบเวอร์ชั่นที่แตกต่างกันของตัวเอง และนี่คือสาเหตุที่ทั้ง 32- บิตและ 64- บิตสามารถอยู่ร่วมกันและทำงานได้ดีโดยไม่รบกวน

ธรรมดาและเรียบง่ายบนแพลตฟอร์ม Windows:

ที่จาวา

ชุดสคริปต์ด้านล่างจะพิมพ์ JRE เริ่มต้นที่มีอยู่ ก็สามารถที่จะแก้ไขได้อย่างง่ายดายเพื่อหาสิ่งที่รุ่น JDK ติดตั้งโดยการเปลี่ยนRuntime Environment JavaกับJava Development Kit

@echo off

setlocal

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal

ใน Windows 10 คุณสามารถค้นหาเส้นทางได้โดยไปที่แผงควบคุม> Java ในแผงควบคุมที่ปรากฏขึ้นคุณสามารถค้นหาเส้นทางตามที่แสดงในภาพหน้าจอด้านล่าง ในแผงควบคุม Java ไปที่แท็บ 'Java' จากนั้นคลิกปุ่ม 'ดู' ภายใต้คำอธิบาย 'ดูและจัดการเวอร์ชันและการตั้งค่า Java Runtime สำหรับแอปพลิเคชันและแอปเล็ต Java'

สิ่งนี้ควรใช้กับ Windows 7 และ Windows รุ่นล่าสุดอื่น ๆ

ในพรอมต์คำสั่ง Windows เพียงพิมพ์:

set java_home

หรือหากคุณไม่ชอบสภาพแวดล้อมคำสั่งคุณสามารถตรวจสอบได้จาก:

เมนูเริ่ม> คอมพิวเตอร์> คุณสมบัติของระบบ> คุณสมบัติระบบขั้นสูง จากนั้นเปิดแท็บขั้นสูง> ตัวแปรสภาพแวดล้อมและในตัวแปรระบบลองค้นหา JAVA_HOME

ภายใต้ Windows คุณสามารถใช้

C:>dir /b /s java.exe

เพื่อพิมพ์เส้นทางแบบเต็มของแต่ละ "java.exe" บนไดรฟ์ C: โดยไม่คำนึงว่าอยู่ในตัวแปรสภาพแวดล้อม PATH ของคุณหรือไม่

เพิ่มเติมเกี่ยวกับตัวแปร Windows ... java.homeอาจไม่ใช่ตำแหน่งเดียวกับไบนารีที่รันอยู่เสมอ

ในฐานะที่เป็นเดนิสอันตรายกล่าวว่าทำให้ Java ติดตั้งไฟล์ลงในแฟ้มโปรแกรมแต่ยังjava.exeเข้าSystem32 โดยไม่มีสิ่งใดที่เกี่ยวข้องกับ Java บนเส้นทางjava -versionยังคงทำงานได้ อย่างไรก็ตามเมื่อรันโปรแกรมของ PeterMmm มันจะรายงานค่าของProgram Filesเป็นjava.homeนี่ไม่ผิด (ติดตั้ง Java ไว้ที่นั่น) แต่ไบนารีจริงที่เรียกใช้อยู่ใน System32

วิธีหนึ่งในการตามล่าหาตำแหน่งของไบนารีjava.exeให้เพิ่มบรรทัดต่อไปนี้ลงในโค้ดของ PeterMmm เพื่อให้โปรแกรมทำงานได้นานขึ้น:

try{Thread.sleep(60000);}catch(Exception e) {}

รวบรวมและเรียกใช้จากนั้นตามตำแหน่งของอิมเมจjava.exe เช่นใน Windows 7 เปิดตัวจัดการงานค้นหารายการjava.exeคลิกขวาและเลือก 'ตำแหน่งไฟล์เปิด' ซึ่งจะเปิดตำแหน่งที่แน่นอนของไบนารี Java ในกรณีนี้มันจะSystem32

เรียกใช้โปรแกรมนี้จาก commandline:

// File: Main.java
public class Main {

    public static void main(String[] args) {
       System.out.println(System.getProperty("java.home"));
    }

}


$ javac Main.java
$ java Main

PowerShell หนึ่งซับ:

$p='HKLM:\SOFTWARE\JavaSoft\Java Development Kit'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome

คุณได้ลองดูตัวแปร% PATH% ของคุณแล้วหรือยัง นั่นคือสิ่งที่ Windows ใช้เพื่อค้นหาสิ่งที่เรียกใช้งานได้

เพียงแค่รัน setคำสั่งในบรรทัดคำสั่งของคุณ จากนั้นคุณจะเห็นตัวแปรสภาพแวดล้อมทั้งหมดที่คุณตั้งไว้

หรือถ้าบน Unix คุณสามารถทำให้มันง่ายขึ้น:

$ set | grep "JAVA_HOME" 

นี่เป็นระบบปฏิบัติการเฉพาะ บน Unix:

which java

จะแสดงเส้นทางไปยังไฟล์ที่เรียกทำงานได้ ฉันไม่รู้จัก Windows เทียบเท่า แต่โดยทั่วไปคุณจะมีbinโฟลเดอร์ของการติดตั้ง JDK ในระบบPATH:

echo %PATH%

คำตอบเหล่านี้ไม่ถูกต้องสำหรับ Linux หากคุณกำลังมองหาบ้านที่มีตำบลเช่น: bin, docs, include, jre, lib ฯลฯ

บน Ubuntu สำหรับ openjdk1.8.0 สิ่งนี้อยู่ใน: /usr/lib/jvm/java-1.8.0-openjdk-amd64

และคุณอาจต้องการใช้สิ่งนั้นJAVA_HOMEเนื่องจากคุณจะสามารถค้นหาส่วนหัวได้หากคุณสร้างไฟล์ต้นฉบับ JNI ในขณะที่มันเป็นความจริงwhich javaจะให้เส้นทางไบนารีมันไม่ได้เป็นบ้าน JDK จริง

บน macOS ให้รัน:

cd /tmp && echo 'public class Main {public static void main(String[] args) {System.out.println(System.getProperty("java.home"));}}' > Main.java && javac Main.java && java Main

บนเครื่องของฉันพิมพ์นี้:

/Library/Java/JavaVirtualMachines/jdk-9.0.4.jdk/Contents/Home

โปรดทราบว่าการรันwhich javaจะไม่แสดงตำแหน่ง JDK เนื่องจากjavaคำสั่งนั้นเป็นส่วนหนึ่งของคำสั่งJavaVM.frameworkซึ่งล้อมรอบ JDK จริง:

$ which java
/usr/bin/java
/private/tmp
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 14 Nov 17:37 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

ใน Windows cmd:

set "JAVA_HOME" 

#!/bin/bash

if [[ $(which ${JAVA_HOME}/bin/java) ]]; then
    exe="${JAVA_HOME}/bin/java"
elif [[ $(which java) ]]; then
    exe="java"
else 
    echo "Java environment is not detected."
    exit 1
fi

${exe} -version

สำหรับ windows:

@echo off
if "%JAVA_HOME%" == "" goto nojavahome

echo Using JAVA_HOME            :   %JAVA_HOME%

"%JAVA_HOME%/bin/java.exe" -version
goto exit

:nojavahome
echo The JAVA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program.
goto exit

:exit

ลิงค์นี้อาจช่วยอธิบายวิธีค้นหาจาวาที่สามารถเรียกใช้งานได้จาก bash: http://srcode.org/2014/05/07/detect-java-executable/

ฉันได้ปรับปรุงคำตอบของmunsinghข้างต้นโดยการทดสอบคีย์รีจิสทรีในการลงทะเบียน 64- บิตและ 32- บิตถ้าจำเป็น:

::- Test for the registry location  
SET VALUE=CurrentVersion
SET KEY_1="HKLM\SOFTWARE\JavaSoft\Java Development Kit"
SET KEY_2=HKLM\SOFTWARE\JavaSoft\JDK
SET REG_1=reg.exe
SET REG_2="C:\Windows\sysnative\reg.exe"
SET REG_3="C:\Windows\syswow64\reg.exe"

SET KEY=%KEY_1%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_2% is for 64-bit installations, using "C:\Windows\sysnative"
SET KEY=%KEY_1%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_3% is for 32-bit installations on a 64-bit system, using "C:\Windows\syswow64"
SET KEY=%KEY_1%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

:_set_value
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JDK_VERSION=%%b
)
SET KEY=%KEY%\%JDK_VERSION%
SET VALUE=JavaHome
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JAVAHOME=%%b
)
ECHO "%JAVAHOME%"
::- SETX JAVA_HOME "%JAVAHOME%"

การอ้างอิงสำหรับการเข้าถึงรีจิสตรี 64- บิต

สคริปต์สำหรับ Windows 32/64 บิต

@echo off

setlocal enabledelayedexpansion

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
)

set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal