มีคำถามที่เกี่ยวข้องกับวันที่ / เวลาที่สัมพันธ์กันบ่อยมากที่จะแก้ด้วยไฟล์แบทช์ แต่ล่ามบรรทัดคำสั่งcmd.exeไม่มีฟังก์ชั่นสำหรับการคำนวณวันที่ / เวลา โซลูชันการทำงานที่ดีจำนวนมากที่ใช้แอปพลิเคชันคอนโซลหรือสคริปต์เพิ่มเติมได้รับการโพสต์แล้วที่นี่ในหน้าอื่น ๆ ของ Stack Overflow และบนเว็บไซต์อื่น ๆ
ทั่วไปสำหรับการดำเนินการตามวันที่ / เวลาคือข้อกำหนดในการแปลงสตริงวันที่ / เวลาเป็นวินาทีตั้งแต่วันที่กำหนด UTC คือ 1970-01-01 00:00:00 UTC แต่สามารถใช้วันต่อมาได้ขึ้นอยู่กับช่วงวันที่ที่ต้องการสนับสนุนงานเฉพาะ
เจโพสต์7daysclean.cmdที่มีได้อย่างรวดเร็ว "วันที่วินาที" วิธีการแก้ปัญหาสำหรับบรรทัดคำสั่งล่ามcmd.exe แต่มันก็ไม่ได้ใช้เวลาปีกระโดดที่ถูกต้องเข้าบัญชี JRโพสต์Add-onสำหรับพิจารณาวันอธิกสุรทินในปีปัจจุบัน แต่ไม่สนใจปีอธิกสุรทินอื่น ๆ ตั้งแต่ปีฐานคือตั้งแต่ปี 1970
ฉันใช้ตารางแบบคงที่ (อาร์เรย์) 20 ปีที่สร้างขึ้นครั้งเดียวด้วยฟังก์ชั่น C ขนาดเล็กเพื่อรับจำนวนวันอย่างรวดเร็วรวมถึงวันอธิกสุรทินจาก 1970-01-01 ในฟังก์ชันแปลงวันที่ / เวลาในแอปพลิเคชันของฉันที่เขียนด้วย C / C ++
วิธีตารางนี้เร็วมากสามารถใช้ในชุดรหัสโดยใช้คำสั่งสำหรับ ดังนั้นฉันจึงตัดสินใจรหัสรูทีนย่อย batch GetSecondsซึ่งคำนวณจำนวนวินาทีตั้งแต่ 1970-01-01 00:00:00 UTC สำหรับสตริงวันที่ / เวลาที่ส่งผ่านไปยังรูทีนนี้
หมายเหตุ:วินาที Leap จะไม่นำมาพิจารณาเนื่องจากระบบไฟล์ Windows ไม่สนับสนุนวินาทีกระโดด
ก่อนตาราง:
วันตั้งแต่ 1970-01-01 00:00:00 UTC สำหรับแต่ละปีรวมถึงวันก้าวกระโดด
1970 - 1979: 0 365 730 1096 1461 1826 2191 2557 2922 3287
1980 - 1989: 3652 4018 4383 4748 5113 5479 5844 6209 6574 6940
1990 - 1999: 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592
2000 - 2009: 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245
2010 - 2019: 14610 14975 15340 15706 16071 16436 16801 17167 17532 17897
2020 - 2029: 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550
2030 - 2039: 21915 22280 22645 23011 23376 23741 24106 24472 24837 25202
2040 - 2049: 25567 25933 26298 26663 27028 27394 27759 28124 28489 28855
2050 - 2059: 29220 29585 29950 30316 30681 31046 31411 31777 32142 32507
2060 - 2069: 32872 33238 33603 33968 34333 34699 35064 35429 35794 36160
2070 - 2079: 36525 36890 37255 37621 37986 38351 38716 39082 39447 39812
2080 - 2089: 40177 40543 40908 41273 41638 42004 42369 42734 43099 43465
2090 - 2099: 43830 44195 44560 44926 45291 45656 46021 46387 46752 47117
2100 - 2106: 47482 47847 48212 48577 48942 49308 49673
การคำนวณวินาทีสำหรับปี 2039 ถึง 2106 ด้วยยุคเริ่มต้น 1970-01-01 เป็นไปได้เฉพาะกับการใช้ตัวแปร 32 บิตที่ไม่ได้ลงชื่อคือความยาวที่ไม่ได้ลงนาม (หรือ int ที่ไม่ได้ลงชื่อ) ใน C / C ++
แต่cmd.exeใช้สำหรับนิพจน์ทางคณิตศาสตร์ซึ่งเป็นตัวแปร 32 บิตที่เซ็นชื่อ ดังนั้นค่าสูงสุดคือ 2147483647 (0x7FFFFFFF) ซึ่งคือ 2038-01-19 03:14:07
ข้อมูล Leap ปี (ไม่ / ใช่) สำหรับปี 1970 ถึง 2106
1970 - 1989: N N Y N N N Y N N N Y N N N Y N N N Y N
1990 - 2009: N N Y N N N Y N N N Y N N N Y N N N Y N
2010 - 2029: N N Y N N N Y N N N Y N N N Y N N N Y N
2030 - 2049: N N Y N N N Y N N N Y N N N Y N N N Y N
2050 - 2069: N N Y N N N Y N N N Y N N N Y N N N Y N
2070 - 2089: N N Y N N N Y N N N Y N N N Y N N N Y N
2090 - 2106: N N Y N N N Y N N N N N N N Y N N
^ year 2100
จำนวนวันถึงวันแรกของแต่ละเดือนในปีปัจจุบัน
Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
Year with 365 days: 0 31 59 90 120 151 181 212 243 273 304 334
Year with 366 days: 0 31 60 91 121 152 182 213 244 274 305 335
การแปลงวันที่เป็นวินาทีตั้งแต่ 1970-01-01 ค่อนข้างง่ายโดยใช้ตารางเหล่านั้น
โปรดให้ความสนใจ!
รูปแบบของสตริงวันที่และเวลาขึ้นอยู่กับการตั้งค่าภูมิภาคและภาษาของ Windows คั่นและการสั่งซื้อของสัญญาณได้รับมอบหมายให้ตัวแปรสภาพแวดล้อมDay, MonthและYearในครั้งแรกสำหรับวงGetSecondsจะต้องมีการปรับให้เข้ากับวันท้องถิ่นรูปแบบที่ / เวลาในกรณีที่จำเป็น
มันเป็นสิ่งจำเป็นที่จะปรับตัวสตริงวันที่ของตัวแปรสภาพแวดล้อมถ้ารูปแบบวันที่ในตัวแปรสภาพแวดล้อมวันจะแตกต่างกับรูปแบบวันที่ใช้โดยคำสั่งFOR%%~tFบน
ตัวอย่างเช่นเมื่อ%DATE%ขยายเป็นSun 02/08/2015ในขณะที่%%~tFขยาย02/08/2015 07:38 PMโค้ดด้านล่างสามารถใช้กับการแก้ไขบรรทัดที่ 4 เป็น:
call :GetSeconds "%DATE:~4% %TIME%"
ส่งผลให้เกิดการส่งผ่านรูทีนย่อยเพียง02/08/2015- สตริงวันที่โดยไม่มีตัวอักษร 3 ตัวของตัวย่อวันทำงานและตัวคั่นช่องว่าง
อีกวิธีหนึ่งต่อไปนี้สามารถใช้เพื่อผ่านวันที่ปัจจุบันในรูปแบบที่ถูกต้อง:
call :GetSeconds "%DATE:~-10% %TIME%"
ตอนนี้ผ่านมา 10 ตัวอักษรจากสตริงวันที่จะถูกส่งผ่านไปยังฟังก์ชั่นGetSecondsและดังนั้นจึงไม่สำคัญว่าถ้าสตริงวันของตัวแปรสภาพแวดล้อมของวันคือมีหรือไม่มีวันเป็นเวลานานเป็นวันและเดือนที่อยู่เสมอด้วยตัวเลข 2 หลักในการสั่งซื้อที่คาดหวังคือในรูปแบบหรือdd/mm/yyyy dd.mm.yyyy
นี่คือรหัสแบตช์พร้อมคำอธิบายความคิดเห็นซึ่งเพิ่งแสดงว่าไฟล์ใดที่จะลบและไฟล์ใดที่จะเก็บไว้ในC:\Tempโครงสร้างโฟลเดอร์ดูรหัสสำหรับวงแรก
@echo off
setlocal EnableExtensions EnableDelayedExpansion
rem Get seconds since 1970-01-01 for current date and time.
call :GetSeconds "%DATE% %TIME%"
rem Subtract seconds for 7 days from seconds value.
set /A "LastWeek=Seconds-7*86400"
rem For each file in each subdirectory of C:\Temp get last modification date
rem (without seconds -> append second 0) and determine the number of seconds
rem since 1970-01-01 for this date/time. The file can be deleted if seconds
rem value is lower than the value calculated above.
for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
call :GetSeconds "%%~tF:0"
rem if !Seconds! LSS %LastWeek% del /F "%%~fF"
if !Seconds! LEQ %LastWeek% (
echo Delete "%%~fF"
) else (
echo Keep "%%~fF"
)
)
endlocal
goto :EOF
rem No validation is made for best performance. So make sure that date
rem and hour in string is in a format supported by the code below like
rem MM/DD/YYYY hh:mm:ss or M/D/YYYY h:m:s for English US date/time.
:GetSeconds
rem If there is " AM" or " PM" in time string because of using 12 hour
rem time format, remove those 2 strings and in case of " PM" remember
rem that 12 hours must be added to the hour depending on hour value.
set "DateTime=%~1"
set "Add12Hours=0"
if "%DateTime: AM=%" NEQ "%DateTime%" (
set "DateTime=%DateTime: AM=%"
) else if "%DateTime: PM=%" NEQ "%DateTime%" (
set "DateTime=%DateTime: PM=%"
set "Add12Hours=1"
)
rem Get year, month, day, hour, minute and second from first parameter.
for /F "tokens=1-6 delims=,-./: " %%A in ("%DateTime%") do (
rem For English US date MM/DD/YYYY or M/D/YYYY
set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
rem For German date DD.MM.YYYY or English UK date DD/MM/YYYY
rem set "Day=%%A" & set "Month=%%B" & set "Year=%%C"
set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
rem echo Date/time is: %Year%-%Month%-%Day% %Hour%:%Minute%:%Second%
rem Remove leading zeros from the date/time values or calculation could be wrong.
if "%Month:~0,1%" EQU "0" ( if "%Month:~1%" NEQ "" set "Month=%Month:~1%" )
if "%Day:~0,1%" EQU "0" ( if "%Day:~1%" NEQ "" set "Day=%Day:~1%" )
if "%Hour:~0,1%" EQU "0" ( if "%Hour:~1%" NEQ "" set "Hour=%Hour:~1%" )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )
rem Add 12 hours for time range 01:00:00 PM to 11:59:59 PM,
rem but keep the hour as is for 12:00:00 PM to 12:59:59 PM.
if "%Add12Hours%" == "1" (
if %Hour% LSS 12 set /A Hour+=12
)
set "DateTime="
set "Add12Hours="
rem Must use 2 arrays as more than 31 tokens are not supported
rem by command line interpreter cmd.exe respectively command FOR.
set /A "Index1=Year-1979"
set /A "Index2=Index1-30"
if %Index1% LEQ 30 (
rem Get number of days to year for the years 1980 to 2009.
for /F "tokens=%Index1% delims= " %%Y in ("3652 4018 4383 4748 5113 5479 5844 6209 6574 6940 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245") do set "Days=%%Y"
for /F "tokens=%Index1% delims= " %%L in ("Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N") do set "LeapYear=%%L"
) else (
rem Get number of days to year for the years 2010 to 2038.
for /F "tokens=%Index2% delims= " %%Y in ("14610 14975 15340 15706 16071 16436 16801 17167 17532 17897 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550 21915 22280 22645 23011 23376 23741 24106 24472 24837") do set "Days=%%Y"
for /F "tokens=%Index2% delims= " %%L in ("N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N") do set "LeapYear=%%L"
)
rem Add the days to month in year.
if "%LeapYear%" == "N" (
for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)
rem Add the complete days in month of year.
set /A "Days+=Day-1"
rem Calculate the seconds which is easy now.
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"
rem Exit this subroutine
goto :EOF
เพื่อประสิทธิภาพสูงสุดจะเป็นการดีที่สุดที่จะลบความคิดเห็นทั้งหมดเช่นทุกบรรทัดที่ขึ้นต้นด้วยremหลังจากช่องว่างนำหน้า 0-4
และอาร์เรย์สามารถมีขนาดเล็กลงเช่นลดช่วงเวลาจาก 1980-01-01 00:00:00 ถึง 2038-01-19 03:14:07 ตามที่ได้รับการสนับสนุนในขณะนี้โดยรหัสชุดงานด้านบนเช่น 2015-01 -01 ถึง 2019-12-31 ตามรหัสด้านล่างใช้ซึ่งลบไฟล์ที่เก่ากว่า 7 วันในC:\Tempโครงสร้างโฟลเดอร์
นอกจากนี้รหัสชุดด้านล่างได้รับการปรับให้เหมาะสมกับรูปแบบเวลา 24 ชั่วโมง
@echo off
setlocal EnableDelayedExpansion
call :GetSeconds "%DATE:~-10% %TIME%"
set /A "LastWeek=Seconds-7*86400"
for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
call :GetSeconds "%%~tF:0"
if !Seconds! LSS %LastWeek% del /F "%%~fF"
)
endlocal
goto :EOF
:GetSeconds
for /F "tokens=1-6 delims=,-./: " %%A in ("%~1") do (
set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
if "%Month:~0,1%" EQU "0" ( if "%Month:~1%" NEQ "" set "Month=%Month:~1%" )
if "%Day:~0,1%" EQU "0" ( if "%Day:~1%" NEQ "" set "Day=%Day:~1%" )
if "%Hour:~0,1%" EQU "0" ( if "%Hour:~1%" NEQ "" set "Hour=%Hour:~1%" )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )
set /A "Index=Year-2014"
for /F "tokens=%Index% delims= " %%Y in ("16436 16801 17167 17532 17897") do set "Days=%%Y"
for /F "tokens=%Index% delims= " %%L in ("N Y N N N") do set "LeapYear=%%L"
if "%LeapYear%" == "N" (
for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)
set /A "Days+=Day-1"
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"
goto :EOF
สำหรับข้อมูลเพิ่มเติมเกี่ยวกับรูปแบบวันที่และเวลาและการเปรียบเทียบเวลาไฟล์บน Windows ดูคำตอบของฉันในค้นหาว่าไฟล์เก่ากว่า 4 ชั่วโมงในไฟล์แบตช์พร้อมข้อมูลเพิ่มเติมมากมายเกี่ยวกับเวลาของไฟล์