เคล็ดลับและลูกเล่น Vim and Ctags [ปิด]

ฉันเพิ่งติดตั้งCtags (เพื่อช่วยในการพัฒนา C ++) กับ Vim ของฉัน (หรือมากกว่า gVim) และต้องการหาคำสั่งแมโครแมโครทางลัดและเคล็ดลับที่คุณชื่นชอบ ...

แบ่งปันคลังแสงที่ดีที่สุดของคุณ Add-on Vim อื่น ๆ ที่คุณอยากจะแนะนำสำหรับ C ++ สำหรับการพัฒนา Vim คืออะไร?

แก้ไขส่วนเสริมอื่น ๆ ที่คุณจะใช้ร่วมกับ Ctags คืออะไร

EDIT2 gVim รุ่นใดที่คุณใช้กับแท็ก มันสร้างความแตกต่างหรือไม่?

EDIT3คุณปรับปรุงประสบการณ์การเขียนโปรแกรมของคุณสำหรับทั้งโครงการขนาดใหญ่และขนาดเล็กได้อย่างไร

Ctrl+ ]- ไปที่คำจำกัดความ
Ctrl+ T- กระโดดกลับจากคำจำกัดความ
Ctrl+ W Ctrl+ ]- เปิดความหมายในแนวนอนแยก

เพิ่มบรรทัดเหล่านี้ใน vimrc
map <C-\> :tab split<CR>:exec("tag ".expand("<cword>"))<CR>
map <A-]> :vsp <CR>:exec("tag ".expand("<cword>"))<CR>

Ctrl+ \- เปิดคำจำกัดความในแท็บใหม่
Alt+ ]- เปิดคำจำกัดความในแนวแยก

หลังจากสร้างแท็กแล้ว คุณสามารถใช้ปุ่มต่อไปนี้เพื่อแท็กและแท็กออกจากฟังก์ชั่น:

Ctrl+ Left MouseClick- ไปที่คำนิยาม
Ctrl+ Right MouseClick- กระโดดกลับจากคำจำกัดความ

บรรทัดหนึ่งที่มักจะอยู่ใน. vimrc ของฉัน:

set tags=./tags;/

สิ่งนี้จะดูในไดเรกทอรีปัจจุบันสำหรับ "แท็ก" และทำงานต้นไม้สู่รากจนกว่าจะพบ IOW คุณสามารถอยู่ที่ไหนก็ได้ในทรีต้นทางของคุณแทนที่จะเป็นเพียงรากของมัน

อีกปลั๊กอินที่มีประโยชน์สำหรับการพัฒนา C คือcscope เช่นเดียวกับ Ctags ช่วยให้คุณข้ามไปยังคำจำกัดความ Cscope ข้ามไปยังฟังก์ชั่นการโทร

หากคุณมี cscope ในไดเรกทอรี ~ / bin / ให้เพิ่มรายการต่อไปนี้ใน. vimrc ของคุณและใช้ g ^] เพื่อไปที่ฟังก์ชันการโทร (ดู: help cscope)

if has("cscope")
    set csprg=~/bin/cscope
    set csto=0
    set cst
    set nocsverb
    " add any database in current directory
    if filereadable("cscope.out")
        cs add cscope.out
        " else add database pointed to by environment
    elseif $CSCOPE_DB != ""
        cs add $CSCOPE_DB
    endif
endif

เกือบลืม ... เช่นเดียวกับ ctags - คุณต้องสร้าง (และอัปเดตฐานข้อมูลเป็นระยะ) ฉันใช้สคริปต์ต่อไปนี้

select_files > cscope.files
ctags -L cscope.files
ctags -e -L cscope.files
cscope -ub -i cscope.files

โดยที่ 'select_files' เป็นสคริปต์อื่นที่แยกรายการของ C และไฟล์ส่วนหัวจาก Makefile วิธีนี้ฉันจัดทำดัชนีเฉพาะไฟล์ที่ใช้จริงโดยโครงการ

คุณสามารถเพิ่มไดเรกทอรีลงในการค้นหา ctags ของคุณ ตัวอย่างเช่นฉันมีดัชนี ctags ที่สร้างขึ้นสำหรับ Qt4 และมีสิ่งนี้ใน. vimrc ของฉัน:

set tags+=/usr/local/share/ctags/qt4

จากทั้งหมดข้างต้นและ ...

code_complete: พารามิเตอร์ฟังก์ชั่นเสร็จสมบูรณ์ตัวอย่างโค้ดและอีกมากมาย

• http://www.vim.org/scripts/script.php?script_id=1764

taglist.vim: ซอร์สโค้ดเบราว์เซอร์ (รองรับ C / C ++, java, perl, python, tcl, sql, php, ฯลฯ )

• http://www.vim.org/scripts/script.php?script_id=273

ฉันใช้ ALT-left และ ALT-right เพื่อป๊อป / พุชจาก / ไปยังสแต็กแท็ก

" Alt-right/left to navigate forward/backward in the tags stack
map <M-Left> <C-T>
map <M-Right> <C-]>

