การสร้างการต่อข้อมูลที่สัมพันธ์กันอย่างสมบูรณ์

ความจริงที่ดีเกี่ยวกับการต่อเรียงคือถ้าฉันรู้ว่ามีสองตัวแปรในสมการ:

a ++ b = c

จากนั้นฉันก็รู้สาม

ฉันต้องการที่จะจับภาพความคิดนี้ใน concat ของตัวเองดังนั้นฉันจึงใช้การพึ่งพาการทำงาน

{-# Language DataKinds, GADTs, FlexibleContexts, FlexibleInstances, FunctionalDependencies, KindSignatures, PolyKinds, TypeOperators, UndecidableInstances #-}
import Data.Kind (Type)

class Concatable
   (m  :: k -> Type)
   (as :: k)
   (bs :: k)
   (cs :: k)
   | as bs -> cs
   , as cs -> bs
   , bs cs -> as
   where
     concat' :: m as -> m bs -> m cs

ตอนนี้ฉันคิดในรายการต่างกันเช่น:

data HList ( as :: [ Type ] ) where
  HEmpty :: HList '[]
  HCons  :: a -> HList as -> HList (a ': as)

แต่เมื่อฉันพยายามประกาศสิ่งเหล่านี้เนื่องจากConcatableฉันมีปัญหา

instance Concatable HList '[] bs bs where
  concat' HEmpty bs = bs
instance
  ( Concatable HList as bs cs
  )
    => Concatable HList (a ': as) bs (a ': cs)
  where
    concat' (HCons head tail) bs = HCons head (concat' tail bs)

ฉันไม่พอใจการทำงานของระบบที่สาม หรือคอมไพเลอร์เชื่อว่าเราทำไม่ได้ bs ~ (a ': cs)เพราะนี่คือคอมไพเลอร์เชื่อว่าในกรณีที่สองของเราก็อาจจะมีกรณีที่ Concatable as (a ': cs) csและมันอาจจะเป็นกรณีถ้า

ฉันจะปรับอินสแตนซ์ของฉันเพื่อให้การพึ่งพาทั้งสามนั้นเป็นที่พอใจได้อย่างไร

ดังนั้นตามความเห็นที่แนะนำ GHC ไม่ได้คิดออกมาเอง แต่เราสามารถช่วยได้ในการเขียนโปรแกรมระดับประเภทเล็กน้อย TypeFamiliesขอแนะนำบาง ฟังก์ชั่นทั้งหมดเหล่านี้เป็นการแปลแบบลิสเทอร์ไปหน้าระดับของการแปลที่ตรงไปตรงมา

-- | This will produce the suffix of `cs` without `as`
type family DropPrefix (as :: [Type]) (cs :: [Type]) where
  DropPrefix '[] cs = cs
  DropPrefix (a ': as) (a ': cs) = DropPrefix as cs

-- Similar to the logic in the question itself: list concatenation. 
type family Concat (as :: [Type]) (bs :: [Type]) where
  Concat '[] bs = bs
  Concat (head ': tail) bs = head ': Concat tail bs

-- | Naive list reversal with help of concatenation.
type family Reverse (xs :: [Type]) where
  Reverse '[] = '[]
  Reverse (x ': xs) = Concat (Reverse xs) '[x]

-- | This will produce the prefix of `cs` without `bs`
type family DropSuffix (bs :: [Type]) (cs :: [Type]) where
  DropSuffix bs cs = Reverse (DropPrefix (Reverse bs) (Reverse cs))

-- | Same definition of `HList` as in the question
data HList (as :: [Type]) where
  HEmpty :: HList '[]
  HCons :: a -> HList as -> HList (a ': as)

-- | Definition of concatenation at the value level
concatHList :: (cs ~ Concat as bs) => HList as -> HList bs -> HList cs
concatHList HEmpty bs = bs
concatHList (HCons head tail) bs = HCons head (concatHList tail bs)

ด้วยเครื่องมือนี้เราสามารถไปถึงเป้าหมายชั่วโมง แต่ก่อนอื่นเรามากำหนดฟังก์ชั่นด้วยคุณสมบัติที่ต้องการ:

• ความสามารถในการอนุมานcsจากasและbs
• ความสามารถในการอนุมานasจากbsและcs
• ความสามารถในการอนุมานbsจากasและcs

voila:

concatH ::
     (cs ~ Concat as bs, bs ~ DropPrefix as cs, as ~ DropSuffix bs cs)
  => HList as
  -> HList bs
  -> HList cs
concatH = concatHList

มาทดสอบกันเถอะ:

foo :: HList '[Char, Bool]
foo = HCons 'a' (HCons True HEmpty)

bar :: HList '[Int]
bar = HCons (1 :: Int) HEmpty

λ> :t concatH foo bar
concatH foo bar :: HList '[Char, Bool, Int]
λ> :t concatH bar foo
concatH bar foo :: HList '[Int, Char, Bool]

และในที่สุดเป้าหมายสุดท้าย:

class Concatable (m :: k -> Type) (as :: k) (bs :: k) (cs :: k)
  | as bs -> cs
  , as cs -> bs
  , bs cs -> as
  where
  concat' :: m as -> m bs -> m cs

instance (cs ~ Concat as bs, bs ~ DropPrefix as cs, as ~ DropSuffix bs cs) =>
         Concatable HList as bs cs where
  concat' = concatH

λ> :t concat' HEmpty bar
concat' HEmpty bar :: HList '[Int]
λ> :t concat' foo bar
concat' foo bar :: HList '[Char, Bool, Int]
λ> :t concat' bar foo
concat' bar foo :: HList '[Int, Char, Bool]