จะทดสอบได้อย่างไรว่าไฟล์ปฏิบัติการมีอยู่ใน% PATH% จากไฟล์แบตช์ของ Windows หรือไม่?

ฉันกำลังมองหาวิธีง่ายๆในการทดสอบว่าไฟล์ปฏิบัติการมีอยู่ในตัวแปรสภาพแวดล้อม PATH จากไฟล์แบตช์ของ Windows หรือไม่

ไม่อนุญาตให้ใช้เครื่องมือภายนอกที่ OS ไม่ได้จัดเตรียมไว้ให้ Windows เวอร์ชันขั้นต่ำที่จำเป็นคือ Windows XP

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

หากคุณต้องการสิ่งนี้สำหรับส่วนขยายที่แตกต่างกันให้ทำซ้ำPATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

อาจเป็นไปได้ว่าwhereมีอยู่แล้วใน Windows รุ่นเก่า แต่ฉันไม่สามารถเข้าถึงได้ดังนั้นฉันจึงไม่สามารถบอกได้ ในเครื่องของฉันสิ่งต่อไปนี้ยังใช้งานได้:

where myExecutable

และส่งคืนด้วยรหัสทางออกที่ไม่ใช่ศูนย์หากไม่พบ ในชุดงานคุณอาจต้องการเปลี่ยนเส้นทางเอาต์พุตไปยังNULด้วย

โปรดทราบ

แยกในชุด ( .bat) ไฟล์และแตกต่างบรรทัดคำสั่ง (เพราะมีไฟล์ batch %0- %9) ดังนั้นคุณต้องไปคู่%มี %Xในบรรทัดคำสั่งนี้ไม่จำเป็นดังนั้นสำหรับตัวแปรที่เป็นเพียง

Windows Vista และเวอร์ชันที่ใหม่กว่ามาพร้อมกับโปรแกรมที่เรียกwhere.exeว่าค้นหาโปรแกรมในเส้นทาง มันทำงานดังนี้:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

สำหรับการใช้งานในไฟล์แบตช์คุณสามารถใช้/qสวิตช์ซึ่งเพิ่งตั้งค่าERRORLEVELและไม่ได้สร้างเอาต์พุตใด ๆ

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

หรือเวอร์ชันชวเลขง่าย ๆ (แต่อ่านได้น้อยกว่า) ที่พิมพ์ข้อความและออกจากแอปของคุณ:

where /q myapplication || ECHO Cound not find app. && EXIT /B

นี่คือวิธีที่ง่ายที่ความพยายามที่จะเรียกใช้โปรแกรมประยุกต์และจัดการข้อผิดพลาดใด ๆในภายหลัง

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

รหัสข้อผิดพลาด 9009 มักจะหมายถึงไม่พบไฟล์

ข้อเสียเพียงอย่างเดียวคือfile.exeจะถูกดำเนินการจริงหากพบ (ซึ่งในบางกรณีไม่สมควร)

สิ่งนี้สามารถทำได้โดยการทดแทนพารามิเตอร์

%~$PATH:1

สิ่งนี้ส่งคืนเส้นทางแบบเต็มของชื่อไฟล์ปฏิบัติการใน% 1 ไม่เช่นนั้นจะเป็นสตริงว่าง

สิ่งนี้ใช้ไม่ได้กับตัวแปรที่ผู้ใช้กำหนดเอง ดังนั้นหากชื่อไฟล์ที่เรียกใช้งานได้ไม่ใช่พารามิเตอร์สำหรับสคริปต์ของคุณคุณต้องมีรูทีนย่อย ตัวอย่างเช่น:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

โปรดดูhttp://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

บางครั้งวิธีง่ายๆนี้ก็ใช้ได้ผลโดยที่คุณตรวจสอบว่าผลลัพธ์ตรงกับที่คุณคาดหวัง บรรทัดแรกรันคำสั่งและคว้าบรรทัดสุดท้ายของเอาต์พุตมาตรฐาน

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

หากคุณกำลังค้นหาบางอย่างเช่นฉันในโฟลเดอร์เริ่มต้นควรไปที่โฟลเดอร์ ตัวอย่างเช่นฉันค้นหา exe ในโฟลเดอร์เริ่มต้นและฉันใช้รหัสนี้เช่น

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

ใช้คำสั่ง: powershell Test-Path "exe ที่คุณกำลังมองหา"

มันจะคืนค่า True ถ้าเป็นปัจจุบันมิฉะนั้น False

สำหรับผู้ที่มองหาตัวเลือก PowerShell คุณสามารถใช้Get-Commandcmdlet ผ่านสองรายการ ก่อนอื่นให้ระบุตำแหน่ง dir ปัจจุบันพร้อม.\คำนำหน้าจากนั้นให้ชื่อ exe

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

ซึ่งจะส่งคืนเป็นจริงหากพบในระบบหรือในเส้นทางกว้าง