ถ้าคุณใช้hjklสำหรับการเคลื่อนไหวคุณสามารถแมป<M-h>และ<M-l>แทน

หลายคำนิยามของชื่อเดียวกัน

<C-w>g<C-]>เปิดคำจำกัดความในการแยก แต่ยังทำเช่น:tjumpนั้นไปที่คำจำกัดความหรือถ้ามีหลายคำจำกัดความนำเสนอรายการคำจำกัดความให้คุณเลือก

คำสั่งที่ฉันใช้บ่อยที่สุดคือ C-] ซึ่งข้ามไปที่นิยามของฟังก์ชันใต้เคอร์เซอร์ คุณสามารถใช้บ่อยขึ้นเพื่อติดตามการโทรมากขึ้น หลังจากนั้น Co จะนำคุณกลับมาหนึ่งระดับ Ci จะลึกอีกครั้ง

ฉันพบปลั๊กอินtaglistที่ต้องมี มันแสดงรายการแท็กทั้งหมดที่รู้เกี่ยวกับ (ไฟล์ที่คุณเปิด) ในหน้าต่างแยกและทำให้ง่ายต่อการนำทางไฟล์ขนาดใหญ่

ฉันใช้มันเป็นส่วนใหญ่ในการพัฒนา Python แต่จะดีกว่าสำหรับ C / C ++ เท่านั้น

ฉันห่อหุ้มแท็กในปลั๊กอินทดลองของฉัน

เกี่ยวกับการพัฒนาภาษา C ++ ในกลุ่มผมได้คำตอบแล้วมี : ผมใช้ชุดของตัวเองและปลั๊กอินอื่น ๆ ไม่กี่

ฉันได้ปรับปลั๊กอินของฉันเป็นเวลาสองปีเพื่อสนับสนุนโครงการ c ++ ที่ใหญ่พอ คุณสามารถดูพวกเขา

พวกเขาใช้ ctags และ cscsope

http://www.vim.org/scripts/script.php?script_id=1638
http://www.vim.org/scripts/script.php?script_id=2507

ฉันใส่สิ่งต่อไปนี้ในไฟล์. gvimrc ซึ่งค้นหาต้นไม้จากจุดใด ๆ สำหรับไฟล์แท็กเมื่อ gvim เริ่มทำงาน:

function SetTags()
    let curdir = getcwd()

    while !filereadable("tags") && getcwd() != "/"
        cd ..
    endwhile

    if filereadable("tags")
        execute "set tags=" . getcwd() . "/tags"
    endif

    execute "cd " . curdir
endfunction

call SetTags()

จากนั้นฉันจะสร้างไฟล์แท็กขึ้นใหม่เป็นระยะที่ด้านบนสุดของทรีซอร์สของฉันด้วยสคริปต์ที่มีลักษณะดังนี้:

#!/bin/bash

find . -regex ".*\.\(c\|h\|hpp\|cc\|cpp\)" -print | ctags --totals --recurse --extra="+qf" --fields="+i" -L -

ฉันใช้เป็นกลุ่มใน macos และ ctags ดั้งเดิมทำงานได้ไม่ดีดังนั้นฉันจึงดาวน์โหลดใหม่ล่าสุดและกำหนดค่าให้ทำการติดตั้ง ฉันติดตั้ง ctgas ใน / usr / local / bin / ctags (เพื่อเก็บต้นฉบับ)

"taglist
let Tlist_Ctags_Cmd = "/usr/local/bin/ctags"
let Tlist_WinWidth = 50
map <leader>ta :TlistToggle<cr>
map <leader>bta :!/usr/local/bin/ctags -R .<CR>
set tags=tags;/
map <M-j> <C-]>
map <M-k> <C-T>

ฉันปรับฟังก์ชั่นการค้นหา SetTags () ด้านบน (ซึ่งควรถูกแทนที่ด้วยสิ่งที่เทียบเท่าset tags+=./tags;/) เพื่อทำงานกับ cscope ดูเหมือนว่าจะทำงาน!

"cscope file-searching alternative
function SetCscope()
    let curdir = getcwd()

    while !filereadable("cscope.out") && getcwd() != "/"
            cd ..
                endwhile

    if filereadable("cscope.out")
            execute "cs add " . getcwd() . "/cscope.out"
                endif

    execute "cd " . curdir
    endfunction

call SetCscope()

การวนซ้ำอีกครั้งในฟังก์ชัน SetCscope () ด้านบน นั่นทำให้ cscope pre-path ทำการจับคู่โดยไม่ต้องอยู่บน dir โดยที่ "cscope.out" คือ:

function s:FindFile(file)
    let curdir = getcwd()
    let found = curdir
    while !filereadable(a:file) && found != "/"
        cd ..
        let found = getcwd()
    endwhile
    execute "cd " . curdir
    return found
endfunction

if has('cscope')    
    let $CSCOPE_DIR=s:FindFile("cscope.out")
    let $CSCOPE_DB=$CSCOPE_DIR."/cscope.out"
    if filereadable($CSCOPE_DB)
        cscope add $CSCOPE_DB $CSCOPE_DIR
    endif

    command -nargs=0 Cscope !cscope -ub -R &
endif